P_MfgQualification

@AbapCatalog.sqlViewName: 'PMFGQUALIFN'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_MfgQualification
  as select from           hrp1000                     as Qualification
    inner join             t77s0                       as SystemTable           on  SystemTable.grpid = 'PLOGI'
                                                                                and SystemTable.semid = 'PLOGI'
                                                                                and SystemTable.gsval = Qualification.plvar
    left outer to one join hrp1001                     as QualificationRelation on  QualificationRelation.objid = Qualification.objid
                                                                                and QualificationRelation.plvar = Qualification.plvar
                                                                                and QualificationRelation.otype = Qualification.otype
                                                                                and QualificationRelation.istat = Qualification.istat
                                                                                and QualificationRelation.begda = Qualification.begda
                                                                                and QualificationRelation.endda = Qualification.endda
                                                                                and QualificationRelation.seqnr = Qualification.seqnr
                                                                                and QualificationRelation.sclas = 'QK'
    left outer to one join P_MfgQualificationGroupList as GroupList             on QualificationRelation.sobid = GroupList.MfgHumanResourceQualification
    left outer to one join I_MfgQualificationGroup     as Catalog               on QualificationRelation.sobid = Catalog.MfgHumRsceQualificationGroup
{
  key cast(Qualification.objid as mpe_qual_id preserving type) as MfgHumanResourceQualification,
      Qualification.stext                                      as MfgHumRsceQualificationDesc,

      case GroupList.MfgHumRsceQualificationIsGroup
      when 0 then
      cast('00000000' as hrobjid preserving type )  else
      GroupList.MfgHumanResourceQualification end              as MfgHumRsceQualificationGroup,
      case GroupList.MfgHumRsceQualificationIsGroup
      when 0 then
      ''  else
      GroupList.MfgHumRsceQualificationGrpDesc end             as MfgHumRsceQualificationGrpDesc,
      case GroupList.MfgHumRsceQualificationIsGroup
      when 0 then
      GroupList.MfgHumanResourceQualification
      else Catalog.MfgHumRsceQualificationCatalog end          as MfgHumRsceQualificationCatalog,
      case GroupList.MfgHumRsceQualificationIsGroup
      when 0 then
      GroupList.MfgHumRsceQualificationGrpDesc
      else Catalog.MfgHumRsceQualifnCatalogDesc  end           as MfgHumRsceQualifnCatalogDesc,
      cast(Qualification.endda as enddatum preserving type )   as EndDate,
      QualificationRelation.sobid                              as MfgHumanRsceQualifnGroupOrCtlg
}
where
      Qualification.otype = 'Q'
  and Qualification.langu = $session.system_language
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGQUALIFICATIONGROUP",
"P_MFGQUALIFICATIONGROUPLIST",
"HRP1000",
"HRP1001",
"T77S0"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/