P_PrepaymentCPEContractAmount

@AbapCatalog.sqlViewName: 'PPMGCTRCPEAMT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm                   : #SESSION_VARIABLE
@VDM.private                                : true
@VDM.viewType                               : #COMPOSITE
@ObjectModel.usageType.sizeCategory         : #L
@ObjectModel.usageType.serviceQuality       : #C
@ObjectModel.usageType.dataClass            : #TRANSACTIONAL
@EndUserText.label: 'Prepayment Contract CPE Amount'
define view P_PrepaymentCPEContractAmount
  -- Valid Doc Types
  as select from I_PrepayWrkCtrAllowedDocTypes as DocTypes
  -- Document Header
    inner join   I_PreAgrmtTradingContract     as Document     on Document.TradingContractType = DocTypes.PrepaymentAgrmtRefDocumentType
  -- Document Item
    inner join   I_PreAgrmtTradingContractItem as DocumentItem on DocumentItem.TradingContract = Document.TradingContract
  -- Material and Commodity
    inner join   I_PrepaymentMaterial          as Material     on DocumentItem.Material = Material.Material
  -- CPE Price
  association [0..1] to P_PrepaymentDocumentMarketVal as CPEPrice on  CPEPrice.TradingContract           = Document.TradingContract
                                                                  and CPEPrice.TradingContractItem       = DocumentItem.TradingContractItem
                                                                  and CPEPrice.PrepaymentRefDocCondition = Document.PrepaymentRefDocCondition
                                                                  and Material.Commodity                 is not initial

{
  key DocTypes.PrepaymentAgrmtWorkCenterType                 as PrepaymentAgrmtWorkCenterType,
  key DocTypes.PrepaymentAgrmtRefDocumentCat                 as PrepaymentAgrmtRefDocumentCat,
  key cast( 'BUS2124' as ppmgac_e_link_bus )                 as PrepaymentAgrmtRefBusObject,
  key Document.TradingContract                               as DocNumber,
  key DocumentItem.TradingContractItem                       as DocumentItemNumber,
      lpad( Document.TradingContract, 25, '0' )              as PrepaymentAgrmtRefDocument,
      Document.CompanyCode                                   as CompanyCode,
      Document.TradingContractType                           as DocumentType,
      @Semantics.amount.currencyCode: 'PrepaymentTotalAmtCrcy'
      cast( CPEPrice.PrepaymentTotalAmt as abap.curr(23,2) ) as PrepaymentTotalAmt,
      @Semantics.currencyCode: true
      DocumentItem.TrdgContrTotalNetAmountCrcy               as PrepaymentTotalAmtCrcy,
      CPEPrice.PrepaymentTotalAmtIsFixedPrice
}
where
  DocTypes.PrepaymentAgrmtRefDocumentCat = 'TC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PREAGRMTTRADINGCONTRACT",
"I_PREAGRMTTRADINGCONTRACTITEM",
"I_PREPAYMENTMATERIAL",
"I_PREPAYWRKCTRALLOWEDDOCTYPES",
"P_PREPAYMENTDOCUMENTMARKETVAL"
],
"ASSOCIATED":
[
"P_PREPAYMENTDOCUMENTMARKETVAL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/