P_RTPCOrderBalance

@AbapCatalog.sqlViewName: 'PRTPCORDBALC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Event-based Order's order balance'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.preserveKey:true

define view P_RTPCOrderBalance
  as select from acdoca   as _item
    inner join   I_Ledger as _ledger on  _ledger.Ledger     = _item.rldnr
    //and _ledger.IsLeadingLedger = 'X'  //support only leading leader in CE2005

                                     and _ledger.LedgerType = '' //standard ledger only

{

  key aufnr                 as OrderID,
  key kokrs                 as ControllingArea,
  key rldnr                 as Ledger,
      fiscyearper           as FiscalYearPeriod,



      sum(hsl)              as AmountInCompanyCodeCurrency,
      sum(ksl)              as AmountInGlobalCurrency,
      sum(osl)              as AmountInFreeDefinedCurrency1,
      sum(vsl)              as AmountInFreeDefinedCurrency2,
      sum(bsl)              as AmountInFreeDefinedCurrency3,
      sum(csl)              as AmountInFreeDefinedCurrency4,
      sum(dsl)              as AmountInFreeDefinedCurrency5,
      sum(esl)              as AmountInFreeDefinedCurrency6,
      sum(fsl)              as AmountInFreeDefinedCurrency7,
      sum(gsl)              as AmountInFreeDefinedCurrency8
}
where
  (
       _item.accasty  =  'OR'
    or _item.accasty  =  'OP'
  )
  and(
       _item.autyp    =  '10'
    or _item.autyp    =  '40'
  )
  and  _item.bttype   <> 'TBCS' //ignore TBCS posting

  and  _item.co_beknz <> ''

  and _item.objnr <> ''
  and (_item.ktosl    <> 'PRD' or _item.bttype <> 'EBVP')
group by
  aufnr,
  kokrs,
  rldnr,
  fiscyearper
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGER",
"ACDOCA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/