P_PL_SAFTInvoiceHeaderBasic

@AbapCatalog.sqlViewName: 'PPLSAFTINVHDRBSC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #P
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PL_SAFTInvoiceHeaderBasic
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum
  as select from I_JournalEntry            as Entry
    inner join   I_OperationalAcctgDocItem as Item       on  Item.CompanyCode          = Entry.CompanyCode
                                                         and Item.AccountingDocument   = Entry.AccountingDocument
                                                         and Item.FiscalYear           = Entry.FiscalYear
                                                         and Item.FinancialAccountType = 'D'

    inner join   P_PL_SAFTMapTaxCode       as MapTaxCode on  Entry.CompanyCode        = MapTaxCode.CompanyCode
                                                         and Entry.FiscalYear         = MapTaxCode.FiscalYear
                                                         and Entry.AccountingDocument = MapTaxCode.AccountingDocument

  association [0..1] to I_JournalEntryItemOneTimeData as _OneTimeAccountBP on  $projection.CompanyCode            = _OneTimeAccountBP.CompanyCode
                                                                and $projection.FiscalYear             = _OneTimeAccountBP.FiscalYear
                                                                and $projection.AccountingDocument     = _OneTimeAccountBP.AccountingDocument
                                                                and $projection.AccountingDocumentItem = _OneTimeAccountBP.AccountingDocumentItem

{
  key Entry.CompanyCode,
  key Entry.AccountingDocument,
  key Entry.FiscalYear,
  key max(AccountingDocumentItem)                 as AccountingDocumentItem,

      Entry.BusinessTransactionType,

      Entry.TaxReportingDate,
      Entry.PostingDate,
      Entry.DocumentDate,
      Entry.ReferenceDocumentType,

      @Semantics.currencyCode: true
      Entry.TransactionCurrency,
      @Semantics.currencyCode: true
      Entry.CompanyCodeCurrency,

      Entry.DocumentReferenceID,
      Entry.AlternativeReferenceDocument,

      Customer,
      Supplier,

      DocumentItemText,

      InvoiceReference,
      InvoiceReferenceFiscalYear,
      
      BillingDocument,

      IsEUTriangularDeal,

      Item.VATRegistration,
      Item.TaxCountry,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      sum(MapTaxCode.AmountInTransactionCurrency) as AmountInTransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      sum(MapTaxCode.AmountInCompanyCodeCurrency) as AmountInCompanyCodeCurrency,

      _CompanyCode,
      _Customer,
      _Supplier,
      _OneTimeAccountBP
}
where
          TaxReportingDate        between $parameters.P_StartDate and $parameters.P_EndDate
  and(
          BusinessTransactionType = 'SD00'
    or    BusinessTransactionType = 'RFBU'
  )
  and(
    (
          Supplier                is not null
      and Supplier                is not initial
    )
    or(
          Customer                is not null
      and Customer                is not initial
    )
  )
group by
  Entry.CompanyCode,
  Entry.AccountingDocument,
  Entry.FiscalYear,
  Entry.BusinessTransactionType,
  Entry.TaxReportingDate,
  Entry.PostingDate,
  Entry.DocumentDate,
  Entry.TransactionCurrency,
  Entry.CompanyCodeCurrency,
  Entry.DocumentReferenceID,
  Entry.AlternativeReferenceDocument,
  Entry.ReferenceDocumentType,
  Customer,
  Supplier,
  DocumentItemText,
  InvoiceReference,
  InvoiceReferenceFiscalYear,
  BillingDocument,
  IsEUTriangularDeal,
  Item.TaxCountry,
  Item.VATRegistration
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"I_OPERATIONALACCTGDOCITEM",
"P_PL_SAFTMAPTAXCODE"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CUSTOMER",
"I_JOURNALENTRYITEMONETIMEDATA",
"I_SUPPLIER"
],
"BASE":
[
"I_JOURNALENTRY",
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/