P_ProjNetworkWithVersion

@AbapCatalog.sqlViewName: 'PPROJNTWKVERS'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AccessControl.authorizationCheck: #CHECK

define view P_ProjNetworkWithVersion
  as select from I_ProjectNetworkVersion

{

  key I_ProjectNetworkVersion.ProjectNetwork,

  key I_ProjectNetworkVersion.Version,

      'X'                               as  IsProjectVersionObject,
      I_ProjectNetworkVersion.ProjectNetworkDescription,
      I_ProjectNetworkVersion.ProjectInternalID,
      I_ProjectNetworkVersion.WBSElementInternalID,
      I_ProjectNetworkVersion.ProjectNetworkInternalID,
      I_ProjectNetworkVersion.BusinessArea,
      I_ProjectNetworkVersion.CompanyCode,
      I_ProjectNetworkVersion.ControllingArea,
      I_ProjectNetworkVersion.ProfitCenter,
      I_ProjectNetworkVersion.CostCenter,
      I_ProjectNetworkVersion.Plant,
      I_ProjectNetworkVersion.SalesOrder,
      I_ProjectNetworkVersion.SalesOrderItem,
      I_ProjectNetworkVersion.MRPController,
      I_ProjectNetworkVersion.ResponsiblePlannerGroup,
      //I_ProjectNetworkVersion.EngineeringChangeOrder,

      I_ProjectNetworkVersion.ChangeNumber,
      I_ProjectNetworkVersion.PriorityCode,
      I_ProjectNetworkVersion.SuperiorProjectNetwork,
      I_ProjectNetworkVersion.ProductConfiguration,
      I_ProjectNetworkVersion.LastScheduledDate,
      I_ProjectNetworkVersion.ConfirmedEndDate,
      I_ProjectNetworkVersion.ScheduledReleaseDate,
      I_ProjectNetworkVersion.ActualReleasedDate,
      I_ProjectNetworkVersion.ActualStartDate,
      I_ProjectNetworkVersion.ActualEndDate,
      I_ProjectNetworkVersion.PlannedStartDate,
      I_ProjectNetworkVersion.PlannedEndDate,
      I_ProjectNetworkVersion.ForecastedStartDate,
      I_ProjectNetworkVersion.ForecastedEndDate,
      I_ProjectNetworkVersion.ScheduledForecastedStartDate,
      I_ProjectNetworkVersion.ScheduledForecastedEndDate,
      I_ProjectNetworkVersion.ScheduledFcstdReleaseDate,
      I_ProjectNetworkVersion.ScheduledBasicStartDate,
      I_ProjectNetworkVersion.ScheduledBasicEndDate,
      I_ProjectNetworkVersion.Reservation,
      I_ProjectNetworkVersion.CreationDate,
      I_ProjectNetworkVersion.CreationTime,
      I_ProjectNetworkVersion.CreatedByUser,
      I_ProjectNetworkVersion.LastChangeDate,
      I_ProjectNetworkVersion.LastChangeTime,
      I_ProjectNetworkVersion.LastChangedByUser,
      I_ProjectNetworkVersion.OrderType as  ProjectNetworkType,
      I_ProjectNetworkVersion.OrderCategory,
      I_ProjectNetworkVersion.JointVentureOriginalCostObject,
      I_ProjectNetworkVersion.JointVentureObjectType,
      I_ProjectNetworkVersion.JointVenture,
      I_ProjectNetworkVersion.JointVentureClass,
      I_ProjectNetworkVersion.JointVentureSubClass,
      I_ProjectNetworkVersion.TaxJurisdiction,
      I_ProjectNetworkVersion.CostingSheet,
      I_ProjectNetworkVersion.CostElement,
      I_ProjectNetworkVersion.ProjectNetworkObject,
      I_ProjectNetworkVersion.Currency,
      I_ProjectNetworkVersion.OverheadCode,
      I_ProjectNetworkVersion.ProjNtwkInterestCalcProfile,
      I_ProjectNetworkVersion.NetworkActivityConfirmation,
      I_ProjectNetworkVersion.IsMarkedForDeletion,
      I_ProjectNetworkVersion.ActualCostsCostingVariant,
      I_ProjectNetworkVersion.PlannedCostsCostingVariant,
      I_ProjectNetworkVersion.ForecastSchedulingType,
      I_ProjectNetworkVersion.BasicSchedulingType,
      I_ProjectNetworkVersion.BaseUnit,
      I_ProjectNetworkVersion.NetworkIsAccountAssigned,
      I_ProjectNetworkVersion.NetworkProfile,
      I_ProjectNetworkVersion.FunctionalArea,
      I_ProjectNetworkVersion.CapacityRequirement,
      I_ProjectNetworkVersion.ControllingObjectClass,
      I_ProjectNetworkVersion.OrderID,
      I_ProjectNetworkVersion.OrderIsNotCostedAutomatically,
      I_ProjectNetworkVersion.OrdIsNotSchedldAutomatically,

      //Calculate Due Overdue Dates

      cast( 0 as int4 )                 as  DueToStartDays,
      cast( 0 as int4 )                 as  DueToEndDays,
      cast( 0 as int4 )                 as  OverdueToStartDays,
      cast( 0 as int4 )                 as  OverdueToEndDays,

      //-->Associations


      I_ProjectNetworkVersion._BusinessArea,
      I_ProjectNetworkVersion._CompanyCode,
      I_ProjectNetworkVersion._ControllingArea,
      I_ProjectNetworkVersion._CostCenter,
      I_ProjectNetworkVersion._Currency,
      I_ProjectNetworkVersion._MRPController,
      I_ProjectNetworkVersion._Plant,
      I_ProjectNetworkVersion._ProfitCenter,
      I_ProjectNetworkVersion._SalesOrder,
      I_ProjectNetworkVersion._SalesOrderItem,
      I_ProjectNetworkVersion._OrderCategory,
      I_ProjectNetworkVersion._FunctionalArea,
      I_ProjectNetworkVersion._NetworkProfile,
      I_ProjectNetworkVersion._ResponsiblePlannerGroup,
      I_ProjectNetworkVersion._ControllingObjectClass,
      I_ProjectNetworkVersion._Prioritycode,
      I_ProjectNetworkVersion._OrderType,
      I_ProjectNetworkVersion._TaxJurisdiction,
      I_ProjectNetworkVersion._NetworkShortText
      //<--Associations

}

