P_RFQEventTypes

@AbapCatalog.sqlViewName: 'PMMRFQEVTTYP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'RFQ based on Purchasing Document Type'
define view P_RFQEventTypes
  with parameters
    P_DisplayCurrency : displaycurrency,
    P_StartDate       : badat,
    P_EndDate         : badat,
    P_DateFunction    : datefunctionid
  as select from I_RequestForQuotation
  left outer join I_CalendarYear on I_CalendarYear.NumberOfDays =1
  
{
  key RequestForQuotation,
      // key Item.RequestForQuotationItem,

      _RFQBidder.Supplier    as Supplier,
      CompanyCode,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      CreatedByUser,
      CreationDate,

      QuotationLatestSubmissionDate,
      BindingPeriodValidityEndDate,
      LatestRegistrationDate,
      PurchasingOrganization,
      PurchasingGroup,
      DocumentCurrency,
       cast( currency_conversion(  amount  => TargetAmount,
                                      source_currency    => DocumentCurrency,
                                      target_currency    =>  :P_DisplayCurrency,
                                      exchange_rate_date => CreationDate,
                                      exchange_rate_type => 'M' ,
                                      error_handling     => 'FAIL_ON_ERROR'
                             )
                 as mm_a_sourcingtargetvalue )  as InternalSourcingValue,


      cast(0 as ktwrt)       as ExternalSourcingValue,

      cast(0 as ktwrt)       as ExternalPricingValue,

      RFQLifecycleStatus,
//      @Aggregation.referenceElement: ['RequestForQuotation']

//      @DefaultAggregation: #COUNT_DISTINCT

      cast( 1 as abap.int4)  as InternalSourcing,

      cast( 0  as abap.int4) as ExternalSourcing,

      cast( 0  as abap.int4) as ExternalPricing,
      cast (CONCAT(RequestForQuotation , PurchasingDocumentType) as char14) as UniqueIntSourcingRequest,
     cast (I_CalendarYear.NumberOfDays as char14) as UniqueExtSourcingRequest,
     cast (I_CalendarYear.NumberOfDays as char14) as UniqueExtPricingRequest
}
where
      PurchasingDocumentType = 'RQ'
  and CreationDate           <= $parameters.P_EndDate
  and CreationDate           >= $parameters.P_StartDate

union all select from I_RequestForQuotation
left outer join I_CalendarYear on I_CalendarYear.NumberOfDays =1
{
  key RequestForQuotation,
      // key Item.RequestForQuotationItem,

      _RFQBidder.Supplier     as Supplier,
      CompanyCode,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      CreatedByUser,
      CreationDate,
      QuotationLatestSubmissionDate,
      BindingPeriodValidityEndDate,
      LatestRegistrationDate,

      PurchasingOrganization,
      PurchasingGroup,
      DocumentCurrency,


      cast(0 as ktwrt)        as InternalSourcingValue,
      
      cast( currency_conversion(  amount  => TargetAmount,
                                       source_currency    => DocumentCurrency,
                                       target_currency    =>  :P_DisplayCurrency,
                                       exchange_rate_date => CreationDate,
                                       exchange_rate_type => 'M' ,
                                       error_handling     => 'FAIL_ON_ERROR'
                              )
                   as mm_a_sourcingtargetvalue ) as ExternalSourcingValue,

      cast(0 as ktwrt)        as ExternalPricingValue,
      RFQLifecycleStatus,

      cast( 0  as abap.int4 ) as InternalSourcing,
//      @Aggregation.referenceElement: ['RequestForQuotation']

//      @DefaultAggregation: #COUNT_DISTINCT

      cast( 1  as abap.int4 ) as ExternalSourcing,

      cast( 0  as abap.int4 ) as ExternalPricing,
      cast (I_CalendarYear.NumberOfDays as char14) as UniqueIntSourcingRequest,
      cast (CONCAT(RequestForQuotation , PurchasingDocumentType) as char14) as UniqueExtSourcingRequest,
     
     cast (I_CalendarYear.NumberOfDays as char14) as UniqueExtPricingRequest


}
where
      PurchasingDocumentType = 'RE'
  and CreationDate           <= $parameters.P_EndDate
  and CreationDate           >= $parameters.P_StartDate

union all select from I_RequestForQuotation
left outer join I_CalendarYear on I_CalendarYear.NumberOfDays =1
{
  key RequestForQuotation,
      // key Item.RequestForQuotationItem,

      _RFQBidder.Supplier     as Supplier,
      CompanyCode,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      CreatedByUser,
      CreationDate,
      QuotationLatestSubmissionDate,
      BindingPeriodValidityEndDate,
      LatestRegistrationDate,
      PurchasingOrganization,
      PurchasingGroup,
      DocumentCurrency,



      cast(0 as ktwrt)        as InternalSourcingValue,

      cast(0 as ktwrt)        as ExternalSourcingValue,
     
     cast( currency_conversion(  amount  => TargetAmount,
                                      source_currency    => DocumentCurrency,
                                      target_currency    =>  :P_DisplayCurrency,
                                      exchange_rate_date => CreationDate,
                                      exchange_rate_type => 'M' ,
                                      error_handling     => 'FAIL_ON_ERROR'
                             )
                  as mm_a_sourcingtargetvalue )  as ExternalPricingValue,


      RFQLifecycleStatus,

      cast( 0 as abap.int4 )  as InternalSourcing,

      cast( 0  as abap.int4 ) as ExternalSourcing,
//      @Aggregation.referenceElement: ['RequestForQuotation']

//      @DefaultAggregation: #COUNT_DISTINCT

      cast( 1  as abap.int4 ) as ExternalPricing,
       cast (I_CalendarYear.NumberOfDays as char14) as UniqueIntSourcingRequest,
     
     cast (I_CalendarYear.NumberOfDays as char14) as UniqueExtSourcingRequest,
      cast (CONCAT(RequestForQuotation , PurchasingDocumentType) as char14) as UniqueExtPricingRequest
}
where
      PurchasingDocumentType = 'RSI'
  and CreationDate           <= $parameters.P_EndDate
  and CreationDate           >= $parameters.P_StartDate
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARYEAR",
"I_REQUESTFORQUOTATION",
"I_RFQBIDDER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/