P_PH_PaytOpnReceivablePyblItm

@AbapCatalog.sqlViewName: 'PPHPATYOPRPITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PH_PaytOpnReceivablePyblItm
  as select from    I_OperationalAcctgDocItem as _PaymentOpenItem
    inner join I_AccountingDocument      as _SourceInvoiceHeader on  _PaymentOpenItem.InvoiceReference                    = _SourceInvoiceHeader.AccountingDocument
                                                                                                      and _PaymentOpenItem.InvoiceReferenceFiscalYear      = _SourceInvoiceHeader.FiscalYear
                                                                                                      and _PaymentOpenItem.CompanyCode                         = _SourceInvoiceHeader.CompanyCode

   left outer join I_OperationalAcctgDocItem as _InvoiceApArItem   on   _InvoiceApArItem.AccountingDocument         = _PaymentOpenItem.InvoiceReference
                                                                                                  and _InvoiceApArItem.FiscalYear                          = _PaymentOpenItem.InvoiceReferenceFiscalYear
                                                                                                  and _InvoiceApArItem.CompanyCode                    = _PaymentOpenItem.CompanyCode
                                                                                                  and _InvoiceApArItem.AccountingDocumentItem   = _PaymentOpenItem.InvoiceItemReference
{
  key _PaymentOpenItem.CompanyCode,
  key _PaymentOpenItem.AccountingDocument,
  key _PaymentOpenItem.FiscalYear,
  key _PaymentOpenItem.AccountingDocumentItem,
  key _InvoiceApArItem.AccountingDocument as InvoiceReference,
  key _InvoiceApArItem.FiscalYear as InvoiceReferenceFiscalYear,
  key _InvoiceApArItem.AccountingDocumentItem as InvoiceItemReference,
  
      coalesce( _PaymentOpenItem.BusinessPlace, _InvoiceApArItem.BusinessPlace) as BusinessPlace,
      _PaymentOpenItem.PostingDate,
      _PaymentOpenItem.AccountingDocumentType,
      _PaymentOpenItem.FinancialAccountType,
      _PaymentOpenItem.IsUsedInPaymentTransaction,
      _PaymentOpenItem.ClearingJournalEntry           as ClearingAccountingDocument,
      _PaymentOpenItem.ClearingJournalEntryFiscalYear as ClearingDocFiscalYear,
      _PaymentOpenItem.ClearingDate,
      _PaymentOpenItem.GLAccount,
      case _PaymentOpenItem.IsNegativePosting
          when 'X' then
              case _PaymentOpenItem.DebitCreditCode
                  when 'H' then 'S'
                  when 'S' then 'H'
              end
          else _PaymentOpenItem.DebitCreditCode
      end as DebitCreditCode,
//      _PaymentOpenItem.DebitCreditCode,

      _PaymentOpenItem.Customer,
      _PaymentOpenItem.Supplier,
      _SourceInvoiceHeader.DocumentReferenceID,

      _PaymentOpenItem.TransactionCurrency,
      _PaymentOpenItem.AmountInTransactionCurrency,
      _PaymentOpenItem.CompanyCodeCurrency,
      _PaymentOpenItem.AmountInCompanyCodeCurrency,
      _PaymentOpenItem.AdditionalCurrency1,
      _PaymentOpenItem.AmountInAdditionalCurrency1,
      _PaymentOpenItem.AdditionalCurrency2,
      _PaymentOpenItem.AmountInAdditionalCurrency2,
      
      _InvoiceApArItem.CompanyCode as InvoiceCompanyCode,
      _PaymentOpenItem._Supplier,
      _PaymentOpenItem._Customer,
      _InvoiceApArItem._OneTimeAccountBP
}
where _PaymentOpenItem.IsUsedInPaymentTransaction  = 'X'
   and _PaymentOpenItem.InvoiceReference != ''
   // Exclude payment document which is a clearing document

 and not( _PaymentOpenItem.ClearingJournalEntry = _PaymentOpenItem.AccountingDocument
         and _PaymentOpenItem.ClearingJournalEntryFiscalYear    = _PaymentOpenItem.FiscalYear
             )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"I_OPERATIONALACCTGDOCITEM"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_ONETIMEACCOUNTBP",
"I_SUPPLIER"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/