P_RO_SAFTPaymentHeader

@AbapCatalog.sqlViewName: 'PROSAFTPAYHDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_RO_SAFTPaymentHeader
  with parameters
    P_AlternativeGLAccountIsUsed : saft_ro_alt_gl_account_flag,
    P_UserSystemIdentifier       : sysid

  // PaymentMapping to GL Account

  as select from C_RO_SAFTJournalEntryItemC(
                 P_AlternativeGLAccountIsUsed : $parameters.P_AlternativeGLAccountIsUsed,
                 P_VATRegistration : '' ) as Item

    join         I_RO_SAFTPaymentMapping  as PaymentMapping on PaymentMapping.CompanyCode               = Item.CompanyCode
                                                            and(
                                                              (
                                                                PaymentMapping.AccountingDocumentType   = Item.AccountingDocumentType
                                                                and(
                                                                  PaymentMapping.GLAccount              = Item.GLAccount
                                                                )
                                                                or(
                                                                  PaymentMapping.AccountingDocumentType = Item.AccountingDocumentType
                                                                  and PaymentMapping.GLAccount          is initial
                                                                  and Item.BusinessPartner              is not initial
                                                                )
                                                              )
                                                            )
    join         I_RO_SAFTAccountingItem  as AccountingItem on  AccountingItem.CompanyCode            = Item.CompanyCode
                                                            and AccountingItem.AccountingDocument     = Item.AccountingDocument
                                                            and AccountingItem.FiscalYear             = Item.FiscalYear
                                                            and AccountingItem.AccountingDocumentItem = Item.AccountingDocumentItem
    join         I_RO_SAFTPaymentMethod   as PaymentMethod  on  PaymentMethod.CompanyCode   = Item.CompanyCode
                                                            and PaymentMethod.PaymentMethod = AccountingItem.PaymentMethod


{
  key Item.SourceLedger,
  key Item.Ledger,
  key Item.CompanyCode,
  key Item.AccountingDocument,
  key Item.FiscalYear,
      Item.FiscalPeriod,
      Item.RO_SAFTJournalTransaction,
      Item.DocumentDate,
      max( PaymentMethod.RO_SAFTPaymentMethod ) as RO_SAFTPaymentMethod,
      Item.DocumentItemText,
      cast(concat( $parameters.P_UserSystemIdentifier,
        concat( concat( concat( '/', cast( $session.client as char3 )), '/' ) ,
        Item.AccountingDocument ) ) as text18)  as RO_SAFTSystemID,
      Item.AccountingDocCreatedByUser,
      Item.TransactionCurrency,
      sum( Item.AmountInTransactionCurrency )   as AmountInTransactionCurrency,
      Item.StatryRptCategory,
      Item.StatryRptgEntity,
      Item.StatryRptRunID,
      case $parameters.P_AlternativeGLAccountIsUsed
        when 'X' then ''
        else 'X'
      end                                       as AccountIsMatched,
      'X'                                       as ItemIsReportingRelevant
}
group by
  Item.SourceLedger,
  Item.Ledger,
  Item.CompanyCode,
  Item.AccountingDocument,
  Item.FiscalYear,
  Item.FiscalPeriod,
  Item.RO_SAFTJournalTransaction,
  Item.DocumentDate,
  Item.DocumentItemText,
  Item.AccountingDocCreatedByUser,
  Item.TransactionCurrency,
  Item.StatryRptCategory,
  Item.StatryRptgEntity,
  Item.StatryRptRunID

// PaymentMapping to Alternative GL Account

union select from C_RO_SAFTJournalEntryItemC(
                  P_AlternativeGLAccountIsUsed : $parameters.P_AlternativeGLAccountIsUsed,
                  P_VATRegistration : '' ) as Item

  join            I_RO_SAFTPaymentMapping  as PaymentMapping on PaymentMapping.CompanyCode               = Item.CompanyCode
                                                             and(
                                                               (
                                                                 PaymentMapping.AccountingDocumentType   = Item.AccountingDocumentType
                                                                 and(
                                                                   PaymentMapping.GLAccount              = Item.AlternativeGLAccount
                                                                   and Item.AlternativeGLAccount         is not initial
                                                                 )
                                                                 or(
                                                                   PaymentMapping.AccountingDocumentType = Item.AccountingDocumentType
                                                                   and PaymentMapping.GLAccount          is initial
                                                                   and Item.BusinessPartner              is not initial
                                                                 )
                                                               )
                                                             )
  join            I_RO_SAFTAccountingItem  as AccountingItem on  AccountingItem.CompanyCode            = Item.CompanyCode
                                                             and AccountingItem.AccountingDocument     = Item.AccountingDocument
                                                             and AccountingItem.FiscalYear             = Item.FiscalYear
                                                             and AccountingItem.AccountingDocumentItem = Item.AccountingDocumentItem
  join            I_RO_SAFTPaymentMethod   as PaymentMethod  on  PaymentMethod.CompanyCode   = Item.CompanyCode
                                                             and PaymentMethod.PaymentMethod = AccountingItem.PaymentMethod


{
  key Item.SourceLedger,
  key Item.Ledger,
  key Item.CompanyCode,
  key Item.AccountingDocument,
  key Item.FiscalYear,
      Item.FiscalPeriod,
      Item.RO_SAFTJournalTransaction,
      Item.DocumentDate,
      max( PaymentMethod.RO_SAFTPaymentMethod ) as RO_SAFTPaymentMethod,
      Item.DocumentItemText,
      cast(concat( $parameters.P_UserSystemIdentifier,
        concat( concat( concat( '/', cast( $session.client as char3 )), '/' ) ,
        Item.AccountingDocument ) ) as text18)  as RO_SAFTSystemID,
      Item.AccountingDocCreatedByUser,
      Item.TransactionCurrency,
      sum( Item.AmountInTransactionCurrency )   as AmountInTransactionCurrency,
      Item.StatryRptCategory,
      Item.StatryRptgEntity,
      Item.StatryRptRunID,
      $parameters.P_AlternativeGLAccountIsUsed  as AccountIsMatched,
      'X'                                       as ItemIsReportingRelevant
}
group by
  Item.SourceLedger,
  Item.Ledger,
  Item.CompanyCode,
  Item.AccountingDocument,
  Item.FiscalYear,
  Item.FiscalPeriod,
  Item.RO_SAFTJournalTransaction,
  Item.DocumentDate,
  Item.DocumentItemText,
  Item.AccountingDocCreatedByUser,
  Item.TransactionCurrency,
  Item.StatryRptCategory,
  Item.StatryRptgEntity,
  Item.StatryRptRunID
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_RO_SAFTJOURNALENTRYITEMC",
"I_RO_SAFTACCOUNTINGITEM",
"I_RO_SAFTPAYMENTMAPPING",
"I_RO_SAFTPAYMENTMETHOD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/