P_PL_SAFTTaxVATDeclnBasic

@AbapCatalog.sqlViewName: 'PPLSAFTTAXVATDCB'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PL_SAFTTaxVATDeclnBasic
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum
  as select from P_PL_SAFTTaxVATDeclUpdFields(P_StartDate : $parameters.P_StartDate, P_EndDate: $parameters.P_EndDate)
{
  key CompanyCode,
  key PL_SAFTTaxVATDeclnBox as PL_DeclarationTaxCode,

      FreeDefinedIndicator1 as FieldFlag,

      @Semantics.currencyCode: true
      CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TotalAmountInCoCodeCrcy,

      FreeDefinedNote       as FieldTextValue
}

union

select from  P_PL_SAFTTAXVATAux(P_StartDate : $parameters.P_StartDate, P_EndDate: $parameters.P_EndDate) as TaxItem

{
  key CompanyCode,
  key PL_DeclarationTaxCode,

      ' '                          as FieldFlag,

      @Semantics.currencyCode: true
      CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      sum(TotalAmountInCoCodeCrcy) as TotalAmountInCoCodeCrcy,

      ''                           as FieldTextValue
}
group by
  CompanyCode,
  PL_DeclarationTaxCode,
  CompanyCodeCurrency

union

select from I_AccountingDocument
{

  key CompanyCode,
  key 'P_63'            as PL_DeclarationTaxCode,
      '1'               as FieldFlag,

      cast('' as waers) as CompanyCodeCurrency,
      0                 as TotalAmountInCoCodeCrcy,
      ''                as FieldTextValue

}
where
       TaxReportingDate           between $parameters.P_StartDate and $parameters.P_EndDate
  and(
       Reference1InDocumentHeader like '%&_____1%'
    or Reference1InDocumentHeader like '%&_____Y%'
  )

union

select from I_AccountingDocument
{

  key CompanyCode,
  key 'P_64'            as PL_DeclarationTaxCode,
      '1'               as FieldFlag,

      cast('' as waers) as CompanyCodeCurrency,
      0                 as TotalAmountInCoCodeCrcy,
      ''                as FieldTextValue

}
where
       TaxReportingDate           between $parameters.P_StartDate and $parameters.P_EndDate
  and(
       Reference1InDocumentHeader like '%&______1%'
    or Reference1InDocumentHeader like '%&______Y%'
  )

union

select from I_AccountingDocument
{

  key CompanyCode,
  key 'P_66'            as PL_DeclarationTaxCode,
      '1'               as FieldFlag,

      cast('' as waers) as CompanyCodeCurrency,
      0                 as TotalAmountInCoCodeCrcy,
      ''                as FieldTextValue

}
where
       TaxReportingDate           between $parameters.P_StartDate and $parameters.P_EndDate
  and(
       Reference1InDocumentHeader like '%&____1%'
    or Reference1InDocumentHeader like '%&____Y%'
    or Reference1InDocumentHeader like '%&___1%' //TT_D

    or Reference1InDocumentHeader like '%&___Y%' //TT_D

  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"P_PL_SAFTTAXVATAUX",
"P_PL_SAFTTAXVATDECLUPDFIELDS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/