P_PFMCarbonFootprintForPR

@AbapCatalog.sqlViewName: 'PMMPFMCFPR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality:  #D
@ObjectModel.usageType.sizeCategory: #L
@VDM.private: true
@VDM.viewType : #CONSUMPTION
define view P_PFMCarbonFootprintForPR
  with parameters
    P_DisplayCurrency : displaycurrency,
    P_StartDate       : bedat,
    P_EndDate         : bedat

  as select from I_PurchaseRequisitionItemBasic as PurchaseRequisition
    inner join   I_PFMTransDataCO2eqFprnt       as CO2eqFprnt on PurchaseRequisition.PFMTransDataFootprintUUID = CO2eqFprnt.PFMTransDataFootprintUUID
{
  key PurchaseRequisition.PurchaseRequisition,
  key PurchaseRequisition.PurchaseRequisitionItem,

      PurchaseRequisition.Material,
      PurchaseRequisition.Plant,
      PurchaseRequisition.MaterialGroup,

      PurchaseRequisition.FixedSupplier,
      PurchaseRequisition.PurchasingOrganization,
      PurchaseRequisition.PurchasingGroup,
      
      PurchaseRequisition.CreationDate,

      CO2eqFprnt.PFMFootprintQuantity,
      CO2eqFprnt.PFMFootprintUnit,

      case when PurchaseRequisition.PurReqnPriceQuantity > 0 and PurchaseRequisition.PurReqnItemCurrency != ''
       then cast ( division (currency_conversion(
                              amount             => PurchaseRequisition.PurchaseRequisitionPrice ,
                              source_currency    => PurchaseRequisition.PurReqnItemCurrency,
                              target_currency    =>  :P_DisplayCurrency,
                              exchange_rate_date => PurchaseRequisition.PurReqCreationDate,
                              exchange_rate_type => 'M'

                              ), PurchaseRequisition.PurReqnPriceQuantity,5) as abap.curr(21,5) )

      else 0
      end as PurchaseRequisitionPrice
}
where
      PurchaseRequisition.CreationDate >= $parameters.P_StartDate
  and PurchaseRequisition.CreationDate <= $parameters.P_EndDate
  and Material                         <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PFMTRANSDATACO2EQFPRNT",
"I_PURCHASEREQUISITIONITEMBASIC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/