union all

select from I_ProjectNetwork

{

  key I_ProjectNetwork.ProjectNetwork,

  key ''  as Version,

      ''  as IsProjectVersionObject,
      I_ProjectNetwork.ProjectNetworkDescription,
      I_ProjectNetwork.ProjectInternalID,
      I_ProjectNetwork.WBSElementInternalID,
      I_ProjectNetwork.ProjectNetworkInternalID,
      I_ProjectNetwork.BusinessArea,
      I_ProjectNetwork.CompanyCode,
      I_ProjectNetwork.ControllingArea,
      I_ProjectNetwork.ProfitCenter,
      I_ProjectNetwork.CostCenter,
      I_ProjectNetwork.Plant,
      I_ProjectNetwork.SalesOrder,
      I_ProjectNetwork.SalesOrderItem,
      I_ProjectNetwork.MRPController,
      I_ProjectNetwork.ResponsiblePlannerGroup,
      //I_ProjectNetwork.EngineeringChangeOrder,

      I_ProjectNetwork.ChangeNumber,
      I_ProjectNetwork.PriorityCode,
      I_ProjectNetwork.SuperiorProjectNetwork,
      I_ProjectNetwork.ProductConfiguration,
      I_ProjectNetwork.LastScheduledDate,
      I_ProjectNetwork.ConfirmedEndDate,
      I_ProjectNetwork.ScheduledReleaseDate,
      I_ProjectNetwork.ActualReleasedDate,
      I_ProjectNetwork.ActualStartDate,
      I_ProjectNetwork.ActualEndDate,
      I_ProjectNetwork.PlannedStartDate,
      I_ProjectNetwork.PlannedEndDate,
      I_ProjectNetwork.ForecastedStartDate,
      I_ProjectNetwork.ForecastedEndDate,
      I_ProjectNetwork.ScheduledForecastedStartDate,
      I_ProjectNetwork.ScheduledForecastedEndDate,
      I_ProjectNetwork.ScheduledFcstdReleaseDate,
      I_ProjectNetwork.ScheduledBasicStartDate,
      I_ProjectNetwork.ScheduledBasicEndDate,
      I_ProjectNetwork.Reservation,
      I_ProjectNetwork.CreationDate,
      I_ProjectNetwork.CreationTime,
      I_ProjectNetwork.CreatedByUser,
      I_ProjectNetwork.LastChangeDate,
      I_ProjectNetwork.LastChangeTime,
      I_ProjectNetwork.LastChangedByUser,
      I_ProjectNetwork.ProjectNetworkType,
      I_ProjectNetwork.OrderCategory,
      I_ProjectNetwork.JointVentureOriginalCostObject,
      I_ProjectNetwork.JointVentureObjectType,
      I_ProjectNetwork.JointVenture,
      I_ProjectNetwork.JointVentureClass,
      I_ProjectNetwork.JointVentureSubClass,
      I_ProjectNetwork.TaxJurisdiction,
      I_ProjectNetwork.CostingSheet,
      I_ProjectNetwork.CostElement,
      I_ProjectNetwork.ProjectNetworkObject,
      I_ProjectNetwork.Currency,
      I_ProjectNetwork.OverheadCode,
      I_ProjectNetwork.ProjNtwkInterestCalcProfile,
      I_ProjectNetwork.NetworkActivityConfirmation,
      I_ProjectNetwork.IsMarkedForDeletion,
      I_ProjectNetwork.ActualCostsCostingVariant,
      I_ProjectNetwork.PlannedCostsCostingVariant,
      I_ProjectNetwork.ForecastSchedulingType,
      I_ProjectNetwork.BasicSchedulingType,
      I_ProjectNetwork.BaseUnit,
      I_ProjectNetwork.NetworkIsAccountAssigned,
      I_ProjectNetwork.NetworkProfile,
      I_ProjectNetwork.FunctionalArea,
      I_ProjectNetwork.CapacityRequirement,
      I_ProjectNetwork.ControllingObjectClass,
      I_ProjectNetwork.OrderID,
      I_ProjectNetwork.OrderIsNotCostedAutomatically,
      I_ProjectNetwork.OrdIsNotSchedldAutomatically,

      case when I_ProjectNetwork.ActualStartDate = '00000000'
            and I_ProjectNetwork.ScheduledBasicStartDate != '00000000'
            and I_ProjectNetwork.ScheduledBasicStartDate > $session.system_date
           then
              DATS_DAYS_BETWEEN(
                cast($session.system_date as sydatum),
                I_ProjectNetwork.ScheduledBasicStartDate
              )
           else case when I_ProjectNetwork.ActualStartDate = '00000000'
                      and I_ProjectNetwork.PlannedStartDate != '00000000'
                      and I_ProjectNetwork.PlannedStartDate > $session.system_date
                     then
                        DATS_DAYS_BETWEEN(
                          cast($session.system_date as sydatum),
                          I_ProjectNetwork.PlannedStartDate
                        )
                     else 0
                  end
      end as DueToStartDays,

      case when I_ProjectNetwork.ActualEndDate = '00000000'
            and I_ProjectNetwork.ScheduledBasicEndDate != '00000000'
            and I_ProjectNetwork.ScheduledBasicEndDate > $session.system_date
           then
              DATS_DAYS_BETWEEN(
                    cast($session.system_date as sydatum),
                    I_ProjectNetwork.ScheduledBasicEndDate
                  )
           else case when I_ProjectNetwork.ActualEndDate = '00000000'
                      and I_ProjectNetwork.PlannedEndDate != '00000000'
                      and I_ProjectNetwork.PlannedEndDate > $session.system_date
                     then
                        DATS_DAYS_BETWEEN(
                          cast($session.system_date as sydatum),
                          I_ProjectNetwork.PlannedEndDate
                        )
                     else 0
                  end
      end as DueToEndDays,

      case when I_ProjectNetwork.ActualStartDate = '00000000'
            and I_ProjectNetwork.ScheduledBasicStartDate != '00000000'
            and I_ProjectNetwork.ScheduledBasicStartDate < $session.system_date
           then
              DATS_DAYS_BETWEEN(
                I_ProjectNetwork.ScheduledBasicStartDate,
                cast($session.system_date as sydatum)
              )
           else case when I_ProjectNetwork.ActualStartDate = '00000000'
                      and I_ProjectNetwork.PlannedStartDate != '00000000'
                      and I_ProjectNetwork.PlannedStartDate < $session.system_date
                     then
                        DATS_DAYS_BETWEEN(
                          I_ProjectNetwork.PlannedStartDate,
                          cast($session.system_date as sydatum)
                        )
                     else 0
                  end
      end as OverdueToStartDays,

      case when I_ProjectNetwork.ActualEndDate = '00000000'
            and I_ProjectNetwork.ScheduledBasicEndDate != '00000000'
            and I_ProjectNetwork.ScheduledBasicEndDate < $session.system_date
           then
              DATS_DAYS_BETWEEN(
                I_ProjectNetwork.ScheduledBasicEndDate,
                cast($session.system_date as sydatum)
              )
           else case when I_ProjectNetwork.ActualEndDate = '00000000'
                      and I_ProjectNetwork.PlannedEndDate != '00000000'
                      and I_ProjectNetwork.PlannedEndDate < $session.system_date
                     then
                        DATS_DAYS_BETWEEN(
                          I_ProjectNetwork.PlannedEndDate,
                          cast($session.system_date as sydatum)
                            )
                     else 0
                  end
      end as OverdueToEndDays,

      //-->Associations


      I_ProjectNetwork._BusinessArea,
      I_ProjectNetwork._CompanyCode,
      I_ProjectNetwork._ControllingArea,
      I_ProjectNetwork._CostCenter,
      I_ProjectNetwork._Currency,
      I_ProjectNetwork._MRPController,
      I_ProjectNetwork._Plant,
      I_ProjectNetwork._ProfitCenter,
      I_ProjectNetwork._SalesOrder,
      I_ProjectNetwork._SalesOrderItem,
      I_ProjectNetwork._OrderCategory,
      I_ProjectNetwork._FunctionalArea,
      I_ProjectNetwork._NetworkProfile,
      I_ProjectNetwork._ResponsiblePlannerGroup,
      I_ProjectNetwork._ControllingObjectClass,
      I_ProjectNetwork._Prioritycode,
      I_ProjectNetwork._OrderType,
      I_ProjectNetwork._TaxJurisdiction,
      I_ProjectNetwork._NetworkShortText
      //<--Associations


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTNETWORK",
"I_PROJECTNETWORKVERSION"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_COSTCENTER",
"I_CURRENCY",
"I_FUNCTIONALAREA",
"I_MRPCONTROLLER",
"I_NETWORKPROFILE",
"I_ORDERCATEGORY",
"I_ORDERTYPE",
"I_PLANT",
"I_PRIORITYCODE",
"I_PROFITCENTER",
"I_PROJECTOBJECTSHORTTEXT",
"I_RESPONSIBLEPLANNERGROUP",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_TAXJURISDICTION"
],
"BASE":
[
"I_PROJECTNETWORKVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/