P_ProcOrdAORList

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Process Orders for AOR'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_ProcOrdAORList as 
  select from I_PPAreaOfResponsibility as AOR
  inner join I_LogisticsOrder as _OrderBasic on AOR.Plant = _OrderBasic.Plant and _OrderBasic.ProductionSupervisor = ''
                                                    and _OrderBasic.OrderCategory = '40'
{
     key _OrderBasic.OrderID,
     _OrderBasic.OrderInternalBillOfOperations as OrderInternalID,
     _OrderBasic.OrderType,
     _OrderBasic.Plant,
     _OrderBasic.ProductionSupervisor,
     _OrderBasic.ObjectInternalID as ProcessOrderObjectNumber,
     AOR.WorkCenterInternalID
}
where AOR.ProductionSupervisor is initial and AOR.WorkCenterInternalID is initial
union all

//select from I_LogisticsOrder as Orders

//inner join I_PPAreaOfResponsibility as AOR1 on Orders.Plant = AOR1.Plant and Orders.ProductionSupervisor = AOR1.ProductionSupervisor and Orders.OrderCategory = '40'

select from I_PPAreaOfResponsibility as AOR1
inner join I_LogisticsOrder as _Orders on AOR1.Plant = _Orders.Plant and AOR1.ProductionSupervisor = _Orders.ProductionSupervisor 
                                                    and _Orders.OrderCategory = '40'
                                                    
{
    key _Orders.OrderID,
    _Orders.OrderInternalBillOfOperations as OrderInternalID,
    _Orders.OrderType,
    _Orders.Plant,
    _Orders.ProductionSupervisor,
    _Orders.ObjectInternalID as ProcessOrderObjectNumber,
    AOR1.WorkCenterInternalID
    //key Orders.OrderID

}
where AOR1.WorkCenterInternalID is initial
union all
select from I_PPAreaOfResponsibility as AOR2
inner join I_OrderOperationBasic as _OrderOperBasic on _OrderOperBasic.WorkCenterInternalID = AOR2.WorkCenterInternalID
inner join I_LogisticsOrder      as _OrdersBasic    on _OrdersBasic.OrderInternalBillOfOperations = _OrderOperBasic.OrderInternalID
                                                    and AOR2.Plant = _OrdersBasic.Plant
                                                    and _OrdersBasic.OrderCategory = '40'
{
    key _OrdersBasic.OrderID,
    _OrdersBasic.OrderInternalBillOfOperations as OrderInternalID,
    _OrdersBasic.OrderType,
    _OrdersBasic.Plant,
    _OrdersBasic.ProductionSupervisor,
    _OrdersBasic.ObjectInternalID as ProcessOrderObjectNumber,
    _OrderOperBasic.WorkCenterInternalID
}
where AOR2.ProductionSupervisor is initial 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOGISTICSORDER",
"I_ORDEROPERATIONBASIC",
"I_PPAREAOFRESPONSIBILITY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/