P_RTPCORDERPLANCOST

@AbapCatalog.sqlViewName: 'PFIRTPCORPLNCOST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'RTPC Order Plan Cost'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define view P_RTPCORDERPLANCOST
  as select from I_FinancialPlanningEntryItem          as _item
    inner join   I_MfgOrdPlngCat as _PlngCat on _item.PlanningCategory = _PlngCat.PlanningCategory
{
  key OrderID,
  key case AccountAssignmentType
        when 'OP' then concat( concat( 'OP', OrderID), OrderItem ) 
        else concat('OR', OrderID) 
      end      as ControllingObject,
  key AccountAssignmentType,
  key OrderItem       as OrderItem,
  key CompanyCode,
  key Ledger,
  key GLAccount,
  key ControllingDebitCreditCode,
  key Material,
  //key PartnerCostCenter       as OriginCostCenter,

  //key PartnerCostCtrActivityType      as OriginCostCenterActivityType,

  key  case OriginCostCenter
         when '' then PartnerCostCenter
         else OriginCostCenter
       end  as OriginCostCenter,
  key  case OriginCostCtrActivityType
         when '' then PartnerCostCtrActivityType
         else OriginCostCtrActivityType
       end  as OriginCostCenterActivityType,
  key IsLotSizeIndependent       as IsLotSzIndep,
  key CostOriginGroup,
  CostingLotSize,
  CostSourceUnit as Unit,
  
  

      sum( AmountInCompanyCodeCurrency )  as hsl,
      sum( AmountInGlobalCurrency )  as ksl,
      sum( AmountInFreeDefinedCurrency1 )  as osl,
      sum( AmountInFreeDefinedCurrency2 )  as vsl,
      sum( AmountInFreeDefinedCurrency3 )  as bsl,
      sum( AmountInFreeDefinedCurrency4 )  as csl,
      sum( AmountInFreeDefinedCurrency5 )  as dsl,
      sum( AmountInFreeDefinedCurrency6 )  as esl,
      sum( AmountInFreeDefinedCurrency7 )  as fsl,
      sum( AmountInFreeDefinedCurrency8 )  as gsl,
      sum( FixedAmountInGlobalCrcy ) as kfsl,
      sum( ValuationQuantity ) as vmsl
}
where
  (
       AccountAssignmentType                     = 'OR'
    or AccountAssignmentType                     = 'OP'
  )
  and  PlngCatIsForOrdReltdPlnCost = 'X'
group by
  OrderID,
  AccountAssignmentType,
  OrderItem,
  CompanyCode,
  Ledger,
  GLAccount,
  ControllingDebitCreditCode,
  Material,
  PartnerCostCenter,
  PartnerCostCtrActivityType,
  OriginCostCenter,
  OriginCostCtrActivityType,
  IsLotSizeIndependent,
  CostingLotSize,
  CostSourceUnit,
  CostOriginGroup
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALPLANNINGENTRYITEM",
"I_MFGORDPLNGCAT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/