P_PT_TaxReturnBoxItem

@VDM.viewType: #COMPOSITE
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType:{
   serviceQuality: #D,
   sizeCategory: #XL,
   dataClass: #MIXED
}
define view entity P_PT_TaxReturnBoxItem

  with parameters
    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id,
    P_ReportingCountry  : land1

  as select from           I_StRpTaxReturnBoxCube (
                                                                                            P_TaxIsDeferredRelevant: 'N',
                                                                                            P_TaxIsMossRelevant   :  'N',
                                                                                            P_StatryRptgEntity     : $parameters.P_StatryRptgEntity ,
                                                                                            P_StatryRptCategory    : $parameters.P_StatryRptCategory,
                                                                                            P_StatryRptRunID       : $parameters.P_StatryRptRunID,
                                                                                            P_ReportingCountry     : $parameters.P_ReportingCountry,
                                                                                            P_TaxBoxConfiguration  : '2' )
  //To Get VAT Registration Number, Supplier, Customer

    left outer to one join P_FristKDOperationItem as BP   on  I_StRpTaxReturnBoxCube.CompanyCode        = BP.CompanyCode
                                                          and I_StRpTaxReturnBoxCube.FiscalYear         = BP.FiscalYear
                                                          and I_StRpTaxReturnBoxCube.AccountingDocument = BP.AccountingDocument

