P_PL_SAFTInvoiceItem

@AbapCatalog.sqlViewName: 'PPLSAFTINVITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #P
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PL_SAFTInvoiceItem
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum
  as select from P_PL_SAFTSalesInvItem( P_StartDate:$parameters.P_StartDate, P_EndDate: $parameters.P_EndDate)
{

  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key BillingDocumentItem,

      ltrim(cast(BillingDocument as abap.char(30)),'0') as InvoiceDocumentNumber,
      BillingDocumentItemText                           as MaterialDescription,
      @Semantics.unitOfMeasure: true
      BillingQuantityUnit                               as UnitOfMeasure,
      @Semantics.currencyCode: true
      TransactionCurrency,
      @Semantics.currencyCode: true
      CompanyCodeCurrency,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      BillingQuantity                                   as Quantity,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case when PL_SAFTInvoiceType = 'KOREKTA'
            then abs(NetPriceAmount)
           when ItemSignIsReversed is not initial
            then -NetPriceAmount
           else NetPriceAmount
      end                                               as NetPriceAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( case when ItemSignIsReversed is not initial
            then -NetAmount
            else NetAmount end as fis_wsl)              as NetAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case when ItemSignIsReversed is not initial
        then -DiscountAmount
        else DiscountAmount
      end                                               as DiscountAmount,

      //      coalesce(lower(_Tax.PL_SAFTTaxPercentageCode),'zw') as TaxRate

      coalesce(lower(PL_SAFTTaxPercentageCode),'zw')    as TaxRate  
}

union

select from P_PL_SAFTAcctgInvoiceItem( P_StartDate:$parameters.P_StartDate, P_EndDate: $parameters.P_EndDate)
{

  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key cast(concat('000',AccountingDocumentItem) as posnr_vf) as BillingDocumentItem,

      InvoiceDocumentNumber,
      DocumentItemText                                       as MaterialDescription,
      @Semantics.unitOfMeasure: true
      BaseUnit                                               as UnitOfMeasure,
      @Semantics.currencyCode: true
      TransactionCurrency,
      @Semantics.currencyCode: true
      CompanyCodeCurrency,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      Quantity,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      NetPriceAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      AmountInTransactionCurrency                            as NetAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      0                                                      as DiscountAmount,

      coalesce(_Tax.PL_SAFTTaxPercentageCode,'zw')           as TaxRate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PL_SAFTACCTGINVOICEITEM",
"P_PL_SAFTINVOICETAX",
"P_PL_SAFTSALESINVITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/