P_OpActyInstanceWithUserAssgmt

@AbapCatalog.sqlViewName: 'POAIWUA'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  serviceQuality: #D,
  sizeCategory:   #L,
  dataClass:      #MIXED
}
@VDM: {
  private: true,
  viewType: #TRANSACTIONAL
}
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view P_OpActyInstanceWithUserAssgmt
  as select from           I_OpActyInstceOpActyNtwkElmnt as OpActyInstceOpActyNtwkElmnt
    inner join             I_OpActyInstanceStatusBasic   as OpActyInstanceStatusBasic on  OpActyInstanceStatusBasic.OpActyNtwkInstance = OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance
                                                                                      and OpActyInstanceStatusBasic.OpActyNtwkElement  = OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement
    inner join             I_OrderOperationDateTime      as OrderOperationDateTime    on  OrderOperationDateTime.OrderInternalID          = OpActyInstceOpActyNtwkElmnt.OrderInternalID
                                                                                      and OrderOperationDateTime.OrderOperationInternalID = OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID
    left outer to one join I_WorkCenter                  as WorkCenter                on  WorkCenter.WorkCenterTypeCode   = OrderOperationDateTime.WorkCenterTypeCode
                                                                                      and WorkCenter.WorkCenterInternalID = OrderOperationDateTime.WorkCenterInternalID
    left outer join        I_OpActyUserAssgmtBasic       as assgmt                    on  OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance = assgmt.OpActyNtwkInstance
                                                                                      and OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement  = assgmt.OpActyNtwkElement
  association [1..1] to I_User                    as _User                    on  $projection.UserID = _User.UserID
  association [1..1] to I_Plant                   as _ProductionPlant         on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_WorkCenterBySemanticKey as _WorkCenterBySemanticKey on  $projection.WorkCenter      = _WorkCenterBySemanticKey.WorkCenter
                                                                              and $projection.ProductionPlant = _WorkCenterBySemanticKey.Plant
  association [0..1] to I_WorkCenterType          as _WorkCenterType          on  $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode
{
      //I_OpActyInstceOpActyNtwkElmnt

  key OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance                                                                 as  OpActyNtwkInstance,
  key OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement                                                                  as  OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_User'
  key coalesce( assgmt.UserID, '' )                                                                                  as  UserID,

      OpActyInstceOpActyNtwkElmnt.ManufacturingOrder                                                                 as  ManufacturingOrder,
      OpActyInstceOpActyNtwkElmnt.OrderInternalID                                                                    as  OrderInternalID,
      OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID                                                           as  OrderOperationInternalID,
      OpActyInstceOpActyNtwkElmnt.StatusAndActionSchema                                                              as  StatusAndActionSchema,
      OpActyInstanceStatusBasic.StatusAndActionSchemaStatus                                                          as  StatusAndActionSchemaStatus,
      OpActyInstanceStatusBasic._SASStatus.SASStatusCategory                                                         as  SASStatusCategory,
      OpActyInstceOpActyNtwkElmnt.ProductionUnit                                                                     as  ProductionUnit,
      OpActyInstceOpActyNtwkElmnt.OpPlannedYieldQuantity                                                             as  OpPlannedYieldQuantity,
      OpActyInstceOpActyNtwkElmnt.OpPlannedScrapQuantity                                                             as  OpPlannedScrapQuantity,
      OpActyInstceOpActyNtwkElmnt.OpActyExpdExecDurnInSeconds                                                        as  OpActyExpdExecDurnInSeconds,
      OpActyInstceOpActyNtwkElmnt.OperationActivityNetwork                                                           as  OperationActivityNetwork,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkVersionCounter                                                           as  OpActyNtwkVersionCounter,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType                                                              as  OpActyNtwkSegmentType,
      OpActyInstceOpActyNtwkElmnt.OpActyConfIsSFIBased                                                               as  OpActyConfIsSFIBased,
      OpActyInstceOpActyNtwkElmnt.OpActyConfirmationIsAllowed                                                        as  OpActyConfirmationIsAllowed,
      OpActyInstceOpActyNtwkElmnt.OpActyConfNotAllowedReason                                                         as  OpActyConfNotAllowedReason,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementExternalID                                                        as  OpActyNtwkElementExternalID,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementElement                                                           as  OpActyNtwkElementElement,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementElmntVersCntr                                                     as  OpActyNtwkElementElmntVersCntr,
      OpActyInstceOpActyNtwkElmnt.OperationActivity                                                                  as  OperationActivity,
      OpActyInstceOpActyNtwkElmnt.OperationActyVersionCounter                                                        as  OperationActyVersionCounter,
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkElementType                                                              as  OpActyNtwkElementType,

      //I_MfgOrderOperation

      OrderOperationDateTime.Operation                                                                               as  ManufacturingOrderOperation,
      OrderOperationDateTime.OperationText                                                                           as  MfgOrderOperationText,
      @ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
      WorkCenter.WorkCenter                                                                                          as  WorkCenter,
      OrderOperationDateTime.WorkCenterInternalID                                                                            as  WorkCenterInternalID,
      OrderOperationDateTime.WorkCenterTypeCode                                                                              as  WorkCenterTypeCode,
      WorkCenter.LaborTrackingIsRequired                                                                             as  LaborTrackingIsRequired,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      OrderOperationDateTime.Plant                                                                                   as  ProductionPlant,

      //I_OpActyUserAssgmt

      assgmt.CreatedByUser                                                                                           as  CreatedByUser,
      assgmt.CreationDateTime                                                                                        as  CreationDateTime,
      assgmt.MfgOpActyExecutionPriority                                                                              as  MfgOpActyExecutionPriority,

      /* Associations */
      //I_OpActyInstceOpActyNtwkElmnt

      OpActyInstceOpActyNtwkElmnt._MfgOrder,
      OpActyInstceOpActyNtwkElmnt._OrderInternalID,
      OpActyInstceOpActyNtwkElmnt._OpActyNtwkInstance,
      OpActyInstceOpActyNtwkElmnt._SASSchema,
      OpActyInstceOpActyNtwkElmnt._UnitOfMeasure,
      OpActyInstceOpActyNtwkElmnt._OpActyNtwkInternalId,
      OpActyInstceOpActyNtwkElmnt._OperationActivityNetwork,
      OpActyInstceOpActyNtwkElmnt._OperationActivity,
      OpActyInstceOpActyNtwkElmnt._OperationActivityText,
      _ProductionPlant,
      _WorkCenterType,
      //I_User

      _User,
      //I_WorkCenterBySemanticKey

      _WorkCenterBySemanticKey,
      //I_OpActyInstanceStatusBasic

      OpActyInstanceStatusBasic._SASStatus,
      cast( case
        when OrderOperationDateTime.OpActualExecutionStartDate <> '00000000' then
          OrderOperationDateTime.OpActualExecutionStartDateTime
         when OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType = '1' then
           OrderOperationDateTime.OpLtstSchedldExecStrtDteTme
         when OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType = '2' then
           OrderOperationDateTime.OpLtstSchedldProcgStrtDteTme
         else
           OrderOperationDateTime.OpLtstSchedldTrdwnStrtDteTme
      end as mpe_oper_schedld_start_time preserving type )                                                          as OpLtstSchedldExecStrtDteTme,
      cast( case
        when OrderOperationDateTime.OpActualExecutionStartDate <> '00000000' then 'X'
        else ''
      end as boolean preserving type )                                                                              as DateIsActualDate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OPACTYINSTANCESTATUSBASIC",
"I_OPACTYINSTCEOPACTYNTWKELMNT",
"I_OPACTYUSERASSGMTBASIC",
"I_ORDEROPERATIONDATETIME",
"I_SASSTATUS",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_MFGORDER",
"I_OPACTYNTWKINSTANCE",
"I_OPACTYNTWKINTERNALID",
"I_OPERATIONACTIVITY",
"I_OPERATIONACTIVITYNETWORK",
"I_OPERATIONACTIVITYTEXT",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANT",
"I_SASSCHEMA",
"I_SASSTATUS",
"I_UNITOFMEASURE",
"I_USER",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERTYPE"
],
"BASE":
[
"I_OPACTYINSTANCESTATUSBASIC",
"I_OPACTYINSTCEOPACTYNTWKELMNT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/