P_RU_CFinVatDocExtras

@AbapCatalog.sqlViewName: 'PRUCFINVATEXTRAS'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_RU_CFinVatDocExtras
  as select from I_Ru_VatDocExtras as VatDocExtras

{
  key VatDocExtras.CompanyCode,
  key VatDocExtras.AccountingDocument,
  key VatDocExtras.FiscalYear,

      cast( '          ' as logsystem_sender    preserving type ) as SenderLogicalSystem,
      cast( '    '       as bukrs_sender        preserving type ) as SenderCompanyCode,
      cast( '          ' as fis_belnr_sender    preserving type ) as SenderAccountingDocument,
      cast( '0000'       as gjahr_sender        preserving type ) as SenderFiscalYear,

      VatDocExtras.ExternalInvoice,
      VatDocExtras.InvoiceDate,
      VatDocExtras.ExternalPayment,
      VatDocExtras.PaymentDate,
      VatDocExtras.Supplier,
      VatDocExtras.Customer,
      VatDocExtras.RU_IncomingInvoiceNumber,
      VatDocExtras.RU_IncomingInvoiceDate
}
where
  VatDocExtras.SenderLogicalSystem = ''

union all select from I_Ru_VatDocExtras as VatDocExtras

  inner join          I_JournalEntry    as JournalEntry on  JournalEntry.SenderCompanyCode        = VatDocExtras.CompanyCode
                                                        and JournalEntry.SenderAccountingDocument = VatDocExtras.AccountingDocument
                                                        and JournalEntry.SenderFiscalYear         = VatDocExtras.FiscalYear
                                                        and JournalEntry.SenderLogicalSystem      = VatDocExtras.SenderLogicalSystem

{
  key JournalEntry.CompanyCode,
  key JournalEntry.AccountingDocument,
  key JournalEntry.FiscalYear,

      JournalEntry.SenderLogicalSystem,
      JournalEntry.SenderCompanyCode,
      JournalEntry.SenderAccountingDocument,
      JournalEntry.SenderFiscalYear,

      VatDocExtras.ExternalInvoice,
      VatDocExtras.InvoiceDate,
      VatDocExtras.ExternalPayment,
      VatDocExtras.PaymentDate,
      VatDocExtras.Supplier,
      VatDocExtras.Customer,
      VatDocExtras.RU_IncomingInvoiceNumber,
      VatDocExtras.RU_IncomingInvoiceDate
}
where
      VatDocExtras.SenderLogicalSystem <> ''
  and JournalEntry.SenderLogicalSystem <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"I_RU_VATDOCEXTRAS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/