P_RTPCOrderSettCstForRevLd

@AbapCatalog.sqlViewName: 'PFIRTPCORSCFRLD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label      : 'RTPC Order Settled Cost For Reversal with Parallel Ledgers'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
@VDM.private:true
define view P_RTPCOrderSettCstForRevLd
  as select from           acdoca         as a
    left outer to one join fins_acdoc_ref as _prec_ref on  a.awtyp          =  _prec_ref.prec_awtyp
                                                       and a.aworg          =  _prec_ref.prec_aworg
                                                       and a.awref          =  _prec_ref.prec_awref
                                                       and a.awitem         =  _prec_ref.prec_awitem
                                                       and a.subta          =  _prec_ref.prec_subta
                                                       and (
                                                          _prec_ref.objnr   =  ''
                                                          or(
                                                            _prec_ref.objnr <> ''
                                                            and a.objnr     =  _prec_ref.objnr
                                                          )
                                                        )

{

  a.rldnr                                          as lednr,
  aufnr,
  a.objnr,
  ryear                                            as gjahr,
  rbukrs,
  fiscyearper,
  belnr,
  docln,
  //  v.versn                                          as versn,

  '04'                                             as wrttp,
  racct                                            as kstar,
  ukostl                                           as kostl,
  ulstar                                           as lstar,
  hrkft,
  vrgng,
  case when parobsrc = '1' then parob1     else case
       when parobsrc = '2' then paccasty
       else ''                             end end as parob,
  uspob,
  rassc                                            as vbund,
  sbusa                                            as pargb,
  co_beknz                                         as beknz,
  rwcur                                            as twaer,
  rvunit                                           as meinh,
  bemot,
  beltp,

  bttype,

  awtyp,
  awref,
  awitem,
  aworg,
  awsys,
  subta,

  _prec_ref.prec_awmult                            as prec_awmult,
  hkgrp,

  wsl,
  wsl2,
  wsl3,
  hsl,
  ksl,
  osl,
  vsl,
  bsl,
  csl,
  dsl,
  esl,
  fsl,
  gsl,
  kfsl,
  kfsl2,
  kfsl3,
  psl,
  pfsl2,
  pfsl3,
  vmsl,
  vmfsl,
  co_osl
}

where
  (
       accasty  =  'OR'
    or accasty  =  'OP'
  )
  and(
       autyp    =  '10'
    or autyp    =  '40'
  )
  and  xsettled =  'X'
  and  bttype   <> 'TBCS' --ignore Transaction-Based Split
  and  bttype   <> 'EBWP' --ignore Event-Based WIP posting
  and  co_beknz <> 'A'    //exclude settlement line items

  //  and  aufnr    <> paufnr //exclude pre-settlement

  //and  co_belnr <> ''

  and  a.objnr  <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ACDOCA",
"FINS_ACDOC_REF"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/