P_PrdtdDelivProcgDlyApplyData

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PDELIVPROCGPAD'

define view P_PrdtdDelivProcgDlyApplyData

as select from I_SalesDocumentItem as Item                                                         
                                                                   
inner join I_SalesDocument                     as SalesDocument     on  Item.SalesDocument = SalesDocument.SalesDocument

left outer to one join I_CalendarDate          as CalendarDate      on  Item.CreationDate = CalendarDate.CalendarDate                                                      

left outer to one join I_SDDocumentPartner     as HeaderShipToParty on  Item.SalesDocument = HeaderShipToParty.SDDocument
                                                                    and HeaderShipToParty.PartnerFunction = 'WE' 

left outer to one join I_SDDocumentItemPartner as ItemShipToParty   on  Item.SalesDocument = ItemShipToParty.SDDocument
                                                                    and Item.SalesDocumentItem = ItemShipToParty.SDDocumentItem
                                                                    and ItemShipToParty.PartnerFunction = 'WE'                                                            

{
  //Key

  key Item.SalesDocument,
  key Item.SalesDocumentItem,
  
  // Delivery Processing

  cast (0 as deliveryprocgdelay) as DelivProcgDelayInDays, //the apply data set needs the same data structure as the training data set

  
  //Category 

  Item.SDDocumentCategory, 
  Item.SalesDocumentItemCategory, 
  Item.SalesDocumentItemType, 
  Item.CompletionRule, 
  
  SalesDocument.SalesDocumentType, 
  SalesDocument.SalesDocumentProcessingType, 
    
  //Admin 

  Item.CreationDate as ItemCreationDate,  
  Item.CreationTime as ItemCreationTime,
  Item.LastChangeDate as ItemLastChangeDate,  
  
  SalesDocument.CreationDate, 
  SalesDocument.CreationTime, 
  SalesDocument.LastChangeDate, 
  SalesDocument.LastChangeDateTime, 
  
  cast (CalendarDate.CalendarYear as creation_date_year) as ItemCreationDateYear,
  cast (CalendarDate.CalendarMonth  as creation_date_month) as ItemCreationCalendarMonth,
  cast (CalendarDate.CalendarWeek  as creation_date_week) as ItemCreationCalendarWeek,
  
  //Organization 

  Item.Division,
  
  SalesDocument.SalesOrganization, 
  SalesDocument.DistributionChannel, 
  cast (SalesDocument.OrganizationDivision as organization_division) as OrganizationDivision, 
  SalesDocument.SalesGroup, 
  SalesDocument.SalesOffice, 
   
  //Product

  Item.Material, 
  Item.OriginallyRequestedMaterial, 
  Item.MaterialByCustomer, 
  Item.InternationalArticleNumber, 
  Item.Batch, 
  Item.ProductHierarchyNode, 
  Item.ProductCatalog, 
  Item.MaterialSubstitutionReason, 
  Item.MaterialGroup, 
  Item.AdditionalMaterialGroup1, 
  Item.AdditionalMaterialGroup2, 
  Item.AdditionalMaterialGroup3, 
  Item.AdditionalMaterialGroup4, 
  Item.AdditionalMaterialGroup5, 
  Item.ProductConfiguration, 
  Item.MRPArea, 
  Item.BillOfMaterial, 
  Item.ProdAvailabilityCheckGroup,  
  
  //Partner

  SalesDocument.SoldToParty,
  cast( coalesce(ItemShipToParty.Customer, HeaderShipToParty.Customer)as kunwe) as ShipToParty,
  
  //Sales 

  Item.SalesDocumentItemText,
  SalesDocument.RequestedDeliveryDate as RequestedDeliveryDate, //only in apply data set 

  Item.OrderQuantity, 
  Item.OrderQuantityUnit, 
  Item.ConfdDelivQtyInOrderQtyUnit, 
  Item.TargetDelivQtyInOrderQtyUnit, 
  Item.ConfdDeliveryQtyInBaseUnit, 
  Item.BaseUnit, 
  Item.RequestedQuantity, 
  Item.RequestedQuantityUnit, 
  Item.RequestedQuantityInBaseUnit, 
  Item.ItemGrossWeight, 
  Item.ItemNetWeight, 
  Item.ItemWeightUnit, 
  Item.ItemVolume, 
  Item.ItemVolumeUnit, 
  Item.SalesDistrict, 
  Item.SalesDeal, 
  cast (Item.SalesPromotion as sales_promotion) as  SalesPromotion, 
  cast (Item.RetailPromotion as retail_promotion) as  RetailPromotion, 
  Item.CustomerGroup, 
  Item.RequirementSegment, 
  Item.QuantityIsFixed,  
  
  SalesDocument.AdditionalCustomerGroup1, 
  SalesDocument.AdditionalCustomerGroup2, 
  SalesDocument.AdditionalCustomerGroup3, 
  SalesDocument.AdditionalCustomerGroup4, 
  SalesDocument.AdditionalCustomerGroup5, 
  SalesDocument.CreditControlArea, 
  SalesDocument.SalesDocumentDate,
  SalesDocument.SDDocumentReason, 
       
  //Pricing

  Item.NetAmount, 
  Item.TransactionCurrency, 
  Item.MaterialPricingGroup, 
  Item.NetPriceAmount, 
  Item.NetPriceQuantity, 
  Item.NetPriceQuantityUnit, 
  Item.Subtotal1Amount, 
  Item.Subtotal2Amount, 
  Item.Subtotal3Amount, 
  Item.Subtotal4Amount, 
  Item.Subtotal5Amount, 
  Item.Subtotal6Amount,  
  SalesDocument.TotalNetAmount,
   
  //Shipping

  Item.ShippingPoint, 
  Item.ShippingType, 
  Item.InventorySpecialStockType, 
  Item.DeliveryPriority, 
  Item.Plant, 
  Item.StorageLocation, 
  Item.Route, 
  Item.DeliveryGroup, 
  Item.DeliveryDateQuantityIsFixed, 
  Item.PartialDeliveryIsAllowed, 
  Item.MaxNmbrOfPartialDelivery, 
  Item.UnlimitedOverdeliveryIsAllowed, 
  Item.OverdelivTolrtdLmtRatioInPct, 
  Item.UnderdelivTolrtdLmtRatioInPct, 
  Item.MinDeliveryQtyInBaseUnit, 
  Item.OpenDeliveryLeadingUnitCode, 
  
  SalesDocument.ShippingCondition, 
  SalesDocument.CompleteDeliveryIsDefined, 
  
  //Fashion

  Item.ProductSeasonYear, 
  Item.ProductSeason, 
  Item.ProductCollection, 
  Item.ProductTheme, 
  Item.ProductCharacteristic1, 
  Item.ProductCharacteristic2, 
  Item.ProductCharacteristic3, 
  Item.ShippingGroupNumber, 
  Item.ShippingGroupRule,
  
  //Payment 

  Item.IncotermsClassification, 
  Item.IncotermsTransferLocation, 
  Item.IncotermsLocation1, 
  Item.IncotermsLocation2, 
  Item.CustomerPaymentTerms, 
  Item.PaymentMethod, 
    
  //Accounting

  Item.BusinessArea, 
  Item.ProfitCenter, 
  @VDM.lifecycle: { status: #DEPRECATED, successor: 'WBSElementInternalID' }
  Item.WBSElement, 
  @Analytics.internalName: #LOCAL
  Item.WBSElementInternalID, 
  Item.OrderID,
  Item.ProfitabilitySegment_2 as ProfitabilitySegment, 
  SalesDocument.CostCenter, 
  SalesDocument.ControllingArea, 
  
  //Reference

  Item.HigherLevelItem 
   
 }
       
 where ( Item.SDDocumentCategory = 'C' or      --> Order
         Item.SDDocumentCategory = 'I' )       --> Order w/o charge
  and  ( TotalDeliveryStatus = 'A' or
         TotalDeliveryStatus = 'B'  )  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SDDOCUMENTITEMPARTNER",
"I_SDDOCUMENTPARTNER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/