P_OrderOpPRTStatusBasic

@AbapCatalog.sqlViewName: 'PORDOPPRTSTSBASC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@VDM.private: true
// provides the non-aggregated system status for Operation PRTs

// to be used in aggregation views such as P_OrderOpPRTStatusAggr only


/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view P_OrderOpPRTStatusBasic
  as select from I_StatusObjectStatusBasic as jest

  association [0..1] to I_StatusCode as _PRTIsCreatedCode      on  _PRTIsCreatedCode.StatusCode    = 'I0001'
                                                               and _PRTIsCreatedCode.StatusProfile = ''
  association [0..1] to I_StatusCode as _PRTIsReleasedCode     on  _PRTIsReleasedCode.StatusCode    = 'I0002'
                                                               and _PRTIsReleasedCode.StatusProfile = ''
  association [0..1] to I_StatusCode as _PRTIsPrintedCode      on  _PRTIsPrintedCode.StatusCode    = 'I0007'
                                                               and _PRTIsPrintedCode.StatusProfile = ''           
  association [0..1] to I_StatusCode as _PRTIsDeletedCode      on  _PRTIsDeletedCode.StatusCode    = 'I0013'
                                                               and _PRTIsDeletedCode.StatusProfile = ''
  association [0..1] to I_StatusCode as _PRTIsNotAvailableCode on  _PRTIsNotAvailableCode.StatusCode    = 'I0095'
                                                               and _PRTIsNotAvailableCode.StatusProfile = ''
{
    // Key

key jest.StatusObject as ObjectInternalID,

    @Semantics.booleanIndicator: true
    case jest.StatusCode
      when 'I0001' then 'X'
      else ''
    end as OrderOperationPRTIsCreated,
    @Semantics.booleanIndicator: true
    case jest.StatusCode
      when 'I0002' then 'X'
      else ''
    end as OrderOperationPRTIsReleased,
    @Semantics.booleanIndicator: true
    case jest.StatusCode
      when 'I0007' then 'X'
      else ''
    end as OrderOperationPRTIsPrinted,
    @Semantics.booleanIndicator: true
    case jest.StatusCode
      when 'I0013' then 'X'
      else ''
    end as OrderOperationPRTIsDeleted,
    @Semantics.booleanIndicator: true
    case jest.StatusCode
      when 'I0095' then 'X'
      else ''
    end as OrdOperationPRTIsNotAvailable,

    // Associations

    _StatusObject,
    _PRTIsCreatedCode,
    _PRTIsReleasedCode,
    _PRTIsPrintedCode,
    _PRTIsDeletedCode,
    _PRTIsNotAvailableCode
}
where
  (     jest.StatusCode       = 'I0001'
    or  jest.StatusCode       = 'I0002'
    or  jest.StatusCode       = 'I0007'
    or  jest.StatusCode       = 'I0013'
    or  jest.StatusCode       = 'I0095'
  ) and jest.StatusIsInactive = ' ' 
    and jest.StatusObject like 'OF%';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STATUSOBJECTSTATUSBASIC"
],
"ASSOCIATED":
[
"I_STATUSCODE",
"I_STATUSOBJECT"
],
"BASE":
[
"I_STATUSOBJECTSTATUSBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/