P_PlanBalFlowDateFunc

@AbapCatalog.sqlViewName: 'PFIPLNBFDF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST, #UNION]
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
define view P_PlanBalFlowDateFunc as select from    I_FinancialPlanningEntryItem
              inner join   P_FiscalDateFunctionValueFY   on (     P_FiscalDateFunctionValueFY.FiscalYearVariant        = I_FinancialPlanningEntryItem.FiscalYearVariant
                                                              and P_FiscalDateFunctionValueFY.DateFunctionValidityDate = $session.system_date
                                                              and P_FiscalDateFunctionValueFY.FiscalYearStartDate     <= I_FinancialPlanningEntryItem.PostingDate
                                                              and P_FiscalDateFunctionValueFY.DateFunctionEndDate     >= I_FinancialPlanningEntryItem.PostingDate )
                                                         or (     P_FiscalDateFunctionValueFY.FiscalYearVariant        = I_FinancialPlanningEntryItem.FiscalYearVariant 
                                                              and P_FiscalDateFunctionValueFY.DateFunctionValidityDate = $session.system_date
                                                              and P_FiscalDateFunctionValueFY.StartFiscalYear         <= I_FinancialPlanningEntryItem.LedgerFiscalYear
                                                              and P_FiscalDateFunctionValueFY.EndFiscalYear           >= I_FinancialPlanningEntryItem.LedgerFiscalYear 
                                                              and                                                        I_FinancialPlanningEntryItem.FiscalPeriod = '000' )
{
key cast( 'P' as fis_actual_plan_code preserving type )   as ActualPlanCode,
key PlanningCategory,
key Ledger,
key CompanyCode,
key DateFunction,
key FiscalYearPeriod,  
key cast( '2         ' as fis_glaccount_flow_type preserving type )   as GLAccountFlowType,      

// *************    


   I_FinancialPlanningEntryItem.FiscalYearVariant,
   LedgerFiscalYear,
   I_FinancialPlanningEntryItem.FiscalYear,

   FiscalPeriod,                                                               
   PostingDate,
   
   ChartOfAccounts,
   GLAccount,
   
   ControllingArea,
   CostCenter,
   ProfitCenter,
   FunctionalArea,
   BusinessArea,
   Segment,
   
// use Sold...   

   Product,           // MATNR

   ProductGroup,      // MATKL_MM 

   
   SoldProduct,       // MATNR_COPA

   SoldProductGroup,  // MATKL

   
   Customer,
   CustomerGroup,   

   cast( '          ' as md_supplier preserving type ) as Supplier,    
   
   @ObjectModel.foreignKey.association: '_GlobalCurrency'
   @Semantics.currencyCode:true
   GlobalCurrency,
   @DefaultAggregation: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
   AmountInGlobalCurrency,
   @DefaultAggregation: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
   FixedAmountInGlobalCrcy,   
   
   @DefaultAggregation: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }        
   case when PostingDate <> '00000000' then AmountInGlobalCurrency    
                                       else cast (0 as fis_ksl)
   end
   as KslwoBCF,
      
   @DefaultAggregation: #SUM
   @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }        
   case when PostingDate = '00000000' then AmountInGlobalCurrency    
                                      else cast (0 as fis_ksl)
   end
   as KslonlyBCF,     
   
   _GlobalCurrency,
   _FiscalCalendarDate,
   _GLAccountInChartOfAccounts,
   _FiscalYearVariant     
                                     
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALPLANNINGENTRYITEM",
"P_FISCALDATEFUNCTIONVALUEFY"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_FISCALCALENDARDATE",
"I_FISCALYEARVARIANT",
"I_GLACCOUNTINCHARTOFACCOUNTS"
],
"BASE":
[
"I_FINANCIALPLANNINGENTRYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/