P_PurchaseOrderHistory_Basic

@VDM.viewType: #BASIC
@VDM.private: true

@AbapCatalog.sqlViewName: 'PPOHISTB'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_UserContactCard']
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

define view P_PurchaseOrderHistory_Basic
  as select from ekbe            as ekbe

    inner join   I_PurchaseOrder as _PurchaseOrder on ekbe.ebeln = _PurchaseOrder.PurchaseOrder

  association [1..1] to I_PurchaseOrderHistCategory as _PurchaseOrderHistCategory on  $projection.PurchaseOrderHistCategory = _PurchaseOrderHistCategory.PurchaseOrderHistCategory
  association [1..1] to I_PurchaseOrderItem         as _PurchaseOrderItem         on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                                  and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [1..1] to I_UserContactCard           as _UserContactCard           on  $projection.CreatedByUser = _UserContactCard.ContactCardID


{
  key cast( ekbe.ebeln as vdm_purchaseorder )                   as PurchaseOrder,
  key cast( ekbe.ebelp as vdm_purchaseorderitem )               as PurchaseOrderItem,
  key ekbe.zekkn                                                as AccountAssignmentNumber,
  key ekbe.vgabe                                                as PurchaseOrderTransactionType,
  key ekbe.gjahr                                                as MaterialDocumentYear,
  key ekbe.belnr                                                as MaterialDocument,
  key ekbe.buzei                                                as MaterialDocumentItem,
      ekbe.bewtp                                                as PurchaseOrderHistCategory,
      _PurchaseOrderHistCategory.SubsequentDebitCreditIsAllowed as SubsequentDebitCreditIsAllowed,
      ekbe.bwart                                                as GoodsMovementType,
      ekbe.budat                                                as PostingDate,
      ekbe.waers                                                as Currency,
      ekbe.shkzg                                                as DebitCreditCode,
      ekbe.elikz                                                as IsCompletelyDelivered,
      ekbe.lfgja                                                as ReferenceDocumentFiscalYear,
      ekbe.lfbnr                                                as ReferenceDocument,
      ekbe.lfpos                                                as ReferenceDocumentItem,
      ekbe.matnr                                                as Material,
      ekbe.werks                                                as Plant,
      ekbe.bldat                                                as DocumentDate,
      ekbe.ernam                                                as CreatedByUser,
      ekbe.bwtar                                                as InventoryValuationType,
      ekbe.xblnr                                                as DocumentReferenceID,
      ekbe.lsmeh                                                as DeliveryQuantityUnit,
      ekbe.cpudt                                                as AccountingDocumentCreationDate,
      ekbe.menge                                                as Quantity,
      ekbe.dmbtr                                                as PurOrdAmountInCompanyCodeCrcy,
      ekbe.wrbtr                                                as PurchaseOrderAmount,
      ekbe.bpmng                                                as QtyInPurchaseOrderPriceUnit,
      ekbe.arewr                                                as GRIRAcctClrgAmtInCoCodeCrcy,
      ekbe.wesbs                                                as GdsRcptBlkdStkQtyInOrdQtyUnit,
      ekbe.bpwes                                                as GdsRcptBlkdStkQtyInOrdPrcUnit,
      ekbe.reewr                                                as InvoiceAmtInCoCodeCrcy,
      ekbe.refwr                                                as InvoiceAmountInFrgnCurrency,
      ekbe.lsmng                                                as QuantityInDeliveryQtyUnit,
      ekbe.areww                                                as GRIRAcctClrgAmtInTransacCrcy,
      ekbe.bamng                                                as QuantityInBaseUnit,
      ekbe.arewb                                                as GRIRAcctClrgAmtInOrdTrnsacCrcy,
      ekbe.rewrb                                                as InvoiceAmtInPurOrdTransacCrcy,
      ekbe.wesbb                                                as VltdGdsRcptBlkdStkQtyInOrdUnit,
      ekbe.bpweb                                                as VltdGdsRcptBlkdQtyInOrdPrcUnit,
      ekbe.kudif                                                as ExchangeRateDifferenceAmount,
     
      _PurchaseOrderItem,
      _PurchaseOrderHistCategory,
      _UserContactCard,
      @Consumption.hidden: true
      _PurchaseOrder._Supplier.AuthorizationGroup //GDPR Supplier Authorization


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDER",
"I_PURCHASEORDERHISTCATEGORY",
"I_SUPPLIER",
"EKBE"
],
"ASSOCIATED":
[
"I_PURCHASEORDERHISTCATEGORY",
"I_PURCHASEORDERITEM",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/