P_PT_DeliveryNumberRange

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Delivery Document Number Range'
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #M,
    dataClass: #CUSTOMIZING
}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_PT_DeliveryNumberRange
  as select from I_PT_DeliveryNumberRange
  association [0..1] to I_CompanyCode                 as _CompanyCode on  $projection.CompanyCode = _CompanyCode.CompanyCode
  // Plant abroad scenrio

  //association [0..1] to I_CountrySalesTax         as _PlantAbroad on  _PlantAbroad.CompanyCode            = $projection.CompanyCode

  //                                                                and _PlantAbroad.VATRegistrationCountry = 'PT'

  association [0..1] to P_PT_SimplifiedDelivDocType   as _DocType     on  _DocType.DeliveryDocumentType = $projection.DeliveryDocumentType
  association [0..1] to I_NumberRangeInterval         as _NumberRange on  _NumberRange.NumberRangeObject    = 'GLO_PT_OBD'
                                                                      and _NumberRange.NumberRangeSubObject = $projection.CompanyCode
                                                                      and _NumberRange.NumberRangeInterval  = $projection.PT_SeriesNumberRangeInterval
  association [0..1] to P_PT_DgtlSgntrStartDeliveries as _StartDeliv  on  $projection.CompanyCode                  = _StartDeliv.CompanyCode
                                                                      and $projection.PT_SeriesNumberRangeInterval = _StartDeliv.PT_SeriesNumberRangeInterval

{
  key       CompanyCode,
            //key    coalesce(_CompanyCode.VATRegistration, _PlantAbroad.CompanyVATRegistration) as VATRegistration,

  key       cast( substring(_CompanyCode.VATRegistration, 3, 18) as stceg) as VATRegistration,
  key       PortugueseDgtlSignatureSeries                                  as PT_SeriesIdentifier,
  key       case _DocType.SpecialDocumentType
              when 'D'
              then 'R'
              else 'N'
              end                                                          as PT_SeriesTypeCode,
  key       'MG'                                                           as PT_SeriesDocumentClass,
  key       case
              when _StartDeliv.PT_SeriesDocumentType is not initial
              then _StartDeliv.PT_SeriesDocumentType
              else DeliveryType
              end                                                          as PT_SeriesDocumentType,

            _NumberRange.NumberRangeObject                                 as PT_SeriesNumberRangeObject,
            _NumberRange.NumberRangeSubObject                              as PT_SeriesNumberRangeSubObject,
            _NumberRange.NumberRangeToYear                                 as PT_SeriesNumberRangeToYear,

            'D'                                                            as PT_SeriesBusinessProcess,

            cast( case
            when LTRIM(_NumberRange.NumberRangeLevel, '0') = ''
              then _NumberRange.NumberRangeFromNumber
            else
              LTRIM(_NumberRange.NumberRangeLevel, '0')
            end as glo_pt_series_sn)                                       as PT_SeriesStartNumber,

             cast (_NumberRange.NumberRangeToNumber as glo_pt_series_ln) as PT_SeriesLastNumber, 
            // set editable based on if any documents posted already for this series

            //            case

            //            when _SrsDocCount.DocumentCount > 0

            //            then ''

            //            else

            //            'X'

            //            end                                                            as PT_SeriesValdtnCodeIsEditable,


            case
            when _StartDeliv.PT_SeriesValdtnCode <> ''
            then ''
            else
            'X'
            end                                                            as PT_SeriesValdtnCodeIsEditable,


            DeliveryDocumentType,
            NumberRange                                                    as PT_SeriesNumberRangeInterval
}
where
      PortugueseDgtlSignatureSeries like 'D___'
  and DeliveryType                  is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_NUMBERRANGEINTERVAL",
"I_PT_DELIVERYNUMBERRANGE",
"P_PT_DGTLSGNTRSTARTDELIVERIES",
"P_PT_SIMPLIFIEDDELIVDOCTYPE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/