P_RO_SAFTPaymentDocument

@AbapCatalog.sqlViewName: 'PROSAFTPAYD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #NOT_REQUIRED
//UNUSED

define view P_RO_SAFTPaymentDocument
  with parameters
    P_AlternativeGLAccountIsUsed : saft_ro_alt_gl_account_flag
  as select from I_RO_SAFTPaymentMapping as PayMap
    inner join   I_JournalEntryItem      as Document on  PayMap.CompanyCode            = Document.CompanyCode
                                                     and PayMap.AccountingDocumentType = Document.AccountingDocumentType
                                                     and PayMap.GLAccount              = Document.GLAccount
{
  key Document.SourceLedger,
  key Document.CompanyCode,
  key Document.FiscalYear,
  key Document.AccountingDocument,
  key Document.Ledger,
  key Document.PostingDate,
  key case $parameters.P_AlternativeGLAccountIsUsed
        when 'X' then ''
        else 'X'
      end as AccountIsMatched,
      Document.AccountingDocumentCategory
}
where
  PayMap.GLAccount <> ''
group by
  Document.SourceLedger,
  Document.Ledger,
  Document.CompanyCode,
  Document.FiscalYear,
  Document.AccountingDocument,
  Document.PostingDate,
  Document.AccountingDocumentCategory


union all select from I_RO_SAFTPaymentMapping as PayMap
  inner join          I_JournalEntryItem      as Document on  PayMap.CompanyCode            = Document.CompanyCode
                                                          and PayMap.AccountingDocumentType = Document.AccountingDocumentType
                                                          and PayMap.GLAccount              = Document.AlternativeGLAccount

{
  key Document.SourceLedger,
  key Document.CompanyCode,
  key Document.FiscalYear,
  key Document.AccountingDocument,
  key Document.Ledger,
  key Document.PostingDate,
  key $parameters.P_AlternativeGLAccountIsUsed as AccountIsMatched,
      Document.AccountingDocumentCategory
}
where
  Document.AlternativeGLAccount <> '' and
  PayMap.GLAccount <> ''
group by
  Document.SourceLedger,
  Document.Ledger,
  Document.CompanyCode,
  Document.FiscalYear,
  Document.AccountingDocument,
  Document.PostingDate,
  Document.AccountingDocumentCategory
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYITEM",
"I_RO_SAFTPAYMENTMAPPING"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/