@AbapCatalog.sqlViewName: 'PFIOFFSETACCT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
//@EndUserText.label: 'Private union view for OffsettingAccount'
define view P_OffsettingAccount as select from I_Supplier {
key cast(' ' as fis_ktopl preserving type ) as ChartOfAccounts,
key cast(I_Supplier.Supplier as fis_gkont preserving type ) as OffsettingAccount,
key cast('K' as farp_gkoar preserving type ) as OffsettingAccountType,
cast(I_Supplier.SupplierName as fis_offsetting_acct_name preserving type ) as OffsettingAccountName,
cast(I_Supplier.OrganizationBPName1 as fis_offsetting_acct_short_name preserving type ) as OffsettingAccountShortName
//I_Supplier.SupplierFullName as OffsettingAccountFullName
}
union all select from I_Customer {
key cast(' ' as fis_ktopl preserving type ) as ChartOfAccounts,
key cast(I_Customer.Customer as fis_gkont preserving type ) as OffsettingAccount,
key cast('D' as farp_gkoar preserving type ) as OffsettingAccountType,
cast(I_Customer.CustomerName as fis_offsetting_acct_name preserving type ) as OffsettingAccountName,
cast(I_Customer.OrganizationBPName1 as fis_offsetting_acct_short_name preserving type ) as OffsettingAccountShortName
//I_Customer.CustomerFullName as OffsettingAccountFullName
}
union all select from I_GLAccountInChartOfAccounts
left outer to one join I_GLAccountTextRawData on I_GLAccountInChartOfAccounts.ChartOfAccounts = I_GLAccountTextRawData.ChartOfAccounts
and I_GLAccountInChartOfAccounts.GLAccount = I_GLAccountTextRawData.GLAccount
and I_GLAccountTextRawData.Language = $session.system_language
{
key I_GLAccountInChartOfAccounts.ChartOfAccounts,
key cast(I_GLAccountInChartOfAccounts.GLAccount as fis_gkont preserving type ) as OffsettingAccount,
key cast('S' as farp_gkoar preserving type ) as OffsettingAccountType,
cast(I_GLAccountTextRawData.GLAccountName as fis_offsetting_acct_name ) as OffsettingAccountName,
I_GLAccountTextRawData.GLAccountName as OffsettingAccountShortName
//I_GLAccountInChartOfAccounts._Text[1: Language = $session.system_language].GLAccountLongName as OffsettingAccountFullName
}
//where I_GLAccountTextRawData.Language = $session.system_language
union all select from I_GLAccountInChartOfAccounts
left outer to one join I_GLAccountTextRawData on I_GLAccountInChartOfAccounts.ChartOfAccounts = I_GLAccountTextRawData.ChartOfAccounts
and I_GLAccountInChartOfAccounts.GLAccount = I_GLAccountTextRawData.GLAccount
and I_GLAccountTextRawData.Language = $session.system_language
{
key I_GLAccountInChartOfAccounts.ChartOfAccounts,
key cast(I_GLAccountInChartOfAccounts.GLAccount as fis_gkont preserving type ) as OffsettingAccount,
key cast('A' as farp_gkoar preserving type ) as OffsettingAccountType,
cast(I_GLAccountTextRawData.GLAccountName as fis_offsetting_acct_name) as OffsettingAccountName,
I_GLAccountTextRawData.GLAccountName as OffsettingAccountShortName
//I_GLAccountInChartOfAccounts._Text[1: Language = $session.system_language].GLAccountLongName as OffsettingAccountFullName
}
//where I_GLAccountTextRawData.Language = $session.system_language
union all select from I_GLAccountInChartOfAccounts
left outer to one join I_GLAccountTextRawData on I_GLAccountInChartOfAccounts.ChartOfAccounts = I_GLAccountTextRawData.ChartOfAccounts
and I_GLAccountInChartOfAccounts.GLAccount = I_GLAccountTextRawData.GLAccount
and I_GLAccountTextRawData.Language = $session.system_language
{
key I_GLAccountInChartOfAccounts.ChartOfAccounts,
key cast(I_GLAccountInChartOfAccounts.GLAccount as fis_gkont preserving type ) as OffsettingAccount,
key cast('M' as farp_gkoar preserving type ) as OffsettingAccountType,
cast(I_GLAccountTextRawData.GLAccountName as fis_offsetting_acct_name) as OffsettingAccountName,
I_GLAccountTextRawData.GLAccountName as OffsettingAccountShortName
//I_GLAccountInChartOfAccounts._Text[1: Language = $session.system_language].GLAccountLongName as OffsettingAccountFullName
}
//where I_GLAccountTextRawData.Language = $session.system_language
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTTEXTRAWDATA",
"I_SUPPLIER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/