P_MfgOrdTargetCost3V2

@AbapCatalog.sqlViewName: 'PMFGORDTGTCST3V2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@VDM.private: true
// PLANORD01 (Target Variant 1)


define view P_MfgOrdTargetCost3V2
  with parameters
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger,
    P_CurrencyRole         : fac_crcyrole
  as select from P_COMFGOrderOutputQuantities( P_FromFiscalYearPeriod : :P_FromFiscalYearPeriod,
                                               P_ToFiscalYearPeriod   : :P_ToFiscalYearPeriod ) as _PlanQuantity
    inner join   P_MfgOrdPlanCostByLdgr2V2( P_Ledger       : :P_Ledger,
                                          P_CurrencyRole : :P_CurrencyRole )                    as _PlanCost on  _PlanCost.OrderID                =  _PlanQuantity.OrderID
                                                                                                             and _PlanCost.OrderItem              =  _PlanQuantity.OrderItem                                                                                                   
{
  key    _PlanQuantity.OrderID,
  key    _PlanQuantity.OrderItem,
  key    _PlanCost.CompanyCode,
  key    AccountAssignmentType,
  key    ControllingArea,
  key    _PlanCost.Material         as product,
  key    _PlanCost.Plant,
  key    GLAccount,
  key    WorkCenterInternalID,
  key    OrderOperation,
  key    cast('001' as  fis_awvrs ) as TargetCostVariant,
  key    cast('05' as co_wrttp)     as ControllingValueType,
  key    ControllingDebitCreditCode,
  key    PartnerCostCenter,
  key    PartnerCostCtrActivityType,
  key    CostSourceUnit             as UnitOfMeasure,
  key    IsLotSizeIndependent,
  key    cast('3' as ck_lbwst)      as ValuationStrategy,
         case
            when IsLotSizeIndependent = 'X' then AmountInDisplayCurrency
            else
              case
                when PlanOutputQuantity <> 0
                  then cast( round(cast(division(ActualOutputQuantity, PlanOutputQuantity, 6) as abap.dec(14, 6)) * AmountInDisplayCurrency, 2) as abap.curr( 23, 2 ) )
                else 0
              end
          end                       as AmountInDisplayCurrency,

         case
           when IsLotSizeIndependent = 'X' then FixedAmountInDisplayCurrency
           else
             case
               when PlanOutputQuantity <> 0
                 then cast( round(cast(division(ActualOutputQuantity, PlanOutputQuantity, 6) as abap.dec(14, 6)) * FixedAmountInDisplayCurrency, 2) as abap.curr( 23, 2 ) )
               else 0
             end
         end                        as FixedAmountInDisplayCurrency,

         case
           when IsLotSizeIndependent = 'X' then TotalQuantity
           else
             case
               when PlanOutputQuantity <> 0
                 then cast( round(cast(division(ActualOutputQuantity, PlanOutputQuantity, 6) as abap.dec(14, 6)) * TotalQuantity, 3) as abap.quan( 23, 3 ) )
               else 0
             end
         end                        as TotalQuantity
}where _PlanQuantity.ActualOutputQuantity <> 0  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_COMFGORDEROUTPUTQUANTITIES",
"P_MFGORDPLANCOSTBYLDGR2V2"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/