P_OpActyNumberOfInspCharcs

@AbapCatalog.sqlViewName: 'POPACTYNMBROFPIC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #B
}
@VDM. private: true
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_OpActyNumberOfInspCharcs
  as select from    I_OpActyInstceNtwkElmntBasic as OpActyInstceNtwkElmntBasic
    inner join      I_LogisticsOrder             as LogisticsOrder            on LogisticsOrder.OrderID = OpActyInstceNtwkElmntBasic.ManufacturingOrder
    inner join      I_OrderOperationBasic        as OrderOperationBasic       on  OrderOperationBasic.OrderInternalID          = LogisticsOrder.OrderInternalBillOfOperations
                                                                              and OrderOperationBasic.OrderOperationInternalID = OpActyInstceNtwkElmntBasic.OrderOperationInternalID
    left outer join I_OpActyBOOCharcAssgmt       as OpActyBOOCharcAssgmt      on  OpActyBOOCharcAssgmt.OperationActivity           = OpActyInstceNtwkElmntBasic.OpActyNtwkElementElement
                                                                              and OpActyBOOCharcAssgmt.OperationActyVersionCounter = OpActyInstceNtwkElmntBasic.OpActyNtwkElementElmntVersCntr
                                                                              and OpActyBOOCharcAssgmt.BillOfOperationsType        = OrderOperationBasic.BillOfOperationsType
                                                                              and OpActyBOOCharcAssgmt.BillOfOperationsGroup       = OrderOperationBasic.BillOfOperationsGroup
                                                                              and OpActyBOOCharcAssgmt.BOOOperationInternalID      = OrderOperationBasic.BOOOperationInternalID
    left outer join I_InspectionCharacteristic   as _InspectionCharacteristic on  _InspectionCharacteristic.InspectionLot               = LogisticsOrder.InspectionLot
    -- Shortcut: Join InspPlanOperationInternalID with OrderOperationInternalID (those are kept identitical)
    -- Alternative: Additional Join with table QAOP which maps InspPlanOperationInternalID (VORGLFNR) with OrderOperationInternalID (APLZL)
                                                                              and _InspectionCharacteristic.InspPlanOperationInternalID = OrderOperationBasic.OrderOperationInternalID
                                                                              and _InspectionCharacteristic.InspectionCharacteristic    = OpActyBOOCharcAssgmt.BOOCharacteristic
{
  key OpActyInstceNtwkElmntBasic.OpActyNtwkInstance        as OpActyNtwkInstance,
  key OpActyInstceNtwkElmntBasic.OpActyNtwkElement         as OpActyNtwkElement,
      sum( case
       when _InspectionCharacteristic.InspSpecCharcCategory = 'X' then 1
       else 0
       end)                                                as NumberOfMandatoryInspCharcs,
      sum( case
        when _InspectionCharacteristic.InspectionCharacteristic is not null or _InspectionCharacteristic.InspectionCharacteristic != '0000' then 1
        else 0
        end)                                               as NumberOfInspCharcs,

      OpActyInstceNtwkElmntBasic._OpActyNtwkInstance
}
group by
  OpActyInstceNtwkElmntBasic.OpActyNtwkInstance,
  OpActyInstceNtwkElmntBasic.OpActyNtwkElement;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONCHARACTERISTIC",
"I_LOGISTICSORDER",
"I_OPACTYBOOCHARCASSGMT",
"I_OPACTYINSTCENTWKELMNTBASIC",
"I_ORDEROPERATIONBASIC"
],
"ASSOCIATED":
[
"I_OPACTYNTWKINSTANCE"
],
"BASE":
[
"I_OPACTYINSTCENTWKELMNTBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/