{
  key I_StRpTaxReturnBoxCube.CompanyCode,
  key I_StRpTaxReturnBoxCube.AccountingDocument,
  key I_StRpTaxReturnBoxCube.FiscalYear,
  key I_StRpTaxReturnBoxCube.TaxItem,
  key I_StRpTaxReturnBoxCube.TransactionTypeDetermination,
  key I_StRpTaxReturnBoxCube.DebitCreditCode,
  key I_StRpTaxReturnBoxCube.AccountingDocumentType,
  key I_StRpTaxReturnBoxCube.SupplierAccountGroup,
  key I_StRpTaxReturnBoxCube.TaxBox,
  key I_StRpTaxReturnBoxCube.TaxDeclnAmountType,
  key I_StRpTaxReturnBoxCube.TaxBoxStrucValidityStartDate as ValidityStartDate,
  key I_StRpTaxReturnBoxCube.UnifiedTaxBoxStructureType,
  key I_StRpTaxReturnBoxCube.TaxGroup,
  key I_StRpTaxReturnBoxCube.TaxItemGrpgDebitCreditCode,
  key I_StRpTaxReturnBoxCube.TaxItemGrpgAcctgDocumentType,
  key I_StRpTaxReturnBoxCube.TaxItemGrpgSupplierAcctGroup,
  key I_StRpTaxReturnBoxCube.TaxItemGrpgSpecialGLCode,
  key I_StRpTaxReturnBoxCube.StatryRptgEntity,
  key I_StRpTaxReturnBoxCube.StatryRptCategory,
  key I_StRpTaxReturnBoxCube.StatryRptRunID,

      I_StRpTaxReturnBoxCube.Country,
      I_StRpTaxReturnBoxCube.TaxCode,
      I_StRpTaxReturnBoxCube.TaxItemGroupingVersion,
      I_StRpTaxReturnBoxCube.TaxBoxStructureType,
      I_StRpTaxReturnBoxCube.TaxBoxStrucValidityEndDate   as ValidityEndDate,

      I_StRpTaxReturnBoxCube.TaxCalculationProcedure,
      I_StRpTaxReturnBoxCube.TaxRate,
      I_StRpTaxReturnBoxCube.TaxRateValidityStartDate,
      I_StRpTaxReturnBoxCube.GLAccount,
      I_StRpTaxReturnBoxCube.TaxItemGroup,
      I_StRpTaxReturnBoxCube.ReferenceDocumentType,
      // Get the value from Reference (XBLNR)

      I_StRpTaxReturnBoxCube.DocumentReferenceID,

      I_StRpTaxReturnBoxCube.PostingDate,
      I_StRpTaxReturnBoxCube.DocumentDate,
      I_StRpTaxReturnBoxCube.TaxReportingDate,
      I_StRpTaxReturnBoxCube.ReportingDate,
      I_StRpTaxReturnBoxCube.FiscalPeriod,
      //  Get the value from HeaderText (BKTXT)

      I_StRpTaxReturnBoxCube.AccountingDocumentHeaderText,

      I_StRpTaxReturnBoxCube.CompanyCodeCountry,
      I_StRpTaxReturnBoxCube.ReportingCountry,
      I_StRpTaxReturnBoxCube.TaxReturnCountry,

      I_StRpTaxReturnBoxCube.CompanyCodeCurrency,

      I_StRpTaxReturnBoxCube.DocumentCurrency,

      I_StRpTaxReturnBoxCube.ReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      I_StRpTaxReturnBoxCube.AmountInReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      I_StRpTaxReturnBoxCube.TaxBaseAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      I_StRpTaxReturnBoxCube.TaxAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      I_StRpTaxReturnBoxCube.NonDeductibleInputTaxAmount,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      I_StRpTaxReturnBoxCube.TaxBaseAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      I_StRpTaxReturnBoxCube.TaxAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      I_StRpTaxReturnBoxCube.TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      I_StRpTaxReturnBoxCube.TaxAmount,
      I_StRpTaxReturnBoxCube.TaxType,

      // Get the original Invoice number, FiscalYear

      BP.InvoiceReference,
      BP.InvoiceReferenceFiscalYear,

      // Get the VAT Registration Number

      BP.Customer,
      BP.Supplier,
      BP.VATRegistration,

      case
      when BP.Supplier <> ''
         then
          case
              when  BP.VATRegistration <> '' then BP.VATRegistration
              else  BP._Supplier.VATRegistration
          end
        when BP.Customer <> ''
         then
          case
              when BP.VATRegistration <> '' then BP.VATRegistration
              else BP._Customer.VATRegistration
          end
      else ''
      end                                                 as CustomerSupplierVATRegn,

      cast(
      case
      when BP.SupplierIsOneTimeAccount is not initial or BP.CustomerIsOneTimeAccount is not initial
        then BP._OneTimeAccountBP.Country
      when BP.Supplier <> ''
        then  BP._Supplier.Country
      when BP._Customer.Customer <> ''
        then  BP._Customer.Country
      end as glo_partner_country)                         as BPCountry,

      cast(
      case
      when BP.Supplier <> ''
         then
          case
              when  BP.VATRegistration <> '' then  left(BP.VATRegistration, 2)
              else  left(BP._Supplier.VATRegistration, 2)
          end
        when BP.Customer <> ''
         then
          case
              when BP.VATRegistration <> '' then left(BP.VATRegistration, 2)
              else left(BP._Customer.VATRegistration, 2)
          end
      else ''
      end     as  stceg_l )                               as VATRegistrationCountry,

      // Get FinancialAccountType

      BP.FinancialAccountType,

      I_StRpTaxReturnBoxCube.TargetTaxCode,
      I_StRpTaxReturnBoxCube.CAReconciliationKey,
      I_StRpTaxReturnBoxCube.StatryRptRun,
      I_StRpTaxReturnBoxCube.TaxTypeName,
      I_StRpTaxReturnBoxCube.TaxIsNotDeductible,
      I_StRpTaxReturnBoxCube.TaxBoxStructure,
      I_StRpTaxReturnBoxCube.TaxBoxStructureName,
      I_StRpTaxReturnBoxCube.TaxBoxName,
      I_StRpTaxReturnBoxCube.TaxBoxCondition,
      I_StRpTaxReturnBoxCube._TaxTypeText

}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_ONETIMEACCOUNTBP",
"I_STRPTAXRETURNBOXCUBE",
"I_SUPPLIER",
"P_FRISTKDOPERATIONITEM"
],
"ASSOCIATED":
[
"I_TAXTYPETEXT"
],
"BASE":
[
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/