P_RU_MaterialReceiptDate1

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PRUMATRCPTDT1'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_RU_MaterialReceiptDate1
  with parameters
    P_StatryRptgEntity : srf_reporting_entity

  as select from    I_JournalEntry           as InvoiceFinAccDoc

    left outer join I_RU_CompanyCodeVatParam as CompanyCodeVatParam on StatryRptgEntity = $parameters.P_StatryRptgEntity

{
  InvoiceFinAccDoc.CompanyCode,
  InvoiceFinAccDoc.AccountingDocument,
  InvoiceFinAccDoc.FiscalYear,
  cast('    '       as werks_d preserving type)       as Plant,
  InvoiceFinAccDoc.ReferenceDocumentType,
  InvoiceFinAccDoc.DocumentDate                       as InvoiceDocumentDate,
  InvoiceFinAccDoc.PostingDate                        as InvoicePostingDate,
  cast( '00000000'              as fis_budat )        as MaterialRcptPostingDate,

  cast( case CompanyCodeVatParam.MatlRcptFinDateType
       when 'DDFI' then 'DFI'
       when 'PDFI' then 'PFI'
       else 'PFI'                                        //default falue

  end                                     as char15 ) as MaterialRcptSourceType,

  case CompanyCodeVatParam.MatlRcptFinDateType
       when 'DDFI' then InvoiceFinAccDoc.DocumentDate
       when 'PDFI' then InvoiceFinAccDoc.PostingDate
       else InvoiceFinAccDoc.PostingDate                            //default falue

  end                                                 as MaterialReceiptDate
}
where
      InvoiceFinAccDoc.ReferenceDocumentType <> 'RMRP'
  and InvoiceFinAccDoc.ReferenceDocumentType <> 'CF3PM'
  and InvoiceFinAccDoc.ReferenceDocumentType <> 'MKPF'
  and InvoiceFinAccDoc.ReferenceDocumentType <> 'CF3PG'

union all select from P_RU_MaterialRcptDateMM  as MatRcptMM

  left outer join     I_RU_CompanyCodeVatParam as CompanyCodeVatParam on StatryRptgEntity = $parameters.P_StatryRptgEntity

{
  MatRcptMM.CompanyCode,
  MatRcptMM.AccountingDocument,
  MatRcptMM.FiscalYear,
  MatRcptMM.Plant,
  ''  as ReferenceDocumentType,
  MatRcptMM.InvoiceDocumentDate,
  MatRcptMM.InvoicePostingDate,
  MatRcptMM.MaterialRcptPostingDate,

  case CompanyCodeVatParam.MatlRcptMatlMgmtDateType
       when 'DMIGO'  then MatRcptMM.MaterialRcptSourceType
       when 'DDMIRO' then 'DMIRO'
       when 'PDMIRO' then 'PMIRO'
       else MatRcptMM.MaterialRcptSourceType                        //default falue

  end as MaterialRcptSourceType,

  case CompanyCodeVatParam.MatlRcptMatlMgmtDateType
       when 'DMIGO'  then MatRcptMM.MaterialRcptPostingDate
       when 'DDMIRO' then MatRcptMM.InvoiceDocumentDate
       when 'PDMIRO' then MatRcptMM.InvoicePostingDate
       else MatRcptMM.MaterialRcptPostingDate                       //default falue

  end as MaterialReceiptDate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"I_RU_COMPANYCODEVATPARAM",
"P_RU_MATERIALRCPTDATEMM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/