P_PurchaseRequisitionItm

@AbapCatalog.sqlViewName: 'PMMPURREQITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality:  #D
@ObjectModel.usageType.sizeCategory: #XL
@VDM.private : true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Purchase Requisition Item'
define view P_PurchaseRequisitionItm
  with parameters
    P_StartDate : budat,
    P_EndDate   : budat
  as select from I_Purchaserequisitionitem as RequisitionItem
    inner join   I_PurchaseOrderItem       as PurchaseOrderItem on  PurchaseOrderItem.PurchaseRequisition     = RequisitionItem.PurchaseRequisition
                                                                and PurchaseOrderItem.PurchaseRequisitionItem = RequisitionItem.PurchaseRequisitionItem

{

  key RequisitionItem.PurchaseRequisition,
  key RequisitionItem.PurchaseRequisitionItem,
  key PurchaseOrder,
  key PurchaseOrderItem,
      PurchaseRequisitionType,
      PurReqnReleaseStatus,
      Supplier,
      RequisitionItem.MaterialGroup,
      RequisitionItem.Material,
      RequisitionItem.Plant,
      CreatedByUser,
      RequisitionItem.CreationDate,
      ReleaseCode,
      PurchaseRequisitionStatus,
      ReleaseStrategy,
      PurReqnOrigin,
      PurchasingGroup,
      PurchasingOrganization,
      PurReqnSSPCatalog,
      RequisitionItem.CompanyCode,
      FixedSupplier,
      
      //Added for displaying PR value in document view

      RequisitionItem.BaseUnit,
      PurReqCreationDate,
      RequestedQuantity,
      PurReqnPriceQuantity,
      @Semantics.currencyCode: true
      PurReqnItemCurrency,
      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      //@DefaultAggregation: #NONE

      PurchaseRequisitionPrice,

      cast( case when PurReqnSSPCatalog = '' and RequisitionItem.Material = ''
                     then '02'
                 when RequisitionItem.Material != ''
                     then '03'
                 when PurReqnSSPCatalog != ''
                     then '01'
              end  as mm_a_pur_reqn_item_classfctn )                      as PurReqnItemClassification
              
}
where
  PurReqnOrigin                                    = 'S'
  and PurchaseOrderItem.PurchasingDocumentDeletionCode = ''
  and RequisitionItem.CreationDate                                     <= $parameters.P_EndDate
  and RequisitionItem.CreationDate                                     >= $parameters.P_StartDate
  and not(
          RequisitionItem.Material                   = ''
          and RequisitionItem.IsOutline              = 'X'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDERITEM",
"I_PURCHASEREQUISITIONITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/