P_MfgOrderSpclStockValStrategy

@AbapCatalog.sqlViewName: 'PMFGORDVALSTR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: true
@VDM.viewType: #COMPOSITE

define view P_MfgOrderSpclStockValStrategy
  with parameters
    P_Ledger       : fins_ledger,
    P_CurrencyRole : fac_crcyrole
  // MTS or MTO ETO valuation 'A'

  as select from P_ProductCostCtrlgOrderAndItem
{
  key OrderID,
  key OrderItem,
  key ObjectInternalID,
      Plant,
      Material,
      SalesOrder,
      SalesOrderItem,

      cast('3' as ck_lbwst) as ValuationStrategy
}
where
  (
           InventorySpecialStockType     is initial
    or(
           InventorySpecialStockValnType = 'A'
      and(
           InventorySpecialStockType     = 'E'
        or InventorySpecialStockType     = 'Q'
      )
    )
  )
  and      IsFixedPriceCoProduct         = ''
  and(     // exclude Joint-Production Header


           OrderItem                     is not initial // Order Item

    or     MfgOrderHasMultipleItems      = '' // Not Joint-Production

  )
  and      ActualReleasedDate            is not initial // filters Released Orders only

  and(
           OrderCategory                 = '10'
    or     OrderCategory                 = '40'
  )
// MTO ETO valuation 'M'

union select from P_ProductCostCtrlgOrderAndItem as _OrderAndItem
  inner join      R_MatlPriceSpclStockValnStrgy  as _ValuationStrategy on  _OrderAndItem.Plant          = _ValuationStrategy.Plant
                                                                       and _OrderAndItem.Material       = _ValuationStrategy.Material
                                                                       and _OrderAndItem.ValuationType  = _ValuationStrategy.ValuationType
{
  key _OrderAndItem.OrderID,
  key _OrderAndItem.OrderItem,
  key ObjectInternalID,
      _OrderAndItem.Plant,
      _OrderAndItem.Material,
      _OrderAndItem.SalesOrder,
      _OrderAndItem.SalesOrderItem,
      CurPlanProjSlsOrdValnStrategy as ValuationStrategy
}
where
  (
    (
          InventorySpecialStockType          = 'E'
      and _OrderAndItem.SalesOrder           = _ValuationStrategy.SalesOrder
      and _OrderAndItem.SalesOrderItem       = _ValuationStrategy.SalesOrderItem
    )
    or(
          InventorySpecialStockType          = 'Q'
      and _OrderAndItem.WBSElementInternalID = _ValuationStrategy.WBSElementInternalID
    )
  )
  and     InventorySpecialStockValnType      = 'M'
  and     IsFixedPriceCoProduct              = ''
  and     Ledger                             = :P_Ledger
  and     CurrencyRole                       = :P_CurrencyRole
  and     CurPlanProjSlsOrdValnStrategy      is not initial
  and     MatlPrcValdtyEndFsclYearPeriod     = '9999012'
  and(    // exclude Joint-Production Header


          OrderItem                          is not initial // Order Item

    or    MfgOrderHasMultipleItems           = '' // Not Joint-Production

  )
  and     ActualReleasedDate                 is not initial // filters Released Orders only

  and(
          OrderCategory                      = '10'
    or    OrderCategory                      = '40'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PRODUCTCOSTCTRLGORDERANDITEM",
"R_MATLPRICESPCLSTOCKVALNSTRGY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/