P_PurOrdItmOverview

@AbapCatalog.sqlViewName: 'PPOITMOVW'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.usageType.serviceQuality: #P
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Purchase Order Item Overview'
define view P_PurOrdItmOverview
  as select from I_PurchaseOrderItem

  association [1..1] to P_PurOrdItemNextDeliveryCalc as _POItemNextDeliveryCalc on  _POItemNextDeliveryCalc.PurchaseOrder     = $projection.PurchaseOrder
                                                                                and _POItemNextDeliveryCalc.PurchaseOrderItem = $projection.PurchaseOrderItem                                                                              
{

  key PurchaseOrder,
  key PurchaseOrderItem,
      _PurchaseOrder.Supplier                                                                          as Supplier,
      _PurchaseOrder._Supplier.SupplierName                                                            as SupplierName,
      MaterialGroup,
      _PurchaseOrder.PurchasingGroup                                                                   as PurchasingGroup,
      Plant,
      cast('1' as numc1)                                                                               as ObjectType,
      Material,
      _PurchaseOrder.PurchasingOrganization                                                            as PurchasingOrganization,
      ServicePerformer,
      CostCenter,
      PurchaseOrder                                                                                    as PurchasingDocument,
      _PurchaseOrder.SupplyingPlant                                                                    as SupplyingPlant,
      PurchaseOrderItemText,
      AccountAssignmentCategory,

      //Work Package

      cast('' as /cpd/pfp_workitem_id)                                                                 as WorkItem,
      _PurchaseOrder.PurchaseOrderType                                                                 as PurchasingDocumentType,
      _PurgDocumentItemCategory._Text[1:Language=$session.system_language].PurgDocExternalItemCategory as PurgDocExternalItemCategory,
      _PurchaseOrder.PurchaseOrderType,

      case when (GoodsReceiptIsExpected <> 'X' or IsCompletelyDelivered = 'X' or PurchaseOrderItemCategory = 'A') then cast('00000000' as abap.dats)
          else _POItemNextDeliveryCalc.ScheduleLineDeliveryDate
      end                                                                                              as DeliveryDate
      

}
where
      PurchasingDocumentDeletionCode                <> 'L'
  and _PurchaseOrder.PurchasingDocumentDeletionCode <> 'L'
  and _PurchaseOrder.PurchasingDocumentIsAged       =  ' '
  // filter out statistical Items (excluding Retail i.e Material = '')  

  and not( Material = '' and IsStatisticalItem = 'X' )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"I_PURGDOCUMENTITEMCATEGORY",
"I_PURGDOCUMENTITEMCATEGORYTEXT",
"I_SUPPLIER",
"P_PURORDITEMNEXTDELIVERYCALC"
],
"ASSOCIATED":
[
"P_PURORDITEMNEXTDELIVERYCALC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/