P_ProcOrdOpsInspLot

@AbapCatalog.sqlViewName: 'PPOROPINSPLOT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Process order operation inspection lot'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #BASIC
@VDM.private: true
define view P_ProcOrdOpsInspLot
  as select from qaop
    inner join   afvc                       on  qaop.aufpl = afvc.aufpl
                                            and qaop.aplzl = afvc.aplzl
    inner join   I_LogisticsOrder as _Order on  _Order.OrderInternalBillOfOperations = qaop.aufpl
                                            and _Order.OrderCategory                 = '40'
  //Association to other QM nodes

  association [1..1] to I_InspectionLot             as _InspectionLot             on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association [0..*] to I_InspectionCharacteristic  as _InspectionCharacteristic  on  $projection.InspectionLot               = _InspectionCharacteristic.InspectionLot
                                                                                  and $projection.InspPlanOperationInternalID = _InspectionCharacteristic.InspPlanOperationInternalID
  association [0..*] to I_InspectionSubset          as _InspectionSubset          on  $projection.InspectionLot               = _InspectionSubset.InspectionLot
                                                                                  and $projection.InspPlanOperationInternalID = _InspectionSubset.InspPlanOperationInternalID

  //Associations to views of other applications

  association [0..1] to I_WorkCenter                as _WorkCenter                on  $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
                                                                                  and _WorkCenter.WorkCenterTypeCode   = 'A'
  association [1..1] to I_Plant                     as _Plant                     on  $projection.InspectionOperationPlant = _Plant.Plant
  association [1..1] to I_BillOfOperationsType      as _BillOfOperationsType      on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_InspectionOperationStatus as _InspectionOperationStatus on  $projection.OrderInternalBillOfOperations = _InspectionOperationStatus.OrderInternalBillOfOperations
                                                                                  and $projection.InspPlanOperationInternalID   = _InspectionOperationStatus.InspPlanOperationInternalID

{
      @ObjectModel.foreignKey.association: '_InspectionLot'
  key qaop.prueflos  as InspectionLot,
  key qaop.vorglfnr  as InspPlanOperationInternalID,
      _Order.OrderID as ProcessOrder,
      qaop.aufpl     as OrderInternalBillOfOperations,
      afvc.aplzl     as OrderOperationInternalID,
      afvc.vornr     as InspectionOperation,
      @ObjectModel.foreignKey.association: '_Plant'
      afvc.werks     as InspectionOperationPlant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      afvc.plnty     as BillOfOperationsType,
      afvc.plnkn     as BOOOperationInternalID,
      @ObjectModel.foreignKey.association: '_Workcenter'
      afvc.arbid     as WorkCenterInternalID,
      afvc.objnr     as StatusObject,
      afvc.steus     as OperationControlProfile,
      afvc.rueck     as OperationConfirmation,
      afvc.subsys    as InspectionSubSystem,

      afvc.ltxa1     as OperationText,
      afvc.qkzprzeit as InspSbstIsTimeRelated,
      afvc.qkzprfrei as InspSbstHasNoTimeOrQuantity,
      afvc.aplfl     as Sequence,

      _InspectionLot.InspectionLotOrigin,

      // Associations

      _WorkCenter,
      _InspectionLot,
      _InspectionCharacteristic,
      _InspectionSubset,
      _InspectionOperationStatus,
      _Plant,
      _BillOfOperationsType,
      _InspectionLot._InspectionLotOrigin
}
where
  _InspectionLot.InspectionLotOrigin = '03' //only 03 is relevant for Operations

//  or _InspectionLot.InspectionLotOrigin = '04';

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONLOT",
"I_LOGISTICSORDER",
"AFVC",
"QAOP"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSTYPE",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONLOTORIGIN",
"I_INSPECTIONOPERATIONSTATUS",
"I_INSPECTIONSUBSET",
"I_PLANT",
"I_WORKCENTER"
],
"BASE":
[
"I_INSPECTIONLOT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/