P_PurchaseRequisition_Ovp

@AbapCatalog.sqlViewName: 'PPRDUEOVP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Purchase Requisition Due'
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST,#UNION]
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

define view P_PurchaseRequisition_Ovp                       //^3354856


  as select from    I_Purchaserequisitionitem      as ebn
    left outer to many join I_PurReqnOpnScheduleRlvnceBase as _PurDocListUuprBase      on  ebn.PurchaseRequisition     = _PurDocListUuprBase.PurchaseRequisition
                                                                               and ebn.PurchaseRequisitionItem = _PurDocListUuprBase.PurchaseRequisitionItem

  association [1..1] to I_PurchasingCategoryMatlGroup as _PurchasingCategoryMatlGroup on ebn.MaterialGroup = _PurchasingCategoryMatlGroup.MaterialGroup
{
  key   ebn.PurchaseRequisition,
  key   ebn.PurchaseRequisitionItem,
        ebn.PurchaseRequisitionItemText,
        concat(  ltrim(ebn.PurchaseRequisition, '0') ,
        concat('/',  ltrim(ebn.PurchaseRequisitionItem, '0')))                                              as FormattedPurRequisitionItem,

        @Semantics.unitOfMeasure: true
        BaseUnit,

        ebn.PurchaseRequisitionType,

        ebn.Plant,

        ebn.PurchasingOrganization,

        ebn.PurchasingGroup,

        Material,

        ebn.MaterialGroup,

        RequestedQuantity,

        PurReqnItemCurrency ,

        @Semantics.businessDate.to: true
        case
        when ebn.DeliveryDate = '' or ebn.DeliveryDate = '00000000'
        then '99991231'
        else ebn.DeliveryDate
        end                                                                                                 as DeliveryDate,

// **********************added due to abap exit in PR************************************

        @Semantics.businessDate.to: true
        case
        when ebn.DeliveryDate = '' or ebn.DeliveryDate = '00000000'
        then '99991231'
        else ebn.DeliveryDate
        end                                                                                                 as FirstDeliveryDate,

// **********************added due to abap exit in PR************************************


        _PurDocListUuprBase.DueDays,

      cast(PurchaseRequisitionPrice as abap.curr(21,5))                                                     as PurchaseRequisitionPrice,

      PurReqnPriceQuantity,

      ebn.PurchaseRequisitionReleaseDate,

        //additional 1608 fields

        Supplier,
        FixedSupplier,

        case
          when (ebn.ProcessingStatus = 'N' or (ebn.ProcessingStatus = 'B' and ebn.OrderedQuantity < ebn.RequestedQuantity))
            then ' '
          else 'X'
        end                                                                                                 as PurReqnHasFllwOnDoc,

        @ObjectModel.text.element: ['PurgCatName']
        @Consumption.labelElement: 'PurgCatName'
        _PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory                                 as PurchasingCategory,
        @Semantics.text: true
        _PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName                                        as PurgCatName

}
where
          ebn.IsDeleted             =  ''
  and(
          ebn.ProcessingStatus      =  'N'
    or    ebn.ProcessingStatus      =  'B'
    or    ebn.ProcessingStatus      =  'A'
  )
  and     ebn.ReleaseIsNotCompleted =  ''
  and     ebn.IsPurReqnBlocked      =  ''
  and     ebn.IsClosed              =  ''
  and(
    (
          ebn.IsPurReqnCmplt        =  'X'
      and ebn.PurReqnCmpltnsCat     =  'H'
    )
    or(
          ebn.IsPurReqnCmplt        <> 'X'
    )
  )
  and ebn.PurchasingDocumentItemCategory <> '9'
  and not( ebn.PurReqnOrigin = 'S' and ebn.ExtCompanyCodeForPurg <> '' ) //v3354856


/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEREQUISITIONITEM",
"I_PURCHASINGCATEGORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"I_PURREQNOPNSCHEDULERLVNCEBASE"
],
"ASSOCIATED":
[
"I_PURCHASINGCATEGORYMATLGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/