P_PurReqnProcFlowResvn

@VDM.private: true
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PPURREQNPFRSVN'

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@DataAging.noAgingRestriction:true

define view P_PurReqnProcFlowResvn as

 //PR-->Reservation

  select from I_Purchaserequisitionitem as purReqnItem
  association [1..*] to I_ReservationItem  as _rsItem   // Note 2930000

                     on  $projection.PurchaseRequisition     = _rsItem.PurchaseRequisition
                     and $projection.PurchaseRequisitionItem = _rsItem.PurchaseRequisitionItem
{
    key purReqnItem.PurchaseRequisition           as PrecedingDocument,
    key purReqnItem.PurchaseRequisitionItem       as PrecedingDocumentItem,

    key purReqnItem.Reservation                   as SubsequentDocument,
    key cast( _rsItem.ReservationItem as char5 )   as SubsequentDocumentItem,

    cast( 'B'  as ebstyp)                         as PrecedingDocumentCategory,
    cast( 'V'  as ebstyp)                         as SubsequentDocumentCategory,

    cast('' as mjahr) as MaterialDocumentYear,
    cast('' as bukrs) as CompanyCode,

  //For Filtering

    purReqnItem.PurchaseRequisition               as PurchaseRequisition,
    purReqnItem.PurchaseRequisitionItem           as PurchaseRequisitionItem,
    _rsItem.RecordType                             as RecordType
}
where purReqnItem.Reservation != '0000000000'

union all

//Reservation-->Goods Issue (GR)

  select from I_Purchaserequisitionitem as purReqn
   inner join I_MaterialDocumentRecord  as matDoc
                 on purReqn.Reservation =  matDoc.Reservation
   association [1..*] to I_ReservationItem  as _rsItem   // Note 2930000

                     on  $projection.PurchaseRequisition     = _rsItem.PurchaseRequisition
                     and $projection.PurchaseRequisitionItem = _rsItem.PurchaseRequisitionItem

{
  key purReqn.Reservation                       as PrecedingDocument,
  key cast( _rsItem.ReservationItem as char5 )   as PrecedingDocumentItem,

  key matDoc.MaterialDocument                   as SubsequentDocument,
  key cast( matDoc.MaterialDocumentItem as char5 ) as SubsequentDocumentItem,

  cast( 'V'  as ebstyp)                         as PrecedingDocumentCategory,
  cast( '1'  as ebstyp)                         as SubsequentDocumentCategory,

  matDoc.MaterialDocumentYear,
  matDoc.CompanyCode,

  //For Filtering

  purReqn.PurchaseRequisition           as PurchaseRequisition,
  purReqn.PurchaseRequisitionItem       as PurchaseRequisitionItem,
  _rsItem.RecordType                     as RecordType

}
where purReqn.Reservation != '0000000000'
and   matDoc.Reservation  != '0000000000'
and   matDoc.MaterialDocumentRecordType = 'MDOC' //Material Document

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD",
"I_PURCHASEREQUISITIONITEM",
"I_RESERVATIONITEM"
],
"ASSOCIATED":
[
"I_RESERVATIONITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/