P_ProjMatCompPurDocItems

@AbapCatalog.sqlViewName: 'PPMCPURDOCITM'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType:#BASIC
@VDM.private: true

define view P_ProjMatCompPurDocItems
  //Direct Procurement: Purchase Requisition Items

  as select from rsdb

  association [1..1] to I_PurchaseRequisitionItemBasic as _PurchaseRequisitionItem on  $projection.PurchasingDocument     = _PurchaseRequisitionItem.PurchaseRequisition
                                                                              and $projection.PurchasingDocumentItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
 association [1..1] to I_PurchasingDocumentType     as _PurchasingDocumentType on  _PurchasingDocumentType.PurchasingDocumentCategory = 'B'
                                                                                and $projection.PurchasingDocumentType                = _PurchasingDocumentType.PurchasingDocumentType

{

  key rsdb.banfn                                           as PurchasingDocument,

  key rsdb.bnfpo                                           as PurchasingDocumentItem,

      rsdb.rsnum                                           as Reservation,
      rsdb.rspos                                           as ReservationItem,
      rsdb.rsart                                           as RecordType,
      _PurchaseRequisitionItem.PurchaseRequisitionType     as PurchasingDocumentType,
  //    _PurchaseRequisitionItem._PurchasingDocumentType._Text[1:Language = $session.system_language].PurchasingDocumentTypeName,

      _PurchaseRequisitionItem.Plant,
      _PurchaseRequisitionItem.Supplier,
      _PurchaseRequisitionItem.PurchaseRequisitionItemText as PurchasingDocumentItemText,
      _PurchasingDocumentType
}
where
      banfn <> '0000000000'
  and bnfpo <> '00000'

union all

//Direct Procurement: Purchase Order Items

select from rsdb
association [1..1] to I_PurchasingDocumentItem as _PurchaseOrderItem on  $projection.PurchasingDocument     = _PurchaseOrderItem.PurchasingDocument
                                                                     and $projection.PurchasingDocumentItem = _PurchaseOrderItem.PurchasingDocumentItem
 association [1..1] to I_PurchasingDocumentType     as _PurchasingDocumentType on  _PurchasingDocumentType.PurchasingDocumentCategory = 'B'
                                                                                and $projection.purchasingdocumenttype                = _PurchasingDocumentType.PurchasingDocumentType

{

  key rsdb.ebeln                               as PurchasingDocument,

  key rsdb.ebelp                               as PurchasingDocumentItem,

      rsdb.rsnum                               as Reservation,
      rsdb.rspos                               as ReservationItem,
      rsdb.rsart                               as RecordType,
      _PurchaseOrderItem._PurchasingDocument.PurchasingDocumentType,
  //    _PurchaseOrderItem._PurchasingDocument._PurchasingDocumentType._Text[1:Language = $session.system_language].PurchasingDocumentTypeName,

      _PurchaseOrderItem.Plant,
      _PurchaseOrderItem._PurchasingDocument.Supplier,
      _PurchaseOrderItem.PurchasingDocumentItemText,
      _PurchasingDocumentType
}
where
      ebeln <> '0000000000'
  and ebelp <> '00000'

union all

//Purchasing from individual customer stock: purchase requisition items

select from rsdbs

association [1..1] to I_PurchaseRequisitionItemBasic as _PurchaseRequisitionItem on  $projection.PurchasingDocument     = _PurchaseRequisitionItem.PurchaseRequisition
                                                                            and $projection.PurchasingDocumentItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
 association [1..1] to I_PurchasingDocumentType     as _PurchasingDocumentType on  _PurchasingDocumentType.PurchasingDocumentCategory = 'B'
                                                                                and $projection.PurchasingDocumentType                = _PurchasingDocumentType.PurchasingDocumentType

{

  key rsdbs.banfn                                          as PurchasingDocument,

  key rsdbs.bnfpo                                          as PurchasingDocumentItem,

      rsdbs.rsnum                                          as Reservation,
      rsdbs.rspos                                          as ReservationItem,
      rsdbs.rsart                                          as RecordType,
      _PurchaseRequisitionItem.PurchaseRequisitionType     as PurchasingDocumentType,
   //   _PurchaseRequisitionItem._PurchasingDocumentType._Text[1:Language = $session.system_language].PurchasingDocumentTypeName,

      _PurchaseRequisitionItem.Plant,
      _PurchaseRequisitionItem.Supplier,
      _PurchaseRequisitionItem.PurchaseRequisitionItemText as PurchasingDocumentItemText,
      _PurchasingDocumentType
}
where
  rsinz = '01'

union all

//Purchasing from individual customer stock: purchase order items

select from rsdbs

association [1..1] to I_PurchasingDocumentItem as _PurchaseOrderItem on  $projection.PurchasingDocument     = _PurchaseOrderItem.PurchasingDocument
                                                                     and $projection.PurchasingDocumentItem = _PurchaseOrderItem.PurchasingDocumentItem
 association [1..1] to I_PurchasingDocumentType     as _PurchasingDocumentType on  _PurchasingDocumentType.PurchasingDocumentCategory = 'B'
                                                                                and $projection.purchasingdocumenttype                = _PurchasingDocumentType.PurchasingDocumentType

{

  key rsdbs.ebeln                              as PurchasingDocument,

  key rsdbs.ebelp                              as PurchasingDocumentItem,

      rsdbs.rsnum                              as Reservation,
      rsdbs.rspos                              as ReservationItem,
      rsdbs.rsart                              as RecordType,
      _PurchaseOrderItem._PurchasingDocument.PurchasingDocumentType,
  //    _PurchaseOrderItem._PurchasingDocument._PurchasingDocumentType._Text[1:Language = $session.system_language].PurchasingDocumentTypeName,

      _PurchaseOrderItem.Plant,
      _PurchaseOrderItem._PurchasingDocument.Supplier,
      _PurchaseOrderItem.PurchasingDocumentItemText,
      _PurchasingDocumentType
}
where
      ebeln <> '0000000000'
  and ebelp <> '00000' 
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEREQUISITIONITEMBASIC",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"RSDB",
"RSDBS"
],
"ASSOCIATED":
[
"I_PURCHASEREQUISITIONITEMBASIC",
"I_PURCHASINGDOCUMENTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/