P_ProductionOrderQuickView

@AbapCatalog.sqlViewName: 'PPRODNORDQV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'P view for Production Order'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XL, dataClass: #MASTER}
@VDM.private: true
@VDM.viewType: #BASIC
define view P_ProductionOrderQuickView
  as select from    I_MfgOrderItem          as ProductionOrderItem
    left outer to one join I_ProductSupplyPlanning as _ProductSupplyPlanning on  ProductionOrderItem.Material = _ProductSupplyPlanning.Product
                                                                      and MRPPlant                     = _ProductSupplyPlanning.Plant
  association [0..1] to I_ReservationItem as _ReservationItem on  $projection.Reservation            = _ReservationItem.Reservation
                                                              and $projection.ManufacturingOrderItem = _ReservationItem.ReservationItem
  association [0..1] to P_DDMRPController as _MRPCtrlr        on  $projection.MRPPlant      = _MRPCtrlr.Plant
                                                              and $projection.MRPController = _MRPCtrlr.MRPController
  association [0..1] to I_RoundingPrfText as _RoundingProfile on  $projection.RoundingProfile = _RoundingProfile.MaterialRoundingProfile
                                                              and $projection.MRPPlant        = _RoundingProfile.Plant
  association [0..1] to I_Order           as _Order           on  $projection.OrderID = _Order.OrderID
  
  association [0..1] to I_ProductionVersion as _ProdVersion
                                                                         on $projection.Material = _ProdVersion.Material
                                                                         and $projection.MRPPlant  = _ProdVersion.Plant
                                                                           and $projection.ProductionVersion = _ProdVersion.ProductionVersion
{
  key ManufacturingOrder                                                                                                                              as OrderID,
  key ManufacturingOrderItem,
      ProductionOrderItem.Material,
      MRPPlant,
      ManufacturingOrderCategory,

      //      // Distinguishing between different quick view categories

      //      case $parameters.P_MRPElementCategory

      //        when 'FE' then '031'

      //        when 'BR' then '033'

      //        when 'AR' then case ManufacturingOrderCategory

      //          when '10' then '032'

      //          when '40' then '034'

      //          else '000'

      //        end

      //        else '000'

      //      end                                                                                                                                             as QuickViewCategory,


      ManufacturingOrderType,
      _MfgOrderType._Text[1: Language = $session.system_language].ManufacturingOrderTypeName,
      MfgOrderReleasedCode,

      MfgOrderPlannedStartDate,
      MfgOrderScheduledReleaseDate,
      MfgOrderScheduledStartDate,
      MfgOrderScheduledEndDate,
      MfgOrderPlannedEndDate,
      MaterialGoodsReceiptDuration,

      MfgOrderPlannedTotalQty,
      _MfgOrder.ExpectedDeviationQuantity,
      MfgOrderPlannedScrapQty,
      _MfgOrder.ActualDeliveredQuantity                                                                                                               as MfgOrderItemGoodsReceiptQty,
      (MfgOrderPlannedTotalQty - _MfgOrder.ExpectedDeviationQuantity - MfgOrderPlannedScrapQty - _MfgOrder.ActualDeliveredQuantity)                   as MRPElementOpenQuantity,
      ProductionOrderItem.BaseUnit,

      ProductionPlant,
      _MfgOrder._Plant.PlantName                                                                                                                      as ProductionPlantName,
      ProductionVersion,
      _ProductionVersion.ProductionVersionText,
      _ProdVersion.ProductionLine                        as ProductionLine,
     // _ProductionVersion._ProductionLine._WorkCenterTextBySemanticKey[ 1: Language = $session.system_language ].WorkCenterText                        as ProductionLineText,

      _MfgOrder.ManufacturingOrderImportance,

      // Internal Contact Data

      ProductionSupervisor,
      _ProductionSupervisor.ProductionSupervisorName,
      MRPController,
      _MRPCtrlr.MRPControllerName                                                                                                                     as MRPControllerName,
      _MRPCtrlr.InternalContactName                                                                                                                   as InternalContactPersonName,
      _MRPCtrlr.PhoneNumber                                                                                                                           as InternalContactPhoneNumber,
      _MRPCtrlr.EmailAddress                                                                                                                          as InternalContactEmailAddress,

      // Requirement Data

      Reservation,
      _ReservationItem.MatlCompRequirementDate                                                                                                        as RequirementDate,
      _ReservationItem.ResvnItmRequiredQtyInBaseUnit                                                                                                  as OrderedQuantity,
      _ReservationItem.ResvnItmWithdrawnQtyInBaseUnit                                                                                                 as WithdrawnQuantity,
      (_ReservationItem.ResvnItmRequiredQtyInBaseUnit - _ReservationItem.ResvnItmWithdrawnQtyInBaseUnit)                                              as OpenQuantity,

      // Procurement Data

      _ProductSupplyPlanning.InHouseProductionTime                                                                                                    as MaterialPlannedProductionDurn,
      _ProductSupplyPlanning.TotalReplenishmentLeadTime                                                                                               as TotalReplenishmentLeadDuration,
      _ProductSupplyPlanning.FixedLotSizeQuantity                                                                                                     as FixedLotSizeQuantity,
      _ProductSupplyPlanning.MinimumLotSizeQuantity                                                                                                   as MinimumLotSizeQuantity,
      _ProductSupplyPlanning.MaximumLotSizeQuantity                                                                                                   as MaximumLotSizeQuantity,
      _ProductSupplyPlanning.LotSizeRoundingQuantity                                                                                                  as LotSizeRoundingQuantity,
      _ProductSupplyPlanning.RoundingProfile                                                                                                          as RoundingProfile,
      _RoundingProfile[ 1: Language = $session.system_language ].MaterialRoundingProfileName                                                          as MaterialRoundingProfileName,

      // Related Objects

      SalesOrder,
      SalesOrderItem,
      WBSElementInternalID,
      _WBSElement.WBSElement                                                                                               as WBSElement,

      // Associations

      _MfgOrder,
      _MfgOrderCategory,
      _MfgOrderType,
      _ProductionPlant,
      _ProductionSupervisor,
      _MRPController,
      _MRPPlant,
      ProductionOrderItem._Material,
      _ProductionVersion,
      _WBSElement,
      _Order
     
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDER",
"I_MFGORDERITEM",
"I_MFGORDERTYPE",
"I_MFGORDERTYPETEXT",
"I_PLANT",
"I_PRODUCTIONSUPERVISOR",
"I_PRODUCTIONVERSION",
"I_PRODUCTSUPPLYPLANNING",
"I_RESERVATIONITEM",
"I_ROUNDINGPRFTEXT",
"I_WBSELEMENTBYINTERNALKEY",
"P_DDMRPCONTROLLER"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDERTYPE",
"I_MRPCONTROLLER",
"I_ORDER",
"I_PLANT",
"I_PRODUCTIONSUPERVISOR",
"I_PRODUCTIONVERSION",
"I_RESERVATIONITEM",
"I_ROUNDINGPRFTEXT",
"I_WBSELEMENTBYINTERNALKEY",
"P_DDMRPCONTROLLER"
],
"BASE":
[
"I_MFGORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/