P_RO_StRpDeferredItem

@AbapCatalog.sqlViewName: 'PROVATDEFITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'RO: VAT 300 Deferred Items'
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.private: true
@VDM.viewType: #CONSUMPTION

define view P_RO_StRpDeferredItem  with parameters P_TaxReportingToDate : vatdate

  as select distinct from I_StRpTaxItemLog as strp
  
  left outer join P_DEFTAX_ITEM_3(P_TaxReportingToDate :$parameters.P_TaxReportingToDate) as dti on strp.CompanyCode = dti.CompanyCode and
                                           strp.AccountingDocument = dti.AccountingDocument and
                                           strp.FiscalYear = dti.FiscalYear and
                                           strp.TransactionTypeDetermination = dti.TransactionTypeDetermination and
                                           strp.TaxCode = dti.TaxCode //and

                                           //dti.TaxTransferDocument <> '' and

                                          //  dti.TaxTransferDocumentYear =  strp.FiscalYear

                                           
  left outer join P_DEFTAX_ITEM_2 as trdti on strp.CompanyCode = trdti.CompanyCode and   
                                              strp.AccountingDocument = trdti.TaxTransferDocument and
                                              strp.FiscalYear = trdti.TaxTransferDocumentYear
                                   
  left outer join I_OperationalAcctgDocItem as oadi on strp.CompanyCode = oadi.CompanyCode and
                                                       strp.AccountingDocument = oadi.AccountingDocument and
                                                       strp.FiscalYear = oadi.FiscalYear and
                                                       ( strp.TaxCode = oadi.TaxCode or oadi.TaxCode = '**' ) and
                                                       ( oadi.FinancialAccountType = 'K' or oadi.FinancialAccountType = 'D' )                                                       

{
  key strp.CompanyCode,
  key strp.AccountingDocument,
  key strp.FiscalYear,
  key StatryRptgEntity,
  key StatryRptCategory,
  key StatryRptRunID,
  key strp.TaxCode,
  key strp.TransactionTypeDetermination,
  key ValidFrom,
  key TaxBoxStructureType,
  
      strp.PostingDate,
      strp.DocumentDate,
      TaxReportingDate,
      ReportingDate,
      strp.FiscalPeriod,
      strp.AccountingDocumentType,
      DocumentReferenceID,
      CompanyCodeCountry,
      ReportingCountry,
      TaxReturnCountry,
      ExchangeRate,
      TaxRate,
      strp.GLAccount,
      strp.BusinessPlace,
      strp.TaxJurisdiction,
      LowestLevelTaxJurisdiction,
      TaxNumber1,
      TaxNumber2,
      TaxNumber3,
      BusinessPartner,
      BusinessPartnerName,
      oadi.VATRegistration,
      CustomerSupplierAddress,
      strp.TaxType,
      TargetTaxCode,
      oadi.ClearingDate,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'ClearingJournalEntry'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntry'
      oadi.ClearingAccountingDocument,
      @Analytics.internalName: #LOCAL
      oadi.ClearingJournalEntry,
      @Semantics.currencyCode:true
      ReportingCurrency,
      
      case
        when TargetTaxCode is not initial
          then concat(strp.CompanyCode, concat('/',concat(strp.AccountingDocument,concat('/',strp.FiscalYear))))
        else concat(strp.CompanyCode, concat('/',concat(trdti.AccountingDocument,concat('/',trdti.FiscalYear))))
      end as SortingNumber,
      
      TaxDeclnAmountType,
      
      //NonEligibleBaseAmount

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      case 
        when TaxDeclnAmountType = 'B' and CompanyCodeCountry = ReportingCountry
          then AmountInReportingCurrency - coalesce(dti.PartialBaseAmtInLocalCrcy,0)
        when TaxDeclnAmountType = 'B'
          then AmountInReportingCurrency - coalesce(dti.PartialBaseAmtInNationalCrcy,0)
        else
          0
      end as  TaxBox33AmtInReportingCurrency,
      
      //NonEligibleVatAmount

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      case 
        when TaxDeclnAmountType = 'T' and CompanyCodeCountry = ReportingCountry
          then AmountInReportingCurrency - coalesce(dti.PartialTaxAmtInLocalCrcy,0)
        when TaxDeclnAmountType = 'T'
          then AmountInReportingCurrency - coalesce(dti.PartialTaxAmtInNationalCrcy,0)
        else
          0
      end as  TaxBox34AmtInReportingCurrency,
      
      AmountInReportingCurrency,
      
      case
      //invoice - full payment

        when strp.TargetTaxCode is not initial
          then  oadi.ClearingJournalEntry
      //transfer document

        when strp.TargetTaxCode is initial
          then trdti.PaymentAccountingDocument
        else ''
      end as PaymentDocument,
      
      case
      //invoice - full payment

        when strp.TargetTaxCode is not initial
          then  oadi.ClearingDate
      //transfer document

        when strp.TargetTaxCode is initial
          then trdti.PaymentPostingDate
        else ''
      end as PaymentDate

}
where
      TaxBox <> ''  and
      ReportingCountry =  'RO'  and
      TargetTaxCode <> '' and
      ( TaxDeclnAmountType = 'T' or TaxDeclnAmountType = 'B' )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OPERATIONALACCTGDOCITEM",
"I_STRPTAXITEMLOG",
"P_DEFTAX_ITEM_2",
"P_DEFTAX_ITEM_3"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/