P_RFQBidderProposal

DDL: P_RFQBIDDERPROPOSAL SQL: PRFQBIDDERPRPSL Type: view BASIC

P_RFQBidderProposal is a Basic CDS View in SAP S/4HANA. It reads from 2 data sources (ekko, ekpo) and exposes 8 fields with key fields Material, Supplier, PurchasingOrganization. It has 1 association to related views.

2 data source(s) 8 fields

Data Sources (2)

SourceAliasJoin Type
ekko ekko from
ekpo ekpo inner

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Supplier _Supplier $projection.Supplier = _Supplier.Supplier

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName PRFQBIDDERPRPSL view
AbapCatalog.compiler.compareFilter true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
VDM.viewType #BASIC view
VDM.private true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY Material ekpo matnr
KEY Supplier ekko lifnr
KEY PurchasingOrganization ekko ekorg
SupplierName _Supplier SupplierName
NumberOfPurchaseOrderItems
LatestPurchaseOrderDate
AddressID _Supplier AddressID
DaysSinceLastOrder 
@AbapCatalog.sqlViewName: 'PRFQBIDDERPRPSL'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType : #BASIC
@VDM.private: true
@ObjectModel:
{
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #XL
}
define view P_RFQBidderProposal
  as select from ekko as ekko
    inner join   ekpo as ekpo on ekko.ebeln = ekpo.ebeln
  association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
{
  key  ekpo.matnr                                                                                         as Material,

  key  ekko.lifnr                                                                                         as Supplier,

  key  ekko.ekorg                                                                                         as PurchasingOrganization,

       _Supplier.SupplierName,

       count(*)                                                                                           as NumberOfPurchaseOrderItems,

       max(ekko.bedat)                                                                                    as LatestPurchaseOrderDate,

       _Supplier.AddressID                                                                                as AddressID,

       DATS_DAYS_BETWEEN( cast(max(ekko.bedat) as abap.dats ), cast($session.system_date as abap.dats ) ) as DaysSinceLastOrder
}

where
      ekko.bstyp        =  'F'
  and ekpo.loekz        =  ''
  and ekpo.matnr        <> ''
  and ekko.lifnr        <> ''
  and ekko.iseopblocked =  ''

group by
  ekko.lifnr,
  ekpo.matnr,
  ekko.ekorg,
  _Supplier.AddressID,
  _Supplier.SupplierName
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLIER",
"EKKO",
"EKPO"
],
"ASSOCIATED":
[
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More