P_RU_FinStmMaterialDocument

@AbapCatalog.sqlViewName: 'PRUFSTMMATDOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_RU_FinStmMaterialDocument

  with parameters
    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id

  as select from matdoc  as materialDoc --distinct is needed bacause in T156W we have more then one record. But not allowed in basic views

    -- Report RM07MLBD -> FORM belege_ergaenzen -> READ TABLE it156w
    join         t156w   as valueString on  valueString.bustw = materialDoc.bustw
                                        and valueString.xbgbb = valueString.xauto
                                        and valueString.vorsl = 'BSX' --FI DOC KTOSL = 'BSX'

    join         I_Plant as plant       on plant.Plant = materialDoc.werks
    
    join I_RU_FinStmntStockValuation as material on ( material.Material = materialDoc.matnr
                                                  and material.ValuationArea = plant.ValuationArea
                                                  and material.StatryRptCategory = $parameters.P_StatryRptCategory
                                                  and material.StatryRptgEntity = $parameters.P_StatryRptgEntity
                                                  and material.StatryRptRunID = $parameters.P_StatryRptRunID )

{
  materialDoc.mblnr   as MaterialDocument,
  materialDoc.mjahr   as MaterialDocumentYear,
  materialDoc.zeile   as MaterialDocumentItem,

  materialDoc.matnr   as Material,
  plant.ValuationArea as ValuationArea,
  materialDoc.bwtar   as InventoryValuationType,
  materialDoc.werks   as Plant,

  cast(
      case materialDoc.shkzg
        when 'H' then
          materialDoc.dmbtr * -1
        else
          materialDoc.dmbtr
      end
  as dmbtr_shl )      as TotalAmountInLocalCurrency,

  materialDoc.werks   as Currency,

  cast(
      case materialDoc.shkzg
        when 'H' then
          materialDoc.menge * -1
        else
          materialDoc.menge
      end
  as menge13 )        as Quantity,

  materialDoc.meins   as MaterialBaseUnit,
  materialDoc.budat   as PostingDate
}
where  
  ( materialDoc.sobkz = '' or materialDoc.sobkz = 'E' or materialDoc.sobkz = 'O' or materialDoc.sobkz = 'Q' or materialDoc.sobkz = 'V' or materialDoc.sobkz = 'W' )
  
    --Consumption Posting MB5B->RM07MLBD->kontiert_aussortieren
    and
      (
        ( materialDoc.kzvbr <> 'V' and materialDoc.kzvbr <> 'A' )
        or (
                ( materialDoc.kzbew <> 'B' and materialDoc.kzbew <> 'F' ) -- B->Goods movement for purchase order / F->Goods movement for production order
              or
                ( materialDoc.mengu <> 'X' and materialDoc.wertu <> 'X' ) -- Quantity / Value Update in Material Master Record
           )
      )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"I_RU_FINSTMNTSTOCKVALUATION",
"MATDOC",
"T156W"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/