P_RSHOperationsPerWorkcenter

@AbapCatalog.sqlViewName: 'PRSHOPSPERWC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Operations on Workcenters for certain time frame'

define view P_RSHOperationsPerWorkcenter
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum

  as select from            P_RSHOperationWorkDetails( P_StartDate : $parameters.P_StartDate, P_EndDate : $parameters.P_EndDate ) as wdetail

    left outer to many join P_RSHOperationWorkPerDay( P_StartDate : $parameters.P_StartDate, P_EndDate : $parameters.P_EndDate )  as wpd             on  wpd.MaintenanceOrder             = wdetail.MaintenanceOrder
                                                                                                                                                     and wpd.MaintenanceOrderOperation    = wdetail.MaintenanceOrderOperation
                                                                                                                                                     and wpd.MaintenanceOrderSubOperation = wdetail.MaintenanceOrderSubOperation

    inner join              I_MaintOrderOperAndSubOper                                                                            as Operations      on  Operations.MaintenanceOrder             = wpd.MaintenanceOrder
                                                                                                                                                     and Operations.MaintenanceOrderOperation    = wpd.MaintenanceOrderOperation
                                                                                                                                                     and Operations.MaintenanceOrderSubOperation = wpd.MaintenanceOrderSubOperation

    inner join              I_MaintOrderOperPlanningValues                                                                        as OperationValues on  Operations.MaintOrderRoutingNumber    = OperationValues.MaintOrderRoutingNumber
                                                                                                                                                     and Operations.MaintOrderOperationCounter = OperationValues.MaintOrderOperationCounter

{

  key wpd.MaintenanceOrder,
  key wpd.MaintenanceOrderOperation,
  key wpd.MaintenanceOrderSubOperation,
  key Operations.MaintOrderRoutingNumber,
  key Operations.MaintOrderOperationCounter,

      sum( wpd.WorkPerDay )                                    as WorkPerPeriod,
      wpd.CalendarDate,
      wdetail.WorkCenter,
      wdetail.WorkCenterInternalID,

      wdetail.PlannedStartDate,
      wdetail.PlannedStartTime,
      wdetail.PlannedEndDate,
      wdetail.PlannedEndTime,
      wdetail.LatestAcceptableCompletionDate,
      ' '                                                      as Was_Simulated_Earlier,
      'X'                                                      as Exists_in_Period,

      wpd.ProcessingStatus,

      cast( unit_conversion(
         QUANTITY =>  OperationValues.OperationDuration,
         SOURCE_UNIT =>  OperationValues.OperationDurationUnit,
         TARGET_UNIT => cast( 'S' as abap.unit(3) ),
         ERROR_HANDLING => 'SET_TO_NULL' ) as abap.dec(24,0) ) as OperationDuration,

      'S'                                                      as OperationDurationUnit,

      Operations.NumberOfCapacities,

      _MaintenanceOrder.MaintOrdBasicStartDate                 as BasicStartDate,
      _MaintenanceOrder.MaintOrdBasicEndDate                   as BasicEndDate,

      _MaintenanceOrder.MaintPriority                          as Priority,
      _MaintenanceOrder.MaintenanceOrderType                   as OrderType,

      Operations.MaintOperationExecStageCode                   as MaintOperationExecStageCode,

      Operations.MaintOrdOpProcessSubPhaseCode                 as MaintOrdOpProcessSubPhaseCode


}

group by
  wpd.CalendarDate,
  wpd.MaintenanceOrder,
  wpd.MaintenanceOrderOperation,
  wpd.MaintenanceOrderSubOperation,
  Operations.MaintOrderRoutingNumber,
  Operations.MaintOrderOperationCounter,
  //  wpd.WorkPerDay,

  wdetail.WorkCenter,
  wdetail.WorkCenterInternalID,
  wdetail.PlannedStartDate,
  wdetail.PlannedStartTime,
  wdetail.PlannedEndDate,
  wdetail.PlannedEndTime,
  wdetail.LatestAcceptableCompletionDate,
  wpd.ProcessingStatus,
  OperationDuration,
  OperationDurationUnit,
  NumberOfCapacities,
  _MaintenanceOrder.MaintOrdBasicStartDate,
  _MaintenanceOrder.MaintOrdBasicEndDate,
  _MaintenanceOrder.MaintPriority,
  _MaintenanceOrder.MaintenanceOrderType,
  Operations.MaintOperationExecStageCode,
  Operations.MaintOrdOpProcessSubPhaseCode
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDER",
"I_MAINTORDEROPERANDSUBOPER",
"I_MAINTORDEROPERPLANNINGVALUES",
"P_RSHOPERATIONWORKDETAILS",
"P_RSHOPERATIONWORKPERDAY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/