P_RU_CFinVatCorRev

@AbapCatalog.sqlViewName: 'PRUCFINVATCR'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_RU_CFinVatCorRev
  as select from I_RU_VatCorrectionRevision

{
  key CompanyCode,
  key Invoice,
  key InvoiceYear,
  key CorrectionInvoice,
  key CorrectionInvoiceYear,
  key RevisionNumber,
      RevisionInvoice,
      RevisionInvoiceYear,

      SenderLogicalSystem,
      cast( '    '       as bukrs_sender        preserving type ) as SenderCompanyCode,
      cast( '          ' as fis_belnr_sender    preserving type ) as SenderInvoice,
      cast( '0000'       as gjahr_sender        preserving type ) as SenderInvoiceYear,
      cast( '          ' as fis_belnr_sender    preserving type ) as SenderCorrectionInvoice,
      cast( '0000'       as gjahr_sender        preserving type ) as SenderCorrectionInvoiceYear,
      cast( '          ' as fis_belnr_sender    preserving type ) as SenderRevisionInvoice,
      cast( '0000'       as gjahr_sender        preserving type ) as SenderRevisionInvoiceYear,

      RevisionInvoiceDate,
      RevisionTaxReportingDate,
      OriginalInvoiceRevisionNumber,
      OriginalInvoiceRevisionDate,

      CompanyCodeName,
      RU_CompanyCodeINN,
      RU_CompanyCodeKPP,
      BusinessPartnerName,
      RU_PartnerOrganizationINN,
      RU_PartnerOrganizationKPP,
      SupplierName,
      RU_SupplierINN,
      RU_SupplierKPP,
      RU_CommissionTradeSupplierName,
      RU_CommissionTradeSupplierINN,
      RU_CommissionTradeSupplierKPP,
      RU_CommissionTradeCustomerName,
      RU_CommissionTradeCustomerINN,
      RU_CommissionTradeCustomerKPP
}
where
  SenderLogicalSystem = ''

union all select from I_RU_VatCorrectionRevision as VatCorRev

  inner join          I_JournalEntry             as InvoiceDoc  on  InvoiceDoc.SenderLogicalSystem      =  VatCorRev.SenderLogicalSystem
                                                                and InvoiceDoc.SenderCompanyCode        =  VatCorRev.CompanyCode
                                                                and InvoiceDoc.SenderAccountingDocument =  VatCorRev.Invoice
                                                                and InvoiceDoc.SenderFiscalYear         =  VatCorRev.InvoiceYear
                                                                and InvoiceDoc.SenderLogicalSystem      <> ''

  left outer join     I_JournalEntry             as CorrectDoc  on  CorrectDoc.SenderLogicalSystem      =  VatCorRev.SenderLogicalSystem
                                                                and CorrectDoc.SenderCompanyCode        =  VatCorRev.CompanyCode
                                                                and CorrectDoc.SenderAccountingDocument =  VatCorRev.CorrectionInvoice
                                                                and CorrectDoc.SenderFiscalYear         =  VatCorRev.CorrectionInvoiceYear
                                                                and VatCorRev.CorrectionInvoice         <> ''
                                                                and CorrectDoc.SenderLogicalSystem      <> ''

  left outer join     I_JournalEntry             as RevisionDoc on  RevisionDoc.SenderLogicalSystem      =  VatCorRev.SenderLogicalSystem
                                                                and RevisionDoc.SenderCompanyCode        =  VatCorRev.CompanyCode
                                                                and RevisionDoc.SenderAccountingDocument =  VatCorRev.RevisionInvoice
                                                                and RevisionDoc.SenderFiscalYear         =  VatCorRev.RevisionInvoiceYear
                                                                and VatCorRev.RevisionInvoice            <> ''
                                                                and RevisionDoc.SenderLogicalSystem      <> ''

{
  InvoiceDoc.CompanyCode                                                 as CompanyCode,
  InvoiceDoc.AccountingDocument                                          as Invoice,
  InvoiceDoc.FiscalYear                                                  as InvoiceYear,
  coalesce( CorrectDoc.AccountingDocument, VatCorRev.CorrectionInvoice ) as CorrectionInvoice,
  coalesce( CorrectDoc.FiscalYear, VatCorRev.CorrectionInvoiceYear )     as CorrectionInvoiceYear,
  VatCorRev.RevisionNumber                                               as RevisionNumber,
  coalesce( RevisionDoc.AccountingDocument, VatCorRev.RevisionInvoice )  as RevisionInvoice,
  coalesce( RevisionDoc.FiscalYear, VatCorRev.RevisionInvoiceYear )      as RevisionInvoiceYear,

  VatCorRev.SenderLogicalSystem                                          as SenderLogicalSystem,
  InvoiceDoc.SenderCompanyCode                                           as SenderCompanyCode,
  InvoiceDoc.SenderAccountingDocument                                    as SenderInvoice,
  InvoiceDoc.SenderFiscalYear                                            as SenderInvoiceYear,
  CorrectDoc.SenderAccountingDocument                                    as SenderCorrectionInvoice,
  CorrectDoc.SenderFiscalYear                                            as SenderCorrectionInvoiceYear,
  RevisionDoc.SenderAccountingDocument                                   as SenderRevisionInvoice,
  RevisionDoc.SenderFiscalYear                                           as SenderRevisionInvoiceYear,

  VatCorRev.RevisionInvoiceDate,
  VatCorRev.RevisionTaxReportingDate,
  VatCorRev.OriginalInvoiceRevisionNumber,
  VatCorRev.OriginalInvoiceRevisionDate,

  VatCorRev.CompanyCodeName,
  VatCorRev.RU_CompanyCodeINN,
  VatCorRev.RU_CompanyCodeKPP,
  VatCorRev.BusinessPartnerName,
  VatCorRev.RU_PartnerOrganizationINN,
  VatCorRev.RU_PartnerOrganizationKPP,
  VatCorRev.SupplierName,
  VatCorRev.RU_SupplierINN,
  VatCorRev.RU_SupplierKPP,
  VatCorRev.RU_CommissionTradeSupplierName,
  VatCorRev.RU_CommissionTradeSupplierINN,
  VatCorRev.RU_CommissionTradeSupplierKPP,
  VatCorRev.RU_CommissionTradeCustomerName,
  VatCorRev.RU_CommissionTradeCustomerINN,
  VatCorRev.RU_CommissionTradeCustomerKPP
}
where
  VatCorRev.SenderLogicalSystem <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"I_RU_VATCORRECTIONREVISION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/