P_ProjectPlanCostLineItem

@AbapCatalog.sqlViewName: 'PPROJBYPLANCOST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_ProjectPlanCostLineItem
  with parameters
    P_ProjectObjectRootNode : j_objnr
 //   P_ControllingArea: kokrs

  as select from(
                 I_FinancialPlanningEntryItem as _ProjCstLineItm
      inner join P_ProjectObject_2            as _hierachyData on  _ProjCstLineItm.ControllingObject   =  _hierachyData.ProjectObjectNode
                                                               and _ProjCstLineItm.ControllingObject   <> ''
                                                               and _hierachyData.ProjectObjectRootNode = $parameters.P_ProjectObjectRootNode
  )
 // left outer join I_PrjAppendedOrdForCostReport( P_ControllingArea: $parameters.P_ControllingArea ) as _AppendIndicator on _AppendIndicator.OrderType = _hierachyData.OrderType

  association [0..*] to I_VirtualPlanningCategory      as _VirtualPlanningCategory on  $projection.PlanningCategory = _VirtualPlanningCategory.SourcePlanningCategory
  association        to I_WBSElementData_2             as _WBSElement              on  _hierachyData.ProjectObjectNode = _WBSElement.WBSElementObject
  association        to I_NetworkActivityForCostReport as _NetworkActivity         on  _hierachyData.ProjectObjectNode = _NetworkActivity.NetworkActivityObject

  association        to I_ProjectNetwork               as _ProjectNetwork          on  _hierachyData.ProjectObjectNode = _ProjectNetwork.ProjectNetworkObject
  association        to I_MaintenanceOrder             as _PMOrder                 on  _hierachyData.ProjectObjectNode = _PMOrder.MaintenanceOrderInternalID
  association        to I_InternalOrder                as _InternalOrder           on  $projection.InternalOrder = _InternalOrder.InternalOrder
  association [0..1] to I_PrjAppendedOrdForCostReport  as _AppendIndicator         on  $projection.OrderType       = _AppendIndicator.OrderType
                                                                                   and $projection.ControllingArea = _AppendIndicator.ControllingArea
{
  key  _ProjCstLineItm.FinancialPlanningReqTransSqnc,
  key  _ProjCstLineItm.FinancialPlanningDataPacket,
  key  cast(abs(_ProjCstLineItm.FinancialPlanningEntryItem) as  fis_act_pln_docln )       as ActualPlanJournalEntryItem,
       cast(cast('' as abap.char (2)) as fins_ledger_pers )                               as SourceLedger,
       _ProjCstLineItm.Ledger,
       _ProjCstLineItm.CompanyCode,
       _ProjCstLineItm.FiscalYear,
       cast(cast('' as abap.char (10)) as farp_belnr_d )                                  as AccountingDocument,
       _ProjCstLineItm.LedgerFiscalYear,
       cast(cast('' as abap.char (6)) as fis_docln )                                      as LedgerGLLineItem,
       _ProjCstLineItm.FinancialPlanningEntryItem,
       cast(cast( 'P' as abap.char (1)) as fis_actual_plan_code)                          as ActualPlanCode,
       _ProjCstLineItm.FinPlngEntryItemCreatedByUser                                      as AccountingDocCreatedByUser,
       _ProjCstLineItm.BusinessArea,
       _ProjCstLineItm.PartnerOrder,
       //       _ProjCstLineItm.OrderID,

       case
       when _hierachyData.ProjectObjectType = 'OR'
       then
       _ProjCstLineItm.OrderID
       else
       ''
       end                                                                                as OrderID,

       _ProjCstLineItm.ControllingObject,
       _ProjCstLineItm.OrderOperation,
       _ProjCstLineItm.OrderSuboperation,

       case
       when _hierachyData.ProjectObjectType = 'IO'
       then
       _ProjCstLineItm.OrderID
       else
       ''
       end                                                                                as InternalOrder,

       case
       when _hierachyData.ProjectObjectType = 'PP'
       then
       _ProjCstLineItm.OrderID
       else
       ''
       end                                                                                as ProductionOrder,

       _ProjCstLineItm.Product,

       case
       when _hierachyData.ProjectObjectType = 'SV'
       then
       _ProjCstLineItm.ServiceDocument
       else
       ''
       end                                                                                as ServiceOrder,

       case
       when _hierachyData.ProjectObjectType = 'SV'
       then
       _ProjCstLineItm.ServiceDocumentItem
       else
       ''
       end                                                                                as ServiceOrderItem,

       case
       when _hierachyData.ProjectObjectType = 'SC'
       then
       _ProjCstLineItm.ServiceDocument
       else
       ''
       end                                                                                as ServiceContract,

       case
       when _hierachyData.ProjectObjectType = 'SC'
       then
       _ProjCstLineItm.ServiceDocumentItem
       else
       ''
       end                                                                                as ServiceContractItem,

       cast(_PartnerOrder.OrderCategory as fis_par_auftyp preserving type )               as PartnerOrderCategory,
       _hierachyData.ProjectObjectType                                                    as ProjectObjectType,
       case
       when _hierachyData.ProjectObjectType = 'PR' or _hierachyData.ProjectObjectType = 'OR'
       then _ProjCstLineItm.PartnerWBSElement
       when _hierachyData.ProjectObjectType = 'NV' or _hierachyData.ProjectObjectType = 'EL'
       or _hierachyData.ProjectObjectType = 'NP'
       then _ProjCstLineItm.PartnerOrder
       end                                                                                as ProjectPartnerObject,

       case
       when _hierachyData.ProjectObjectType = 'PR' or _hierachyData.ProjectObjectType = 'OR' or _hierachyData.ProjectObjectType = 'NP'
       then ''
       when _hierachyData.ProjectObjectType = 'NV' or _hierachyData.ProjectObjectType = 'EL'
       then _ProjCstLineItm.PartnerOrderItem
       end                                                                                as PartnerProjectNetworkActivity,

       _ProjCstLineItm.PartnerProject,
       _ProjCstLineItm.BusinessTransactionType,
       cast( ( case ControllingDebitCreditCode
               when 'S' then 'S'
                        else 'H'
         end )
       as fis_shkzg preserving type )                                                     as DebitCreditCode,
       _ProjCstLineItm.ControllingDebitCreditCode,
       _hierachyData.WBSElement,
       _ProjCstLineItm.ProjectNetwork                                                     as ProjectNetwork,
       _NetworkActivity.NetworkActivity                                                   as NetworkActivity,
       _NetworkActivity.NetworkActivityElement                                            as NetworkActivityElement,
       _hierachyData.ProjectObjectExternalID,

       case
       when _hierachyData.ProjectObjectType = 'PR' or _hierachyData.ProjectObjectType = 'OR' or _hierachyData.ProjectObjectType = 'NP'
       then ''
       when _hierachyData.ProjectObjectType = 'NV' or _hierachyData.ProjectObjectType = 'EL'
       then _ProjCstLineItm.OrderItem
       end                                                                                as ProjectNetworkActivity,


       _hierachyData.Project,

       _ProjCstLineItm.ProjectInternalID,

       case
       when _hierachyData.ProjectObjectType = 'PR'
       then _ProjCstLineItm.WBSElementInternalID
       when _hierachyData.ProjectObjectType = 'OR' or _hierachyData.ProjectObjectType = 'PP'
       then _ProjCstLineItm.OrderID
       when _hierachyData.ProjectObjectType = 'NV' or _hierachyData.ProjectObjectType = 'EL'
       or _hierachyData.ProjectObjectType = 'NP'
       then _ProjCstLineItm.ProjectNetwork
       end                                                                                as ObjectInternalID,
       _ProjCstLineItm.ControllingArea,
       _ProjCstLineItm.GLAccount,
       _ProjCstLineItm.CostCenter,
       _ProjCstLineItm.ProfitCenter,
       _ProjCstLineItm.ChartOfAccounts,
       cast(cast(substring(FinancialPlanningReqTransSqnc,1,8)as abap.dats) as fis_budat ) as CreationDate,
       _ProjCstLineItm.FunctionalArea,
       _ProjCstLineItm.CostCtrActivityType,
       _ProjCstLineItm.OriginCostCtrActivityType,
       _ProjCstLineItm.OriginCostCenter,
       @Semantics.currencyCode: true
       _ProjCstLineItm.ControllingObjectCurrency,

       @Aggregation.default: #SUM
       @Semantics.amount.currencyCode: 'ControllingObjectCurrency'
       _ProjCstLineItm.AmountInObjectCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.TransactionCurrency,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       _ProjCstLineItm.AmountInTransactionCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.CompanyCodeCurrency,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
       _ProjCstLineItm.AmountInCompanyCodeCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.GlobalCurrency,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       _ProjCstLineItm.AmountInGlobalCurrency,

       @Semantics.currencyCode: true
       _ProjCstLineItm.FunctionalCurrency,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
       _ProjCstLineItm.AmountInFunctionalCurrency                                         as PlanAmountInFunctionalCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency1,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency1,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency2,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency2,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency3,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency3,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency4,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency4,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency5,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency5,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency6,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency6,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency7,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency7,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency8,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency8,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
       _ProjCstLineItm.AmountInObjectCurrency                                             as PlndCostAmtInProjCrcy,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       _ProjCstLineItm.AmountInGlobalCurrency                                             as PlanAmountInGlobalCurrency,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency1                                       as PlanAmountInFreeDefinedCrcy1,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency2                                       as PlanAmountInFreeDefinedCrcy2,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency3                                       as PlanAmountInFreeDefinedCrcy3,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency4                                       as PlanAmountInFreeDefinedCrcy4,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency5                                       as PlanAmountInFreeDefinedCrcy5,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency6                                       as PlanAmountInFreeDefinedCrcy6,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency7                                       as PlanAmountInFreeDefinedCrcy7,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency8                                       as PlanAmountInFreeDefinedCrcy8,

       cast('' as fins_src_awtyp   )                                                      as SourceReferenceDocumentType,
       cast('' as fins_src_awsys   )                                                      as SourceLogicalSystem,
       cast('' as fins_src_aworg   )                                                      as SourceReferenceDocumentCntxt,
       cast('' as fins_src_awref   )                                                      as SourceReferenceDocument,
       cast('000000' as fins_src_awitem preserving type )                                 as SourceReferenceDocumentItem,
       cast('000000' as fins_src_awsubit preserving type )                                as SourceReferenceDocSubitem,
       cast(' ' as fins_xcommitment preserving type )                                     as IsCommitment,
       'X'                                                                                as IsSettled,
       _ProjCstLineItm.PlanningCategory,

       _ProjCstLineItm.PostingDate,

       cast( '00000000' as bldat )                                                        as DocumentDate,
       _ProjCstLineItm.FiscalPeriod,
       _ProjCstLineItm.FiscalYearPeriod,
       _ProjCstLineItm.FiscalYearVariant,
       _ProjCstLineItm.PartnerProfitCenter,
       _ProjCstLineItm.PartnerCompanyCode,
       cast( 'X' as boolean )                                                             as MaintenanceOrderIsSelected,
       case
       when _hierachyData.ProjectObjectType = 'PR'
       then _hierachyData.ProjectObjectType
       when _hierachyData.ProjectObjectType = 'OR' or _hierachyData.ProjectObjectType = 'OV'
       then  cast( 'OR' as ps_s4_projselobj )
       when _hierachyData.ProjectObjectType = 'NV' or _hierachyData.ProjectObjectType = 'EL' or
       _hierachyData.ProjectObjectType = 'NP'
       then cast( 'ZZ' as ps_s4_projselobj )
       when _hierachyData.ProjectObjectType = 'IO'
       then _hierachyData.ProjectObjectType
       when _hierachyData.ProjectObjectType = 'SV'
       then _hierachyData.ProjectObjectType
       when _hierachyData.ProjectObjectType = 'SC'
       then _hierachyData.ProjectObjectType
       when _hierachyData.ProjectObjectType = 'PP'
       then _hierachyData.ProjectObjectType
       end                                                                                as ProjectSelectedObject,

       _hierachyData.ProjectObjectProfitCenter,

       _hierachyData.ProjectObjectDescription,
       _hierachyData.ProjectObjectNode,
       _hierachyData.ProjectObjectRootNode,
       _hierachyData.ResponsibleCostCenter,

       _hierachyData.ProjectType,
       _hierachyData.OrderType,
       case when _hierachyData.ProjectObjectType = 'PR' 
              or _hierachyData.ProjectObjectType = 'SV' 
              or _hierachyData.ProjectObjectType = 'SC'
            then '1'
            else
              _AppendIndicator.OrderTypeAppendedCode end                                  as OrderTypeAppendedCode,
       _VirtualPlanningCategory,
       _WBSElement,
       _ProjectNetwork,
       _NetworkActivity,
       _PMOrder,
       _InternalOrder

}

