P_RTPCOrderFxdPrcProdDlvrdCost

@AbapCatalog.sqlViewName: 'PFIRTPCFXDPRDGR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'RTPC Order Fixed Price CoProducts Delivered Cost'

@VDM.viewType: #BASIC
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view P_RTPCOrderFxdPrcProdDlvrdCost
  as select from acdoca   as _item
    inner join   afpo     as _afpo   on  _afpo.aufnr = _item.aufnr
                                     and _afpo.posnr = _item.aufps
                                     and _afpo.fxpru = 'X'
                                     and _afpo.matnr = _item.matnr
    inner join   I_Ledger as _ledger on  _ledger.Ledger     = _item.rldnr
                                     and _ledger.LedgerType = '' //standard ledger only

{
  key _item.aufnr as OrderID,
  key objnr       as ControllingObject,
  key aufps       as OrderItem,
  key rbukrs      as CompanyCode,
  key rldnr       as Ledger,
  key racct       as GLAccount,
  key co_beknz    as ControllingDebitCreditCode,
  key _item.matnr as Material,
  key fiscyearper as FiscalYearPeriod,

      rvunit      as ValuationUnit,
      runit       as Unit,

      xsettled    as IsSettled,
      xreversed   as IsReversed,
      
      budat       as PostingDate,
      timestamp,

      hsl,
      ksl,
      osl,
      vsl,
      bsl,
      csl,
      dsl,
      esl,
      fsl,
      gsl,
      kfsl,
      vmsl,
      msl
}
where
       accasty  =  'OP'
  and  ktosl    =  'GBB'
  and  co_beknz =  'L'
  and  bttype   <> 'TBCS' --ignore Transaction-Based Split
  and(
       autyp    =  '10'
    or autyp    =  '40'
  )
  and  objnr    <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGER",
"ACDOCA",
"AFPO"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/