P_ProductSalesDeliveryWD

@AbapCatalog.sqlViewName: 'PPRDSALESDELIVWD'
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
//@EndUserText.label: 'Product Sales Delivery Union (draft)'

@AccessControl.authorizationCheck: #NOT_REQUIRED
define view P_ProductSalesDeliveryWD
  as

  select from       I_ProductSalesDelivery  as ActiveDocument
    left outer join P_ProductSalesDeliveryD as DraftDocument on  DraftDocument.ActiveProduct                 = ActiveDocument.Product
                                                             and DraftDocument.ActiveProductSalesOrg         = ActiveDocument.ProductSalesOrg
                                                             and DraftDocument.ActiveProductDistributionChnl = ActiveDocument.ProductDistributionChnl

{
  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x )                           as Draftkey,
  key ActiveDocument.Product                                                                       as ActiveProduct,
  key ActiveDocument.ProductSalesOrg                                                      as ActiveProductSalesOrg,
  key ActiveDocument.ProductDistributionChnl                                                    as ActiveProductDistributionChnl,
      cast ( hextobin('00000000000000000000000000000000') as sysuuid_x )                           as ParentDraftKey,
      ActiveDocument.Product,
//      ActiveDocument.ProductSalesOrganization,

//      ActiveDocument.ProductDistributionChannel,

      ActiveDocument.MinimumOrderQuantity,
      ActiveDocument.SupplyingPlant,
      ActiveDocument.PriceSpecificationProductGroup,
      ActiveDocument.AccountDetnProductGroup,
      ActiveDocument.DeliveryNoteProcMinDelivQty,
      ActiveDocument.ItemCategoryGroup,
      ActiveDocument.DeliveryQuantityUnit,
      ActiveDocument. DeliveryQuantity,
      ActiveDocument.ProductSalesStatus,
      ActiveDocument.ProductSalesStatusValidityDate,
      ActiveDocument.SalesMeasureUnit,
      cast(ActiveDocument.IsMarkedForDeletion as boole_d)                                          as IsMarkedForDeletion,
      ActiveDocument.ProductHierarchy,
      ActiveDocument.FirstSalesSpecProductGroup,
      ActiveDocument.SecondSalesSpecProductGroup,
      ActiveDocument.ThirdSalesSpecProductGroup,
      ActiveDocument.FourthSalesSpecProductGroup,
      ActiveDocument.FifthSalesSpecProductGroup,
      ActiveDocument.MinimumMakeToOrderOrderQty,
      //retail fields added on 25.4.16

      ActiveDocument.LogisticsStatisticsGroup,
      ActiveDocument.VolumeRebateGroup,
      ActiveDocument.ProductCommissionGroup,
      ActiveDocument.CashDiscountIsDeductible,
      ActiveDocument.PricingReferenceProduct,
      ActiveDocument.AssortmentGrade,
      ActiveDocument.StoreListingProcedure,
      ActiveDocument.DistrCntrListingProcedure,
      ActiveDocument.StoreListingStartDate,
      ActiveDocument.StoreListingEndDate,
      ActiveDocument.DistrCntrListingStartDate,
      ActiveDocument.DistrCntrListingEndDate,
      ActiveDocument.StoreSaleStartDate,
      ActiveDocument.StoreSaleEndDate,
      ActiveDocument.DistrCntrSaleStartDate,
      ActiveDocument.DistrCntrSaleEndDate,
      ActiveDocument.RoundingProfile,
      ActiveDocument.ProductUnitGroup,
      ActiveDocument.MaxDeliveryQtyStoreOrder,
      ActiveDocument.PriceFixingCategory,
      ActiveDocument.VariableSalesUnitIsNotAllowed,
      ActiveDocument.CompetitionPressureCategory,

      cast( 'X' as boole_d )                                                                       as IsActiveEntity,
      cast( ' ' as boole_d )                                                                       as HasActiveEntity,
      cast(
      case
       when DraftDocument.Draftkey is null
       then ' '
       else 'X'
      end  as boole_d)                                                                             as HasDraftEntity,
      cast(DraftDocument.ParentDraftKey as sysuuid_x )                                             as DraftAdministrativeDataUUID
}