union all select from I_FinancialPlanningEntryItem as _ProjCstLineItm //Statistical Internal Orders


  inner join          I_InternalOrder              as InternalOrder on  InternalOrder.InternalOrder      =  _ProjCstLineItm.OrderID
                                                                    and InternalOrder.IsStatisticalOrder =  'X'
                                                                    and _ProjCstLineItm.OrderID          <> ''

//left outer join I_PrjAppendedOrdForCostReport( P_ControllingArea: $parameters.P_ControllingArea  ) as _AppendIndicator   on  _AppendIndicator.OrderType = InternalOrder.OrderType

association [0..*] to I_VirtualPlanningCategory      as _VirtualPlanningCategory on  $projection.PlanningCategory = _VirtualPlanningCategory.SourcePlanningCategory
association        to I_WBSElementData_2             as _WBSElement              on  InternalOrder.ControllingObject = _WBSElement.WBSElementObject
association        to I_NetworkActivityForCostReport as _NetworkActivity         on  InternalOrder.ControllingObject = _NetworkActivity.NetworkActivityObject
association        to I_ProjectNetwork               as _ProjectNetwork          on  InternalOrder.ControllingObject = _ProjectNetwork.ProjectNetworkObject

association        to I_MaintenanceOrder             as _PMOrder                 on  InternalOrder.ControllingObject = _PMOrder.MaintenanceOrderInternalID
association        to I_InternalOrder                as _InternalOrder           on  $projection.InternalOrder = _InternalOrder.InternalOrder
association [0..1] to I_PrjAppendedOrdForCostReport  as _AppendIndicator         on  $projection.OrderType       = _AppendIndicator.OrderType
                                                                               and $projection.ControllingArea = _AppendIndicator.ControllingArea
{

  key  _ProjCstLineItm.FinancialPlanningReqTransSqnc,
  key  _ProjCstLineItm.FinancialPlanningDataPacket,
  key  cast(abs(_ProjCstLineItm.FinancialPlanningEntryItem) as  fis_act_pln_docln )       as ActualPlanJournalEntryItem,
       cast(cast('' as abap.char (2)) as fins_ledger_pers )                               as SourceLedger,
       _ProjCstLineItm.Ledger,
       _ProjCstLineItm.CompanyCode,
       _ProjCstLineItm.FiscalYear,
       cast(cast('' as abap.char (10)) as farp_belnr_d )                                  as AccountingDocument,
       _ProjCstLineItm.LedgerFiscalYear,
       cast(cast('' as abap.char (6)) as fis_docln )                                      as LedgerGLLineItem,
       _ProjCstLineItm.FinancialPlanningEntryItem,
       cast(cast( 'P' as abap.char (1)) as fis_actual_plan_code)                          as ActualPlanCode,
       _ProjCstLineItm.FinPlngEntryItemCreatedByUser                                      as AccountingDocCreatedByUser,
       _ProjCstLineItm.BusinessArea,
       _ProjCstLineItm.PartnerOrder,
       _ProjCstLineItm.OrderID,
       _ProjCstLineItm.ControllingObject,
       _ProjCstLineItm.OrderOperation,
       _ProjCstLineItm.OrderSuboperation,


       _ProjCstLineItm.OrderID                                                            as InternalOrder,
       ''                                                                                 as ProductionOrder,
       _ProjCstLineItm.Product,
       ''                                                                                 as ServiceOrder,
       ''                                                                                 as ServiceOrderItem,
       ''                                                                                 as ServiceContract,
       ''                                                                                 as ServiceContractItem,
       cast(_PartnerOrder.OrderCategory as fis_par_auftyp preserving type )               as PartnerOrderCategory,
       cast('IO' as abap.char(2))                                                         as ProjectObjectType,
       _ProjCstLineItm.PartnerWBSElement                                                  as ProjectPartnerObject,

       ''                                                                                 as PartnerProjectNetworkActivity,
       _ProjCstLineItm.PartnerProject,
       _ProjCstLineItm.BusinessTransactionType,
       cast( ( case ControllingDebitCreditCode
               when 'S' then 'S'
                        else 'H'
         end )
       as fis_shkzg preserving type )                                                     as DebitCreditCode,
       _ProjCstLineItm.ControllingDebitCreditCode,

       _WBSElement.WBSElementExternalID                                                   as WBSElement,

       _ProjCstLineItm.ProjectNetwork                                                     as ProjectNetwork,
       ''                                                                                 as NetworkActivity,
       ''                                                                                 as NetworkActivityElement,
       InternalOrder.InternalOrder                                                        as ProjectObjectExternalID,

       ''                                                                                 as ProjectNetworkActivity,


       InternalOrder._WBSElementBasicData._Project.Project,
       InternalOrder._WBSElementBasicData.ProjectInternalID,

       _ProjCstLineItm.OrderID                                                            as ObjectInternalID,


       _ProjCstLineItm.ControllingArea,
       _ProjCstLineItm.GLAccount,
       _ProjCstLineItm.CostCenter,
       _ProjCstLineItm.ProfitCenter,
       _ProjCstLineItm.ChartOfAccounts,
       cast(cast(substring(FinancialPlanningReqTransSqnc,1,8)as abap.dats) as fis_budat ) as CreationDate,
       _ProjCstLineItm.FunctionalArea,
       _ProjCstLineItm.CostCtrActivityType,
       _ProjCstLineItm.OriginCostCtrActivityType,
       _ProjCstLineItm.OriginCostCenter,
       @Semantics.currencyCode: true
       _ProjCstLineItm.ControllingObjectCurrency,

       @Aggregation.default: #SUM
       @Semantics.amount.currencyCode: 'ControllingObjectCurrency'
       _ProjCstLineItm.AmountInObjectCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.TransactionCurrency,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       _ProjCstLineItm.AmountInTransactionCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.CompanyCodeCurrency,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
       _ProjCstLineItm.AmountInCompanyCodeCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.GlobalCurrency,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       _ProjCstLineItm.AmountInGlobalCurrency,

       @Semantics.currencyCode: true
       _ProjCstLineItm.FunctionalCurrency,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
       _ProjCstLineItm.AmountInFunctionalCurrency                                         as PlanAmountInFunctionalCurrency,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency1,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency1,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency2,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency2,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency3,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency3,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency4,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency4,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency5,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency5,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency6,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency6,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency7,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency7,

       @Semantics.currencyCode:true
       _ProjCstLineItm.FreeDefinedCurrency8,
       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency8,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
       _ProjCstLineItm.AmountInObjectCurrency                                             as PlndCostAmtInProjCrcy,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       _ProjCstLineItm.AmountInGlobalCurrency                                             as PlanAmountInGlobalCurrency,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency1                                       as PlanAmountInFreeDefinedCrcy1,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency2                                       as PlanAmountInFreeDefinedCrcy2,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency3                                       as PlanAmountInFreeDefinedCrcy3,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency4                                       as PlanAmountInFreeDefinedCrcy4,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency5                                       as PlanAmountInFreeDefinedCrcy5,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency6                                       as PlanAmountInFreeDefinedCrcy6,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency7                                       as PlanAmountInFreeDefinedCrcy7,

       @Aggregation.default: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
       _ProjCstLineItm.AmountInFreeDefinedCurrency8                                       as PlanAmountInFreeDefinedCrcy8,

       cast('' as fins_src_awtyp   )                                                      as SourceReferenceDocumentType,
       cast('' as fins_src_awsys   )                                                      as SourceLogicalSystem,
       cast('' as fins_src_aworg   )                                                      as SourceReferenceDocumentCntxt,
       cast('' as fins_src_awref   )                                                      as SourceReferenceDocument,
       cast('000000' as fins_src_awitem preserving type )                                 as SourceReferenceDocumentItem,
       cast('000000' as fins_src_awsubit preserving type )                                as SourceReferenceDocSubitem,
       cast(' ' as fins_xcommitment preserving type )                                     as IsCommitment,
       'X'                                                                                as IsSettled,
       //         ' ' as IsSettled,

       _ProjCstLineItm.PlanningCategory,

       _ProjCstLineItm.PostingDate,

       cast( '00000000' as bldat )                                                        as DocumentDate,
       _ProjCstLineItm.FiscalPeriod,
       _ProjCstLineItm.FiscalYearPeriod,
       _ProjCstLineItm.FiscalYearVariant,
       _ProjCstLineItm.PartnerProfitCenter,
       _ProjCstLineItm.PartnerCompanyCode,
       cast( 'X' as boolean )                                                             as MaintenanceOrderIsSelected,

       cast( 'IO' as ps_s4_projselobj )                                                   as ProjectSelectedObject,
       InternalOrder.ProfitCenter                                                         as ProjectObjectProfitCenter,
       InternalOrder.InternalOrderDescription                                             as ProjectObjectDescription,

       InternalOrder.ControllingObject                                                    as ProjectObjectNode,
       InternalOrder._WBSElementBasicData._Project.ProjectObject                          as ProjectObjectRootNode,
       InternalOrder.ResponsibleCostCenter                                                as ResponsibleCostCenter,
       cast( '' as ps_prart )                                                             as ProjectType,
       InternalOrder.OrderType                                                            as OrderType,
       _AppendIndicator.OrderTypeAppendedCode                                             as OrderTypeAppendedCode,
       _VirtualPlanningCategory,
       _WBSElement,
       _ProjectNetwork,
       _NetworkActivity,
       _PMOrder,
       _InternalOrder
}