P_PurOrdMaintainHeaderAll

// =========================================================================

//   PO Maintenance: Purchase Order Headers (Active + Draft)

// =========================================================================


@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AbapCatalog.sqlViewName: 'PPOMAINTHDRALL'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_PurOrdMaintainHeaderAll
     as select from P_PurOrdMaintainHeaderActive as active 

        association [0..1] to I_Supplier                     as active_supplier             on $projection.Supplier               = active_supplier.Supplier
        association [0..1] to I_Supplier                     as active_invparty             on $projection.InvoicingParty         = active_invparty.Supplier
        association [0..1] to I_PurchasingOrganization       as active_ekorg                on $projection.PurchasingOrganization = active_ekorg.PurchasingOrganization
        association [0..1] to I_PurchasingGroup              as active_ekgrp                on $projection.PurchasingGroup        = active_ekgrp.PurchasingGroup
        association [1..1] to I_CompanyCode                  as active_t001                 on $projection.CompanyCode            = active_t001.CompanyCode
        association [1..1] to P_PurOrdMaintainHeaderActCalFs as active_POHeaderCalFields    on $projection.PurchaseOrder          = active_POHeaderCalFields.PurchaseOrder
        association [0..1] to P_PurOrdMaintainHeaderDraft    as draft_header                on $projection.PurchaseOrder          = draft_header.PurchaseOrder 

     {
      key cast(CONCAT(':',REPLACE(REPLACE(active.PurchaseOrder,'~','~~'),':','~:'))  as abap.char(32)) as ID,
      key                                                                         active.PurchaseOrder as PurchaseOrder,
      key                                                                    cast('' as abap.char(32)) as PurchaseOrderHeaderDraftUUID,
                                                          hextobin('00000000000000000000000000000000') as DraftUUID,      
                                                                     active.PurchasingDocumentCategory as PurchasingDocumentCategory,
                                                                         active.PurchasingDocumentType as PurchasingDocumentType,
                                                                                    active.CompanyCode as CompanyCode,
                                                                           active_t001.CompanyCodeName as CompanyCodeName,  
                                                                         active.PurchasingOrganization as PurchasingOrganization,
                                                               active_ekorg.PurchasingOrganizationName as PurchasingOrganizationName,      
                                                                                active.PurchasingGroup as PurchasingGroup,
                                                                      active_ekgrp.PurchasingGroupName as PurchasingGroupName,
                                                                                       active.Supplier as Supplier,
                                                                          active_supplier.SupplierName as SupplierName,
                                                @Semantics.amount.currencyCode: true   active.Currency as Currency,
                                                                                   active.PaymentTerms as PaymentTerms,
                                                                              active.CashDiscount1Days as CashDiscount1Days,
                                                                              active.CashDiscount2Days as CashDiscount2Days,
                                                                                 active.NetPaymentDays as NetPaymentDays,
                                                                           active.CashDiscount1Percent as CashDiscount1Percent,
                                                                           active.CashDiscount2Percent as CashDiscount2Percent,      
                                                                                   active.ExchangeRate as ExchangeRate,
                                                                       active.IncotermsClassification  as IncotermsClassification,
                                                                      active.IncotermsTransferLocation as IncotermsTransferLocation,
                                                                               active.IncotermsVersion as IncotermsVersion,
                                                                             active.IncotermsLocation1 as IncotermsLocation1,
                                                                             active.IncotermsLocation2 as IncotermsLocation2,
                                                                                  active.CreatedByUser as CreatedByUser,
                                                                              active.PurchaseOrderDate as PurchaseOrderDate,
                                                                             active.LastChangeDateTime as LastChangeDateTime,
                                                                                 active.LastChangeUser as LastChangeUser,  
                                                                                 active.InvoicingParty as InvoicingParty,
                                                                          active_invparty.SupplierName as InvoicingPartyName,
                                                                          active.ReleaseIsNotCompleted as ReleaseIsNotCompleted,
                                                                                         active.IsHeld as IsHeld,
                                                                active_POHeaderCalFields.NumberOfItems as NumberOfItems, 
                                                                     active_POHeaderCalFields.NetValue as PurchaseOrderNetAmount,
                                                     active_POHeaderCalFields.PurchasingDocumentStatus as PurchasingDocumentStatus,
                                                                                      active.EditState as EditState,
                                                                              cast('' as abap.char(1)) as IsDraft,
                                                                                        active.HasTwin as HasTwin,
                                                             draft_header.PurchaseOrderHeaderDraftUUID as TwinPurchaseOrderHdrDraftUUID,
                                                   hextobin(draft_header.PurchaseOrderHeaderDraftUUID) as TwinUUID,                               
                                                                    active.PurchasingDocumentCondition as PurchasingDocumentCondition,
                                                                               active.PricingProcedure as PricingProcedure,  
                                                                                     active.AddressID  as AddressID,
                                                                                   active.AddressName  as AddressName,    
                                                                             active.AddressStreetName  as AddressStreetName,
                                                                            active.AddressHouseNumber  as AddressHouseNumber,
                                                                             active.AddressPostalCode  as AddressPostalCode,
                                                                               active.AddressCityName  as AddressCityName,
                                                                            active.AddressPhoneNumber  as AddressPhoneNumber,
                                                                              active.AddressFaxNumber  as AddressFaxNumber,         
                                                                                 active.AddressRegion  as AddressRegion,    
                                                                                active.AddressCountry  as AddressCountry,
                                                                 active.AddressCorrespondenceLanguage  as AddressCorrespondenceLanguage,
                                                                 cast('X' as abap.char(1))             as IsActiveEntity,
                                                                 IsEndOfPurposeBlocked                 as IsEndOfPurposeBlocked                  

     }

     union all select from P_PurOrdMaintainHeaderDraft as draft 

        association [0..1] to I_Supplier                     as draft_supplier          on $projection.Supplier                     = draft_supplier.Supplier
        association [0..1] to I_Supplier                     as draft_invparty          on $projection.InvoicingParty               = draft_invparty.Supplier
        association [0..1] to I_PurchasingOrganization       as draft_ekorg             on $projection.PurchasingOrganization       = draft_ekorg.PurchasingOrganization    
        association [0..1] to I_PurchasingGroup              as draft_ekgrp             on $projection.PurchasingGroup              = draft_ekgrp.PurchasingGroup   
        association [1..1] to I_CompanyCode                  as draft_t001              on $projection.CompanyCode                  = draft_t001.CompanyCode 
        association [1..1] to P_PurOrdMaintainHeaderDrfCalFs as draft_POHeaderCalFields on $projection.PurchaseOrderHeaderDraftUUID = draft_POHeaderCalFields.PurchaseOrderHeaderDraftUUID
                
     {
      key cast(draft.PurchaseOrderHeaderDraftUUID as abap.char(32))                    as ID,
      key                                                          draft.PurchaseOrder as PurchaseOrder,
      key                                           draft.PurchaseOrderHeaderDraftUUID as PurchaseOrderHeaderDraftUUID,
                                          hextobin(draft.PurchaseOrderHeaderDraftUUID) as DraftUUID,      
                                                      draft.PurchasingDocumentCategory as PurchasingDocumentCategory,
                                                          draft.PurchasingDocumentType as PurchasingDocumentType,
                                                                     draft.CompanyCode as CompanyCode,
                                                            draft_t001.CompanyCodeName as CompanyCodeName,        
                                                          draft.PurchasingOrganization as PurchasingOrganization,
                                                draft_ekorg.PurchasingOrganizationName as PurchasingOrganizationName,
                                                                 draft.PurchasingGroup as PurchasingGroup,
                                                       draft_ekgrp.PurchasingGroupName as PurchasingGroupName,      
                                                                        draft.Supplier as Supplier,
                                                           draft_supplier.SupplierName as SupplierName,
                                @Semantics.amount.currencyCode: true    draft.Currency as Currency,
                                                                    draft.PaymentTerms as PaymentTerms,
                                                               draft.CashDiscount1Days as CashDiscount1Days,
                                                               draft.CashDiscount2Days as CashDiscount2Days,
                                                                  draft.NetPaymentDays as NetPaymentDays,
                                                            draft.CashDiscount1Percent as CashDiscount1Percent,
                                                            draft.CashDiscount2Percent as CashDiscount2Percent,       
                                                                    draft.ExchangeRate as ExchangeRate,
                                                        draft.IncotermsClassification  as IncotermsClassification,
                                                       draft.IncotermsTransferLocation as IncotermsTransferLocation,
                                                                draft.IncotermsVersion as IncotermsVersion,
                                                              draft.IncotermsLocation1 as IncotermsLocation1,
                                                              draft.IncotermsLocation2 as IncotermsLocation2,
                                                                   draft.CreatedByUser as CreatedByUser,
                                                               draft.PurchaseOrderDate as PurchaseOrderDate,
                                                              draft.LastChangeDateTime as LastChangeDateTime,  
                                                                  draft.LastChangeUser as LastChangeUser,        
                                                                  draft.InvoicingParty as InvoicingParty,
                                                           draft_invparty.SupplierName as InvoicingPartyName,
                                                           draft.ReleaseIsNotCompleted as ReleaseIsNotCompleted,
                                                                          draft.IsHeld as IsHeld,
                                                 draft_POHeaderCalFields.NumberOfItems as NumberOfItems, 
                                                      draft_POHeaderCalFields.NetValue as PurchaseOrderNetAmount,
                                                                                    '' as PurchasingDocumentStatus,
                                                            case draft.PurchaseOrder 
                                                              when '' then cast('1'  as abap.char(1)) 
                                                              else         cast('3'  as abap.char(1))
                                                            end                        as EditState,
                                                             cast('X' as abap.char(1)) as IsDraft,
                                                            case draft.PurchaseOrder 
                                                              when '' then cast(''  as abap.char(1))
                                                              else         cast('X' as abap.char(1))
                                                            end                        as HasTwin,                                                             
                                                           cast( '' as abap.char(32))  as TwinPurchaseOrderHdrDraftUUID,
                                          hextobin('00000000000000000000000000000000') as TwinUUID,                                                                                                                       
                                                     draft.PurchasingDocumentCondition as PurchasingDocumentCondition,
                                                                draft.PricingProcedure as PricingProcedure,       
                                                                       draft.AddressID as AddressID,           
                                                                     draft.AddressName as AddressName,    
                                                               draft.AddressStreetName as AddressStreetName,
                                                              draft.AddressHouseNumber as AddressHouseNumber,
                                                               draft.AddressPostalCode as AddressPostalCode,
                                                                 draft.AddressCityName as AddressCityName,
                                                              draft.AddressPhoneNumber as AddressPhoneNumber,
                                                                draft.AddressFaxNumber as AddressFaxNumber,          
                                                                   draft.AddressRegion as AddressRegion,    
                                                                  draft.AddressCountry as AddressCountry,
                                                   draft.AddressCorrespondenceLanguage as AddressCorrespondenceLanguage,
                                                   cast(' ' as abap.char(1))           as IsActiveEntity,
                                                   cast(' ' as abap.char(1))           as IsEndOfPurposeBlocked                     
     }
                                                         
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"P_PURORDMAINTAINHEADERACTCALFS",
"P_PURORDMAINTAINHEADERACTIVE",
"P_PURORDMAINTAINHEADERDRAFT",
"P_PURORDMAINTAINHEADERDRFCALFS"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"P_PURORDMAINTAINHEADERACTCALFS",
"P_PURORDMAINTAINHEADERDRAFT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/