union all

select from  P_ProductSalesDeliveryD   as DraftDocument
  inner join P_ProductD                as DraftRootDocument       on DraftRootDocument.Draftkey = DraftDocument.ParentDraftKey

  inner join I_DraftAdministrativeData as DraftAdministrativeData on DraftAdministrativeData.DraftUUID = DraftDocument.ParentDraftKey

{
  key DraftDocument.Draftkey                                                        as Draftkey,
      DraftDocument.ActiveProduct                                                   as ActiveProduct,
      DraftDocument.ActiveProductSalesOrg                                           as ActiveProductSalesOrg,
      DraftDocument.ActiveProductDistributionChnl                                   as ActiveProductDistributionChnl,
      DraftDocument.ParentDraftKey                                                  as ParentDraftKey,
      DraftRootDocument.product,
//      DraftDocument.productsalesorganization,

//      DraftDocument.productdistributionchannel,

      DraftDocument.minimumorderquantity,
      DraftDocument.supplyingplant,
      DraftDocument.pricespecificationproductgroup,
      DraftDocument.accountdetnproductgroup,
      DraftDocument.deliverynoteprocmindelivqty,
      DraftDocument.itemcategorygroup,
      DraftDocument.deliveryquantityunit,
      DraftDocument.deliveryquantity,
      DraftDocument.productsalesstatus,
      DraftDocument.productsalesstatusvaliditydate,
      DraftDocument.salesmeasureunit,
      cast(DraftDocument.ismarkedfordeletion as boole_d)                            as IsMarkedForDeletion,
      DraftDocument.producthierarchy,
      DraftDocument.firstsalesspecproductgroup,
      DraftDocument.secondsalesspecproductgroup,
      DraftDocument.thirdsalesspecproductgroup,
      DraftDocument.fourthsalesspecproductgroup,
      DraftDocument.fifthsalesspecproductgroup,
      DraftDocument.minimummaketoorderorderqty,
      //retail fields added on 25.4.16

      DraftDocument.logisticsstatisticsgroup,
      DraftDocument.volumerebategroup,
      DraftDocument.productcommissiongroup,
      DraftDocument.cashdiscountisdeductible,
      DraftDocument.pricingreferenceproduct,
      DraftDocument.assortmentgrade,
      DraftDocument.storelistingprocedure,
      DraftDocument.distrcntrlistingprocedure,
      DraftDocument.storelistingstartdate,
      DraftDocument.storelistingenddate,
      DraftDocument.distrcntrlistingstartdate,
      DraftDocument.distrcntrlistingenddate,
      DraftDocument.storesalestartdate,
      DraftDocument.storesaleenddate,
      DraftDocument.distrcntrsalestartdate,
      DraftDocument.distrcntrsaleenddate,
      DraftDocument.roundingprofile,
      DraftDocument.productunitgroup,
      DraftDocument.maxdeliveryqtystoreorder,
      DraftDocument.pricefixingcategory,
      DraftDocument.variablesalesunitisnotallowed,
      DraftDocument.competitionpressurecategory,

      cast( ' ' as boole_d )                                                        as IsActiveEntity,
      DraftDocument.hasactiveentity                                                 as HasActiveEntity,
      cast( ' ' as boole_d )                                                        as HasDraftEntity,
      cast(DraftDocument.ParentDraftKey as sysuuid_x )                              as DraftAdministrativeDataUUID
}
where
     DraftAdministrativeData.CreatedByUser   = $session.user
  or DraftAdministrativeData.InProcessByUser = $session.user      
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DRAFTADMINISTRATIVEDATA",
"I_PRODUCTSALESDELIVERY",
"P_PRODUCTD",
"P_PRODUCTSALESDELIVERYD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/