P_OpActyAllManufacturingUsers

@AbapCatalog.sqlViewName: 'PMPEOAALLMFGUSRS'
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
define view P_OpActyAllManufacturingUsers
  as select from           I_OpActyInstceOpActyNtwkElmnt as OpActyInstceOpActyNtwkElmnt
    cross join             I_MfgBusinessPartner          as MfgBusinessPartner
    inner join             I_OrderOperationBasic         as OrderOperation on  OrderOperation.OrderInternalID          = OpActyInstceOpActyNtwkElmnt.OrderInternalID
                                                                           and OrderOperation.OrderOperationInternalID = OpActyInstceOpActyNtwkElmnt.OrderOperationInternalID
    left outer to one join I_WorkCenter                  as WorkCenter     on  WorkCenter.WorkCenterTypeCode   = OrderOperation.WorkCenterTypeCode
                                                                           and WorkCenter.WorkCenterInternalID = OrderOperation.WorkCenterInternalID

  association [0..*] to I_OperationActivityWorklistTP as _OperationActivityWorklistTP on $projection.userid = _OperationActivityWorklistTP.UserID
  association [1..1] to I_Plant                       as _Plant                       on $projection.Plant = _Plant.Plant
  association [0..1] to I_User                        as _User                        on $projection.userid = _User.UserID
  association [0..*] to I_UserOpenOpActyAssignment    as _UserOpenOpActyAssignment    on $projection.userid = _UserOpenOpActyAssignment.UserID
  association [0..*] to I_MfgHumRsceQualifnBPAssgmt   as _MfgHumRsceQualifnBPAssgmt   on $projection.MfgBusinessPartner = _MfgHumRsceQualifnBPAssgmt.MfgBusinessPartner
{
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key OpActyInstceOpActyNtwkElmnt.OpActyNtwkInstance,
  key OpActyInstceOpActyNtwkElmnt.OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_User'
  key MfgBusinessPartner._User.UserID,
      MfgBusinessPartner.MfgBusinessPartner,
      MfgBusinessPartner.BusinessPartnerUUID,
      @ObjectModel.foreignKey.association: '_MfgOrder'
      OpActyInstceOpActyNtwkElmnt.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_OANSegmentType'
      OpActyInstceOpActyNtwkElmnt.OpActyNtwkSegmentType,
      @ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
      MfgBusinessPartner.WorkCenter,
      @ObjectModel.foreignKey.association: '_Plant'
      MfgBusinessPartner.Plant,
      cast(case
        when WorkCenter.WorkCenter is not null
        and WorkCenter.WorkCenter = MfgBusinessPartner.WorkCenter
        and WorkCenter.Plant = MfgBusinessPartner.Plant
          then 'X'
        else ''
      end as boolean preserving type) as UserIsOpActyMainWrkCtrMfgUser,

      OpActyInstceOpActyNtwkElmnt._OpActyNtwkInstance,
      _User,
      MfgBusinessPartner._WorkCenterBySemanticKey,
      OpActyInstceOpActyNtwkElmnt._OANSegmentType,
      OpActyInstceOpActyNtwkElmnt._MfgOrder,
      _Plant,
      _OperationActivityWorklistTP,
      _UserOpenOpActyAssignment,
      _MfgHumRsceQualifnBPAssgmt
}
where
  MfgBusinessPartner._User.UserID is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGBUSINESSPARTNER",
"I_OPACTYINSTCEOPACTYNTWKELMNT",
"I_ORDEROPERATIONBASIC",
"I_USER",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_MFGHUMRSCEQUALIFNBPASSGMT",
"I_MFGORDER",
"I_OANSEGMENTTYPE",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYWORKLISTTP",
"I_PLANT",
"I_USER",
"I_USEROPENOPACTYASSIGNMENT",
"I_WORKCENTERBYSEMANTICKEY"
],
"BASE":
[
"I_MFGBUSINESSPARTNER",
"I_OPACTYINSTCEOPACTYNTWKELMNT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/