P_PrcFixationOptionCnvrsnSls

@AbapCatalog.sqlViewName: 'PPRCFIXOPTCNSLS'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM.viewType: #BASIC
@VDM.private: true
@AbapCatalog.preserveKey: true

@ObjectModel.usageType.sizeCategory         : #L
@ObjectModel.usageType.serviceQuality       : #B
@ObjectModel.usageType.dataClass            : #TRANSACTIONAL

define view P_PrcFixationOptionCnvrsnSls
  as select from    cped_formdoc     as formdoc
    inner join      cped_extension   as termextension on  formdoc.docitem_guid = termextension.docitem_guid
                                                      and formdoc.cond_type    = termextension.cond_type
    inner join      cped_prcfix_def  as prcfix_def    on termextension.ref_guid = prcfix_def.ref_guid
    inner join      cped_knumvtoguid as knumvtoguid   on knumvtoguid.docitem_guid = formdoc.docitem_guid
    left outer join cped_termgrpout  as termgrpout    on  termgrpout.forminput_guid = formdoc.forminput_guid
                                                      and termgrpout.termno         = termextension.termno
    left outer join cped_termout     as termout       on  termout.docitem_guid = knumvtoguid.docitem_guid
                                                      and termout.cond_type    = termextension.cond_type
                                                      and termout.termno       = termextension.termno
    left outer join cped_termconvout as termconvout   on ( termconvout.termconvout_guid = termout.termconvout_guid or 
                                                           termconvout.termconvout_guid = termgrpout.termconvout_guid )
    inner join      vbak             as vbak          on vbak.knumv = knumvtoguid.knumv
    inner join      vbap             as vbap          on  vbap.vbeln = vbak.vbeln
                                                      and vbap.posnr = knumvtoguid.kposn
{
  key vbak.vbeln                     as SalesDocument, 
  key vbap.posnr                     as SalesDocumentItem, 
  key formdoc.cond_type              as ConditionType,
  key termextension.termno           as ConditionTermNumber,
      termconvout.termconvout_guid,
      termconvout.convplace,
      termconvout.usedexchrate,
      termconvout.usedcurrfrom       as PrcgCndnTermCnvrsnSourceCrcy,
      termconvout.usedcurrto         as PrcgCndnTermCnvrsnTargetCrcy,
      termconvout.usedfactorfrom,
      termconvout.usedfactorfrom_df34,
      termconvout.useduomfrom,
      termconvout.usedfactorto,
      termconvout.usedfactorto_df34,
      termconvout.useduomto,
      termconvout.forecast_status,
      termconvout.quan_adj_factor
}
where
      termextension.ref_type   =  'T'
  and termextension.ref_kind   =  'PRCFIX_DEFINITION'
  and termconvout.convplace    =  '0062'
  and termconvout.usedcurrfrom <> termconvout.usedcurrto
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CPED_EXTENSION",
"CPED_FORMDOC",
"CPED_KNUMVTOGUID",
"CPED_PRCFIX_DEF",
"CPED_TERMCONVOUT",
"CPED_TERMGRPOUT",
"CPED_TERMOUT",
"VBAK",
"VBAP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/