P_PLANDATA_RT_07

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'PPLANDATA_07'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
//@AccessControl.authorizationCheck: #NOT_ALLOWED

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

define view P_PLANDATA_RT_07
  with parameters
    P_CreationDateTimeRgFr :timestamp,
    P_CreationDateTimeRgTo :timestamp

  as select from           P_PlanData_RT_06
                 (P_CreationDateTimeRgFr : :P_CreationDateTimeRgFr,
                            P_CreationDateTimeRgTo : :P_CreationDateTimeRgTo) as Source

  //  TF103A: Breakdown info for transaction currency (RTCUR) depending on breakdown category (ITGRP)

    left outer to one join I_BreakdownCategoryField tf103a_rtcur                         on  Source.ConsolidationChartOfAccounts = tf103a_rtcur.ConsolidationChartOfAccounts
                                                                                         and Source.BreakdownCategory            = tf103a_rtcur.BreakdownCategory
                                                                                         and tf103a_rtcur.BreakdownCatFieldName  = 'RTCUR'

  //  TF160: Cons. unit master data

    left outer to one join I_CnsldtnUnit                                                 on  Source.ConsolidationDimension = I_CnsldtnUnit.ConsolidationDimension
                                                                                         and Source.ConsolidationUnit      = I_CnsldtnUnit.ConsolidationUnit

    inner join             I_FinancialPlanningEntryItem                       as _acdocp on  Source.FinancialPlanningReqTransSqnc = _acdocp.FinancialPlanningReqTransSqnc
                                                                                         and Source.FinancialPlanningDataPacket   = _acdocp.FinancialPlanningDataPacket
                                                                                         and Source.FinancialPlanningEntryItem    = _acdocp.FinancialPlanningEntryItem

  /*association [1..1] to I_FinancialPlanningEntryItem as _acdocp on  Source.FinancialPlanningReqTransSqnc = _acdocp.FinancialPlanningReqTransSqnc
                                                                and Source.FinancialPlanningDataPacket   = _acdocp.FinancialPlanningDataPacket
                                                                and Source.FinancialPlanningEntryItem    = _acdocp.FinancialPlanningEntryItem*/
{

  // Value in transaction currency (TSL): Evaluate breakdown type for RTCUR

  case //only 0 and 2 are possible for RTCUR

      when tf103a_rtcur.BreakdownType = '0'
        or tf103a_rtcur.BreakdownType is null
  //      no breakdown

          then
  //      TSL is never empty: Set local or group currency as default

              case I_CnsldtnUnit.DocumentEntryIsInGroupCurrency
                  when '' then Source.AmountInLocalCurrency
                  when 'X' // The cons. unit provides only values in group currency

                      then Source.AmountInGroupCurrency
              end
      when tf103a_rtcur.BreakdownType = '2'
  //      breakdown required, default allowed

         then Source.AmountInTransactionCurrency
  end                                  as AmountInTransactionCurrency,

  // Transaction currency key (RTCUR): Evaluate breakdown type

  case  //only 0 and 2 are possible for RTCUR

      when tf103a_rtcur.BreakdownType = '0'
        or tf103a_rtcur.BreakdownType is null
  //      no breakdown

          then
  //    RTCUR is never empty: Set local or group currency as default

              case I_CnsldtnUnit.DocumentEntryIsInGroupCurrency
                  when '' then Source.ConsolidationUnitLocalCurrency
                  when 'X' // The cons. unit provides only values in group currency

                      then Source.GroupCurrency
              end
      when tf103a_rtcur.BreakdownType = '2'
  //      breakdown required, default allowed

          then Source.BalanceTransactionCurrency
  end                                  as BalanceTransactionCurrency,

  // case

  Source.SubItemCategory,
  Source.SubItem,
  Source.PartnerConsolidationUnit,
  Source.BaseUnit,
  Source.QuantityInBaseUnit,
  Source.FinancialTransactionType,
  Source.FunctionalArea,
  Source.BusinessArea,
  Source.CostCenter,
  Source.GLAccount,
  Source.ProfitCenter,
  Source.Segment,
  Source.AmountInLocalCurrency,
  Source.AmountInGroupCurrency,

  // I_CnsldtnFinStmntItem

  /*Source.BreakdownCategory,*/

  // I_FSItemMappingAssgmtWithVers

  Source.FinancialStatementItem,
  Source.ConsolidationChartOfAccounts,

  // P_ConsolidationUnitCurrency

  Source.ConsolidationUnitLocalCurrency,

  // tfin010

  Source.ConsolidationDimension,
  Source.ConsolidationUnit,

  // tf200

  Source.ConsolidationVersion,

  // t881

  Source.ConsolidationLedger,
  Source.GroupCurrency,

  // I_FiscalCalendarDate / Or other source

  Source.FiscalPeriod,
  Source.FiscalYear,

  // mandatory standard fields

  /*Source.BalanceTransactionCurrency,*/
  /*Source.AmountInTransactionCurrency,*/

  // additional fields

  _acdocp.CompanyCode,
  _acdocp.ChartOfAccounts,
  cast('' as dzuonr)                   as AssignmentReference,
  _acdocp.ControllingArea,
  _acdocp.PartnerCostCenter,
  _acdocp.PartnerProfitCenter,
  _acdocp.PartnerFunctionalArea,
  _acdocp.PartnerBusinessArea,
  _acdocp.PartnerCompany,
  _acdocp.PartnerSegment,
  _acdocp.OrderID,
  _acdocp.Customer,
  cast('' as lifnr)                    as Supplier,
  _acdocp.Material,
  _acdocp.MaterialGroup,
  _acdocp.Plant,
  _acdocp.WBSElement                   as WBSElementExternalID,
  _acdocp.WBSElement,
  _acdocp.Project,
  _acdocp.BillingDocumentType,
  _acdocp.SalesOrganization,
  _acdocp.DistributionChannel,
  _acdocp.OrganizationDivision,
  _acdocp.SoldProduct,
  _acdocp.SoldProductGroup,
  _acdocp.CustomerGroup,
  _acdocp.CustomerSupplierCountry,
  _acdocp.CustomerSupplierIndustry,
  _acdocp.SalesDistrict,
  _acdocp.BillToParty,
  _acdocp.ShipToParty,
  _acdocp.CustomerSupplierCorporateGroup,
  _acdocp.WBSElementInternalID,
  _acdocp.FinPlngEntryItemCrtnDateTime as CreationDateTime,

  // specific fileds for this cds view

  Source.FinancialPlanningReqTransSqnc,
  Source.FinancialPlanningDataPacket,
  Source.FinancialPlanningEntryItem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BREAKDOWNCATEGORYFIELD",
"I_CNSLDTNUNIT",
"I_FINANCIALPLANNINGENTRYITEM",
"P_PLANDATA_RT_06"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/