P_PT_GLAccountBOPLineItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}

define view entity P_PT_GLAccountBOPLineItem
  as select from P_PT_GLAccountBOPCustUnion as Cust
    inner join   I_GLAccountLineItem        as Je on Cust.CompanyCode = Je.CompanyCode
                                             and
                                            (
                                               (
                                                 Cust.Account_To is not initial
                                                 and Je.GLAccount between Cust.Account_From and Cust.Account_To
                                               )
                                               or
                                               (
                                                  Cust.Account_To is initial
                                                 and Je.GLAccount  = Cust.Account_From
                                               )
                                             )

    inner join      I_Ledger                          on  Je.Ledger                = I_Ledger.Ledger
                                                      and I_Ledger.IsLeadingLedger = 'X'                                                    

{
  key  Je.SourceLedger                                as Sourceledger,
  key  Je.CompanyCode                                 as CompanyCode,
  key  Je.FiscalYear                                  as FiscalYear,
  key  Je.AccountingDocument                          as AccountingDocument,
  key  Je.LedgerGLLineItem                            as LedgerGLLineItem,
  key  Je.Ledger                                      as Ledger,
       Je.LedgerFiscalYear                            as LedgerFiscalYear,
       Je.AccountingDocumentCategory                  as AccountingDocumentCategory,
       Je.PostingDate                                 as Postingdate,
       Je.ClearingDate                                as Clearingdate,
       Je.GLAccount                                   as GLAccount,
       Je.GLAccountType                               as GLAccountType,
       Je.FinancialAccountType                        as FinancialAccountType,
       Je.HouseBankAccount                            as HouseBankAccount,
       Je.DebitCreditCode                             as DebitCreditCode,
       Je.BalanceTransactionCurrency                  as BalanceTransactionCurrency,
       Je._BalanceTransactionCurrency.CurrencyISOCode as CurrencyISOCode,
       @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
       Je.AmountInBalanceTransacCrcy                  as AmountInBalanceTransacCrcy,
       
       case
         when Je.HouseBank = ''
           then Je._GLAccountInCompanyCode.HouseBank
         else Je.HouseBank
       end                                            as HouseBank,

       cast( 'P' as fipt_cope_value_type preserving type) as PT_BOPValueType


}
where

          Je._GLAccountInCompanyCode.ReconciliationAccountType  <> 'K'
  and     Je._GLAccountInCompanyCode.ReconciliationAccountType  <> 'D'
  and(
          Je.AccountingDocumentCategory                        is initial
    or    Je.AccountingDocumentCategory                        =       'L'
    or    Je.AccountingDocumentCategory                        =       'U'
    or    Je.AccountingDocumentCategory                        =       'C'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CURRENCY",
"I_GLACCOUNTINCOMPANYCODE",
"I_GLACCOUNTLINEITEM",
"I_LEDGER",
"P_PT_GLACCOUNTBOPCUSTUNION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/