P_PurDocItemCurConv

@AbapCatalog.sqlViewName: 'PURDOCITEMCUR'
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
//@Analytics.dataCategory: #CUBE

@VDM.private : true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Purchase Document with Currency Conversion for dates'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view P_PurDocItemCurConv
  with parameters
    P_DisplayCurrency : displaycurrency

  as select from I_PurchasingDocumentItem as PurchaseDocItem
    inner join   I_PurchasingDocument     as PurchaseDoc on PurchaseDocItem.PurchasingDocument = PurchaseDoc.PurchasingDocument

    inner join   I_CalendarDate           as Calendar    on PurchaseDoc.PurchasingDocumentOrderDate = Calendar.CalendarDate

{

  key PurchaseDocItem.PurchasingDocument,
  key PurchaseDocItem.PurchasingDocumentItem,
      CONCAT( PurchaseDocItem.PurchasingDocument , PurchaseDocItem.PurchasingDocumentItem  ) as PurchasingDocumentItemNo,
      PurchaseDoc.PurchasingDocumentOrderDate,
      cast( PurchaseDoc.PurchasingOrganization as mm_a_purg_org )                            as PurchasingOrganization,
      PurchaseDoc.PurchasingGroup,
      cast(PurchaseDoc._PurchasingGroup.PurchasingGroupName as mm_a_purg_grp_name )          as PurchasingGroupName,
      PurchaseDocItem.CompanyCode,
      PurchaseDoc.Supplier,
      cast( PurchaseDoc._Supplier._StandardAddress.Country as mm_a_supplier_country )        as SupplierCountry,
      PurchaseDocItem.Material,
      PurchaseDocItem.Plant,
      PurchaseDocItem.MaterialGroup,
      PurchaseDoc.PurchasingDocumentCategory,
      PurchaseDocItem.DocumentCurrency,
      PurchaseDocItem.PurchaseContract,
      PurchaseDocItem.ProfitCenter,
      PurchaseDocItem.OrderPriceUnit,
      PurchaseDocItem. AccountAssignmentCategory,
      PurchaseDoc.PurchasingDocumentOrigin,
      PurchaseDoc.CreatedByUser,
      PurchaseDocItem.MultipleAcctAssgmtDistribution                                         as MultipleAcctAssgmtDistribution,
      :P_DisplayCurrency                                                                     as DisplayCurrency,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      currency_conversion(  amount             => PurchaseDocItem.NetAmount,
                             source_currency    => PurchaseDocItem.DocumentCurrency,
                             target_currency    => $parameters.P_DisplayCurrency,
                             exchange_rate_date => PurchaseDoc.PurchasingDocumentOrderDate,
                             exchange_rate_type => 'M'
       )                                                                                     as NetAmountInDisplayCurrency,

      Calendar.CalendarYear,
      Calendar.CalendarMonth,
      Calendar.CalendarQuarter,
      Calendar.CalendarWeek,
      _Supplier
}
where
      PurchaseDoc.PurchasingDocumentDeletionCode     = ''
  and PurchaseDoc.ReleaseIsNotCompleted              = ''
  and PurchaseDoc.PurchasingCompletenessStatus       = ''
  and PurchaseDocItem.PurchasingDocumentDeletionCode = ''
  and PurchaseDocItem.IsEndOfPurposeBlocked          = ''
  and PurchaseDocItem.DocumentCurrency != ''
  and PurchaseDoc.PurchasingDocumentOrderDate != '00000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_CALENDARDATE",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_PURCHASINGGROUP",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_SUPPLIER"
],
"BASE":
[
"I_PURCHASINGDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/