P_MfgOrderItem

@AbapCatalog.sqlViewName: 'PPPMFGORDITEM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@VDM.private: true

define view P_MfgOrderItem
// used for AMDP method (Table Function) determine_item_durations

  as select from afpo as afpo
      inner join afko as afko on  afko.mandt = afpo.mandt 
                              and afko.aufnr = afpo.aufnr
         
  association[1..1] to I_Plant as _ProductionPlant on $projection.ProductionPlant = _ProductionPlant.Plant
{
      // Key

  key afpo.aufnr as ManufacturingOrder,
  key afpo.posnr as ManufacturingOrderItem,

      // Category and Type

      afpo.dauty as ManufacturingOrderCategory,
      afpo.dauat as ManufacturingOrderType,

      // Assignments

      afpo.dwerk as ProductionPlant,
      _ProductionPlant.FactoryCalendar as FactoryCalendar,    
      afpo.pwerk as MRPPlant,

      // Dates

      afko.gstrp as MfgOrderPlannedStartDate,
      afko.gstrs as MfgOrderScheduledStartDate,
      afko.gstri as MfgOrderActualStartDate,
      afpo.dgltp as MfgOrderItemPlannedEndDate,
      afpo.dglts as MfgOrderItemScheduledEndDate,
      afpo.ltrmp as MfgOrderItemPlndDeliveryDate,
      afpo.ltrmi as MfgOrderItemActualDeliveryDate,
      
      // others

      afpo.webaz as MaterialGoodsReceiptDuration,

      // Associations

      _ProductionPlant
}
  where ( afpo.dauty = '10' or //Manufacturing orders only

          afpo.dauty = '40' ); 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"AFKO",
"AFPO"
],
"ASSOCIATED":
[
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/